PCLfile:		Top_level
                        Top_level {;} <PCL-file>

<Top-level>             ::= <Command-declaration>
                        ::= <Procedure-declaration>
                        ::= <Variable-declaration>

<Command-declaration>   ::= <Command-head> ; <Procedure-body>
<Command-head>          ::= COMMAND <Identifier>
                        ::= COMMAND <Identifier>
                                        ( <Command-argument-list> )
<Command-argument-list> ::= <Command-argument>
                        ::= <Command-argument> ; <Command-argument-list>
<Command-argument>      ::= <Field-specification>
                        ::= <Field-specification> : <Identifier>

<Procedure-declaration> ::= <Procedure-head> ; <Procedure-body>
                        ::= <Simple-type> <Procedure-head> ;
                                <Procedure-body>
<Procedure-head>        ::= PROCEDURE <Identifier>
                        ::= PROCEDURE <Identifier> (<Formal-parm-list>)

<Procedure-body>        ::= <Block>
<Formal-parm-list>      ::= <Simple-type> <Id-list>
                        ::= <Simple-type> <Id-list> ; <Formal-parm-list>

<Block>                 ::= <Block-head> <Compound-tail>
<Block-head>            ::= BEGIN { <Declaration-list> ; }
<Declaration-list>      ::= <Declaration>
                        ::= <Declaration> ; <Declaration-list>
<Compound-statement>    ::= BEGIN <Compound-tail>
<Compound-tail>         ::= <Statement-list> { ; } END
                        ::= END
<Statement-list>        ::= <Statement>
                        ::= <Statement> ; <Statement-list>

8.2. Declaration BNF

<Declaration>           ::= <Variable-declaration>
                        ::= <External-procedure-declaration>
                        ::= EXTERNAL <Variable-declaration>
<Variable-declaration>  ::= <Simple-type> <Id-list>
<Simple-type>           ::= INTEGER
                        ::= STRING
<Id-list>               ::= <Identifier>
                        ::= <Identifier> , <Id-list>
<External-procedure-declaration>
                        ::= EXTERNAL PROCEDURE <Id-list>
                        ::= EXTERNAL <Simple-type> PROCEDURE <Id-list>


8.3. Statement BNF
<Statement>             ::= <Compound-statement>
                        ::= <Assignment-statement>
                        ::= <Conditional-statement>
                        ::= <Go-to-statement>
                        ::= <Do-statement>
                        ::= <Case-statement>
                        ::= <Select-statement>
                        ::= <Return-statement>
                        ::= <Exit-statement>
                        ::= <Procedure-statement>
                        ::= <Parse-statement>
                        ::= <Command-statement>
                        ::= <Program-statement>
                        ::= <No-op-statement>
                        ::= <Label> : <Statement>

<Assignment-statement>  ::= LET <Identifier> = <Expression>
                        ::= <Identifier> = <Expression>
<Conditional-statement> ::= <If-statement>
                        ::= <If-statement> ELSE <Statement>
<If-statement>          ::= IF <Logical-expression> THEN <Statement>
<Go-to-statement>       ::= GOTO <Label-identifier>
<Do-statement>          ::= DO <Statement> WHILE <Logical-expression>
                        ::= WHILE <Logical-expression> DO <Statement>
<Case-statement>        ::= <Case-head> { <Tagged-statement-list> {;} } END
<Case-head>             ::= CASE <Integer-expression>
                                FROM <Integer-constant>
                                TO <Integer-constant> OF BEGIN
<Tagged-statement-list> ::= <Tagged-statement>
                        ::= <Tagged-statement> ; <Tagged-statement-list>
<Tagged-statement>      ::= <Integer-constant> : <Statement>
                        ::= INRANGE : <Statement>
                        ::= OUTRANGE : <Statement>
<Select-statement>      ::= <Select-head> { <Expr-statement-list> {;} } END
<Select-head>           ::= SELECT <Expression> OF BEGIN
<Expr-statement-list>   ::= <Expr-statement>
                        ::= <Expr-statement> ; <Expr-statement-list>
<Expr-statement>        ::= <Expression> : <Statement>
                        ::= OTHERWISE : <Statement>
<Return-statement>      ::= RETURN
                        ::= RETURN <Expression>
<Exit-statement>        ::= EXIT
                        ::= EXIT SAVE
                        ::= EXIT TOPROGRAM
                        ::= ABORT <String-expression>
<Procedure-statement>   ::= CALL <Procedure-Identifier>
                        ::= CALL <Procedure-Identifier> (<Actual-parms>)
<No-op-statement>       ::= NOP

8.4. Parse BNF
<Parse-statement>       ::= GUIDE <String-constant>
                        ::= PROMPT <String-constant>
                        ::= PROMPT NOECHO <String-constant>
                        ::= PARSE <Field-specification>
                        ::= PARSE BEGIN <Parse-field-list> END
<Parse-field>           ::= <Field-specification> [ : <Statement> ]
                        ::= OTHERWISE : <Statement>
<Parse-field-list>      ::= <Parse-field>
                        ::= <Parse-field> ; <Parse-field-list>
<Field-specification>   ::= <Field-type>
                        ::= <Field-type> ( <Field-option-list> )
<Field-type>            ::= KEYWORD
                        ::= SWITCH
                        ::= NUMBER
                        ::= NOISE <String-constant>
                        ::= INPUTFILE
                        ::= OUTPUTFILE
                        ::= FILE
                        ::= FIELD
                        ::= EOL        (not available as command argument)
                        ::= DIRECTORY
                        ::= USERNAME
                        ::= COMMA
                        ::= DEVICE
                        ::= TEXT
                        ::= DAYTIME
                        ::= QUOTEDSTRING
                        ::= TOKEN <String-constant>
                        ::= NODE
                        ::= FILELIST
<Field-option-list>     ::= <Field-option> { , <Field-option> }
<Field-option>
                        ::= DEFAULT <String-primary>
                        ::= HELP <String-primary>
                        ::= PARSEONLY
                        ::= NOHELP
                        ::= STDHELP
                        ::= NOINDIRECT
                        ::= INPUT
                        ::= OUTPUT
                        ::= INVISIBLE
                        ::= DELETED
                        ::= WILD
                        ::= DEFAULT_DEV <String-primary>
                        ::= DEFAULT_DIR <String-primary>
                        ::= DEFAULT_NAM <String-primary>
                        ::= DEFAULT_EXT <String-primary>
                        ::= DEFAULT_GEN <Code>
                              The codes are 0 (highest generation), + (next
                              generation), - (first generation), * (all
                              generations), or a generation number.
                        ::= RADIX <Integer-constant>
                        ::= WORDS ( <Word-list> )
                        ::= TIME
                        ::= DATE
                        ::= ERROR <Label-identifier>
<Word-list>             ::= <Word-definition>
                        ::= <Word-definition> , <Word-list>
<Word-definition>       ::= <Identifier> : <Integer-constant>
                        ::= <Integer-constant> : <Integer-constant>
                        ::= <Identifier> :: <Integer-constant>
                        ::= <Integer-constant> :: <Integer-constant>

8.5. Command Statement BNF
<Command-statement>     ::= DOCOMMAND <String-expression> <Command-option>
                        ::= DOCOMMAND ORIGINAL <String-expression>
                                <Command-option>
<Command-option>        ::= <empty>
                        ::= TO <String-identifier> <Command-option>

8.6. Program Statement BNF
<Program-statement>     ::= INVOKE <String-expression>
                        ::= INVOKE PASSOUTPUT <String-expression>
                        ::= KILLPROGRAM
                        ::= TYPEIN <String-expression>
                        ::= TYPEIN NORETURN <String-expression>
                        ::= GETTYPEOUT <String-identifier>
                        ::= CLEARTYPEOUT
                        ::= DISPLAY <String-expression>
                        ::= DISPLAY NORETURN <String-expression>
                        ::= DISPLAY BINARY <String-expression>

8.7. Expression BNF
<Logical-expression>    ::= <Relational-expression>
<Relational-expression> ::= <Integer-expression> <Relational-operator>
                                <Integer-expression>
                        ::= <String-expression> <Relational-operator>
                                <String-expression>
<Relational-operator>   ::= <
                        ::= =
                        ::= >
                        ::= <=
                        ::= <>
                        ::= >=

<Expression>            ::= <Integer-expression>
                        ::= <String-expression>

<Integer-expression>    ::= <Term>
                        ::= <Term> <Add-operator> <Term>
<Add-operator>          ::= +
                        ::= -
<Term>                  ::= <Integer-primary>
                        ::= <Integer-primary> <Mult-operator> <Term>
<Mult-operator>         ::= *
                        ::= /
<String-expression>     ::= <String-primary>
                        ::= <String-primary> + <String-expression>
<Integer-primary>       ::= <Integer-identifier>
                        ::= - <Integer-primary>
                        ::= <Integer-constant>
                        ::= <Procedure-call>
                        ::= ( <Integer-expression> )
<String-primary>        ::= <String-identifier>
                        ::= <String-constant>
                        ::= <Procedure-call>
                        ::= <String-primary>
                               [ <Integer-expression> :
                               <Integer-expression> ]
                        ::= <String-primary>
                               [ <Integer-expression> : * ]
<Procedure-call>        ::= <Procedure-identifier>
                        ::= <Procedure-identifier> ( Actual-parms> )
<Actual-parms>          ::= <Expression>
                        ::= <Expression> , <Actual-parms>

8.8. Identifier BNF
<Integer-identifier>    ::= <Identifier>
                        ::= <System-variable-identifier>
<String-identifier>     ::= <Identifier>
                        ::= <System-variable-identifier>
<Procedure-identifier>  ::= <Identifier>
<Label-identifier>      ::= <Identifier>
<Identifier>            ::= <Alphabetic>
                        ::= <Identifier> <Alphanumeric>
                        ::= <Identifier> _ <Alphanumeric>
<Integer-constant>      ::= <Decimal>
                        ::= <Decimal-constant> <Decimal>
<String-constant>       ::= {sequence of characters enclosed by double-
                             quotes; double-quotes may be inserted in the
                             string by doubling them}


.