Add tcsh(1) dotfiles - dotfiles - leot's dotfiles
(HTM) hg clone https://bitbucket.org/iamleot/dotfiles
(DIR) Log
(DIR) Files
(DIR) Refs
---
(DIR) changeset 663f56665e414cc5929615eabbe21396d157936e
(DIR) parent e6226a80fcfdc40a976092371d4502756930d78a
(HTM) Author: Leonardo Taccari <iamleot@gmail.com>
Date: Sun, 23 Sep 2018 23:08:37
Add tcsh(1) dotfiles
Diffstat:
tcsh.complete | 104 +++++++++++++++++++++++++++++++++++++++++++
tcshrc | 140 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
2 files changed, 244 insertions(+), 0 deletions(-)
---
diff -r e6226a80fcfd -r 663f56665e41 tcsh.complete
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/tcsh.complete Sun Sep 23 23:08:37 2018 +0200
@@ -0,0 +1,104 @@
+set backslash_quote
+
+## tcsh builtin commands
+complete {,un}alias 'p/1/a/'
+complete {,un}set 'p/1/v/'
+complete {,un}setenv 'p/1/e/'
+complete limit 'p/1/l/'
+complete {f,b,fg,bg,stop} 'c/%/j/' 'p/1/(%)//'
+complete where 'p/1/c/'
+complete which 'p/1/c/'
+
+## commands
+complete audioctl 'p/*/`audioctl -a | awk -F \'=\' \'{ print $1 }\'`/'
+complete ifconfig 'p/*/`ifconfig -l`/'
+complete kill 'c/-/S/' 'p/*/`ps -o pid=`/'
+# XXX: How to insert a `...` inside a `...`?
+#complete man 'p/*/`set cl = ($COMMAND_LINE); [ $#cl = 2 ] && man -p | xargs -J % find % -type f -name $cl[2]* | awk -F \'/\' \'{ sub(/\\..*$/, "", $NF); print $NF }\'`/'
+complete man 'p/*/c/'
+complete look 'p/1/`set cl = ($COMMAND_LINE); [ $#cl = 2 ] && look $cl[2]`/'
+complete mixerctl 'p/*/`mixerctl -a | awk -F \'=\' \'{ print $1 }\'`/'
+complete p{grep,renice} 'p/*/`ps -o ucomm= | sort -u`/'
+complete pkill 'c/-/S/' 'p/*/`ps -o ucomm= | sort -u`/'
+complete sysctl 'p/*/`sysctl -a | awk \'{ print $1 }\'`/'
+
+## cvs
+complete cvs 'p/1/(acl add admin annotate checkout commit diff \
+ edit editors export history import init log login logout ls pserver \
+ racl rannotate rdiff release remove rlog rls rtag server status \
+ tag unedit update version watch watchers)/'
+
+## git
+complete git 'p/1/(add add--interactive am annotate apply \
+ archimport archive bisect bisect--helper blame branch bundle cat-file \
+ check-attr check-ignore check-mailmap check-ref-format checkout \
+ checkout-index cherry cherry-pick clean clone column commit \
+ commit-tree config count-objects credential credential-cache \
+ credential-cache--daemon credential-store cvsexportcommit cvsimport \
+ cvsserver daemon describe diff diff-files diff-index diff-tree \
+ difftool difftool--helper fast-export fast-import fetch fetch-pack \
+ filter-branch fmt-merge-msg for-each-ref format-patch fsck fsck-objects \
+ gc get-tar-commit-id grep hash-object help http-backend http-fetch \
+ http-push imap-send index-pack init init-db instaweb interpret-trailers \
+ log ls-files ls-remote ls-tree mailinfo mailsplit merge merge-base \
+ merge-file merge-index merge-octopus merge-one-file merge-ours \
+ merge-recursive merge-resolve merge-subtree merge-tree mergetool \
+ mktag mktree mv name-rev notes p4 pack-objects pack-redundant \
+ pack-refs patch-id prune prune-packed pull push quiltimport read-tree \
+ rebase receive-pack reflog relink remote remote-ext remote-fd \
+ remote-ftp remote-ftps remote-http remote-https remote-testsvn \
+ repack replace request-pull rerere reset rev-list rev-parse revert \
+ rm send-email send-pack sh-i18n--envsubst shell shortlog show \
+ show-branch show-index show-ref stage stash status stripspace \
+ submodule submodule--helper svn symbolic-ref tag unpack-file \
+ unpack-objects update-index update-ref update-server-info upload-archive \
+ upload-pack var verify-commit verify-pack verify-tag web--browse \
+ whatchanged worktree write-tree)/'
+
+## hg
+complete hg 'p/1/(add addremove annotate archive backout bisect \
+ bookmarks branch branches bundle cat clone commit config copy diff \
+ export files forget graft grep heads help identify import incoming \
+ init log manifest merge outgoing paths phase pull push recover \
+ remove rename resolve revert root serve status summary tag tags \
+ unbundle update verify version)/'
+
+## nmh
+complete ali 'p;*;`ali | awk -F : \'/:/ { print $1 }\'`;'
+complete anno 'c/+/`folders -fast`/'
+complete burst 'c/+/`folders -fast`/'
+complete comp 'c/+/`folders -fast`/'
+complete dist 'c/+/`folders -fast`/'
+complete flist 'c/+/`folders -fast`/'
+complete folder 'c/+/`folders -fast`/'
+complete forw 'c/+/`folders -fast`/'
+complete inc 'c/+/`folders -fast`/'
+complete mark 'c/+/`folders -fast`/'
+complete mhl 'c/+/`folders -fast`/'
+complete mhn 'c/+/`folders -fast`/'
+complete mhpath 'c/+/`folders -fast`/'
+complete next 'c/+/`folders -fast`/'
+complete packf 'c/+/`folders -fast`/'
+complete pick 'c/+/`folders -fast`/'
+complete prev 'c/+/`folders -fast`/'
+complete rcvstore 'c/+/`folders -fast`/'
+complete refile 'c/+/`folders -fast`/'
+complete repl 'c/+/`folders -fast`/'
+complete rmf 'c/+/`folders -fast`/'
+complete rmm 'c/+/`folders -fast`/'
+complete scan 'c/+/`folders -fast`/'
+complete send 'c/+/`folders -fast`/'
+complete show 'c/+/`folders -fast`/'
+complete sortm 'c/+/`folders -fast`/'
+complete whatnow 'c/+/`folders -fast`/'
+complete whom 'c/+/`folders -fast`/'
+
+## pass
+complete pass 'p/1/(init ls find show grep insert edit generate rm \
+ mv cp git help version)/' \
+ 'n:edit:`pass ls | awk \'NR > 1 { print $2 }\'`:' \
+ 'n:ls:`pass ls | awk \'NR > 1 { print $2 }\'`:' \
+ 'n:show:`pass ls | awk \'NR > 1 { print $2 }\'`:'
+
+## surfraw
+complete {s,surfraw} 'p:*:`surfraw -elvi | awk \'/--/ { print $1 }\' ; bookmarks list | cut -f 1`:'
diff -r e6226a80fcfd -r 663f56665e41 tcshrc
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/tcshrc Sun Sep 23 23:08:37 2018 +0200
@@ -0,0 +1,140 @@
+bindkey -v
+bindkey \ magic-space
+bindkey -a \ magic-space
+bindkey -b ^T run-help
+bindkey -b ^Z run-fg-editor
+bindkey -b -c ^N noice
+bindkey -a -b ^T run-help
+bindkey -a -b -c ^N noice
+
+set autolist
+set backslash_quote
+set echo_style = both
+set editors = (vi less noice pvi)
+set histlit
+set prompt = "%B%#%b "
+set prompt2 = "... "
+set promptchars = %#
+set rprompt = "%U%c3%u"
+set vimoveback # XXX: experimental!
+
+alias helpcommand '( man -h \!:1 > /dev/tty ) >& /dev/null'
+
+source ~/.tcsh.complete
+
+#
+# ~/.tcshrc.private does not contain actually anything particularly private
+# but also not so interesting in general!
+#
+# send-pr(1) variables: NAME, ORGANIZATION, REPLYTO
+# pkgtools/url2pkg: PKGMAINTAINER
+# wu variables: WU_APIKEY, WU_CITY
+# statusbar variables: STATUSBAR_*
+# t variables: T_TODO_FILE, T_DONE_FILE
+#
+source ~/.tcshrc.private
+
+# PATH
+setenv PATH ${HOME}/bin:/bin:/sbin:/usr/bin:/usr/sbin:/usr/X11R7/bin:/usr/pkg/bin
+setenv PATH ${PATH}:/usr/pkg/sbin:/usr/games:/usr/local/bin:/usr/local/sbin
+
+# Other useful variables
+setenv EDITOR vi
+setenv LESS '-m -R'
+setenv LESSHISTFILE -
+setenv PAGER less
+
+# locale(1) setenvtings
+setenv LANG "en_US.UTF-8"
+
+# wtf(6)
+setenv ACRONYMDB "/usr/share/misc/acronyms /usr/share/misc/acronyms-o /usr/share/misc/acronyms.comp ${HOME}/.acronyms"
+
+# mail/nmh
+setenv MHTMPDIR /tmp
+
+# Perl-ish stuffs
+setenv PERL_BADLANG 0
+setenv PERL_LWP_ENV_PROXY 1
+
+# Python-ic stuffs
+#setenv PYTHONSTARTUP "${HOME}/.pythonrc"
+
+# nethack setenvtings
+setenv NETHACKOPTIONS '\!autopick,color'
+
+setenv PKGSRCDIR /usr/pkgsrc
+
+# chicken-doc
+setenv CHICKEN_DOC_REPOSITORY "${HOME}/.eggs/share/chicken/chicken-doc"
+setenv CHICKEN_DOC_COLORS auto
+setenv CHICKEN_DOC_WRAP 80
+
+# xdg-open (XXX: this hack is needed in order to avoid disturbing dbus-daemon)
+setenv XDG_CURRENT_DESKTOP X-Generic
+setenv BROWSER www-browser
+
+setenv XDG_CACHE_HOME "/tmp/.xdg-${USER}/.cache"
+
+setenv SXHKD_SHELL "/bin/sh"
+
+# password-store stuffs
+setenv PASSWORD_STORE_X_SELECTION "primary"
+
+# alias-es
+alias ag "ag --nocolor"
+alias cal "cal -d 1"
+#alias cdwrk "[ -d '../../pkgsrc' ] && set wrkdir = `make show-var VARNAME=WRKSRC` && cd $wrkdir"
+alias gdb "gdb -q"
+alias googler "googler -n 7"
+alias jq "jq -M"
+alias pdfgrep "pdfgrep --color never"
+alias sh "sh -V"
+alias theme-light "printf '\033[?5h'"
+alias theme-dark "printf '\033[?5l'"
+alias rprompt-on 'set rprompt = "%U%c3%u"'
+alias rprompt-off 'set rprompt = ""'
+
+# single letter aliases
+alias a ag
+alias b bg
+alias e ${EDITOR}
+alias f fg
+alias j jobs
+alias J "[ -f ~/.journal.txt ] && ${EDITOR} -c $ ~/.journal.txt"
+alias h history
+alias l ls-F
+alias n noice
+alias o plumb
+alias p ${PAGER}
+alias s surfraw
+alias T todo.sh
+
+# two letters aliases
+alias xi xclip -i
+alias xo xclip -o
+alias xu 'printf "" | xclip -f | xclip -f -selection clipboard | xclip -f -selection secondary'
+
+# three letters aliases
+alias xic xclip -i -selection clipboard
+alias xoc xclip -o -selection clipboard
+
+if ( $term == emacs ) then
+ # Emacs, or - better - `:script' in vi!
+ unset rprompt
+ setenv PAGER catless
+else if ( $?TMUX ) then
+ # XXX: Kludge to reset #{pane_title} for tmux
+ echo -n "\e]0;\a" > /dev/tty
+ alias cwdcmd 'echo -n "\e]0;${cwd:s;'${HOME}';~;}/\a" > /dev/tty'
+endif
+
+# Start ssh-agent(1)
+if ((! $?SSH_AGENT_PID) && (! $?SSH_TTY )) then
+ eval `ssh-agent -c` > /dev/null
+endif
+
+# Needed by gpg-agent (needs security/gnupg2)
+setenv GPG_TTY `tty`
+
+set printexitvalue