        SPARKWARE

:1ST /NONULL /FONT /DISPLAY:One moment please...

:START
        ASSIGN(_Default$,"48")
        CALL "@API$(5)LOGO.MDL"

:TOP
        DISPLAY OFF
        SCREEN(2,RESTORE)
        QPRINT("The customer support menu",4,35,True)
        QPRINT("Customer support BBS: (615) 230-8822",6,35,True)
        QPRINT("Internet address: help@sparkware.com",7,39,True)
        SCREEN(3,SAVE)

        CLEAR_BOXES
        DIALOG_BOX(1,1,49,1,"1",12,5,112,112,1,116,15)
        QPRINT("View the @READER@ tutorial",12,11,True)
        DIALOG_BOX(2,1,50,2,"2",14,5,112,112,1,116,15)
        QPRINT("View the new user's guide",14,11,True)
        DIALOG_BOX(3,1,51,3,"3",16,5,112,112,1,116,15)
        QPRINT("View the @READER@ manual",16,11,True)
        DIALOG_BOX(4,1,52,4,"4",18,5,112,112,1,116,15)
        QPRINT("View the advanced user's guide",18,11,True)
        DIALOG_BOX(5,1,53,5,"5",20,5,112,112,1,116,15)
        QPRINT("View the programmer's guide",20,11,True)
        DIALOG_BOX(6,1,54,6,"6",22,5,112,112,1,116,15)
        QPRINT("View the telnet script guide",22,11,True)
        DIALOG_BOX(7,1,55,7,"7",18,46,112,112,1,116,15)
        QPRINT("Create a boot diskette",18,52,True)
        DIALOG_BOX(8,1,57,8,"8",20,46,112,112,1,116,15)
        QPRINT("Extra features",20,52,True)
        DIALOG_BOX(9,1,27,9,"Q",22,46,112,112,1,116,15)
        QPRINT("Quit & return to @READER@",22,52,True)

        DISPLAY ON
        GET(Choice$,1)

        ON Choice$ GOTO 1,2,3,4,5,6,7,8
        EXIT

:1
        IF EXIST "#1TUTOR.MDL" THEN
                CALL "#1TUTOR.MDL"
        ELSE
                ASSIGN(Description$,"@READER@ tutorial")
                GOSUB NotOnFile
        END IF
        GOTO START

:2
        ASSIGN(FileSpec$,"@API$(5)NOVICE.EXE")
        ASSIGN(Description$,"@READER@ new user's guide")
        GOSUB RunSpec
        GOTO TOP

:3
        ASSIGN(FileSpec$,"@API$(5)MANUAL.EXE")
        ASSIGN(Description$,"@READER@ manual")
        GOSUB RunSpec
        GOTO TOP

:4
        ASSIGN(FileSpec$,"@API$(5)ADVANCED.EXE")
        ASSIGN(Description$,"@READER@ advanced user's guide")
        GOSUB RunSpec
        GOTO TOP

:5
        ASSIGN(FileSpec$,"@API$(5)1ST-PROG.EXE")
        ASSIGN(Description$,"@READER@ programmer's guide")
        GOSUB RunSpec
        GOTO TOP

:6
        ASSIGN(FileSpec$,"@API$(5)SCRIPT.EXE")
        ASSIGN(Description$,"@READER@ telnet script guide")
        GOSUB RunSpec
        GOTO TOP

:7
        IF EXIST "BOOTDISK.MDL" THEN
                CALL "BOOTDISK.MDL"
        ELSE
                ASSIGN(Description$,"Create a boot diskette")
                GOSUB NotOnFile
        END IF
        GOTO START

:8
        IF EXIST "$$EXTRA.MDL" THEN
                CALL "$$EXTRA.MDL"
                IF NOT COMPARE(@API$(106),"") THEN EXIT
        ELSE
                ASSIGN(Description$,"Extra features")
                GOSUB NotOnFile
        END IF
        GOTO START

:RUNSPEC
        IF EXIST FileSpec$ THEN
                ASSIGN(Cmd$,FileSpec$+"/SS /SCRNSAVE")
                SHELL Cmd$
        ELSE
                GOSUB NotOnFile
        END IF
        RETURN

:NOTONFILE
        SCREEN(3,RESTORE)
        BOX(12,10,18,70,112,112,1,1)
        QPRINT("Sorry, but @READER@ could not locate",14,-1,112)
        QPRINT(Description$,16,-1,112)
        PAUSE 10
        RETURN

