*********************    ***********************  
      ******      .                              .  ******
     ****     .  .   .  Init & Exit code     .   "     **** 
    ***   '         .   """"""""""""""""             .   *** 
    **  .  .    . .                        .  "  . .      ** 
    **       "       written in a hurry for     . .       ** 
    ***  .  :   . .  """"""""""""""""""""""        .     *** 
     ****          #Amycoders' starfield compo      by **** 
      ******    .  """""""""""""""""""""""""""      morbid  
        *********************    ***********************   

;==== 3d starfield code by kaneda / grasshopper d ====
;== completed in a rush.. damn ! someone took my net axs away :(
;== uses 8 bit co-ordinates.. oops ;)
;== no time to fix..
                
        bsr     CloseWB         ; Flush view and disable multitasking
        bsr     OpenScreen      ; Set pointers and sync

        jsr     Starfield_init  ;Init starfield
        
**
************************************************************
************************************************************
**
**                    >>> M A I N <<<
**



        


Main    btst    #6,$bfe001
        beq     Exit
        
.wa      btst	#2,$dff016
        beq.s	.wa
        
        
************************************************************


        bsr     DisplayScreen
        jsr     Starfield       ;call starfield (a0=Bitplane)
        bra     Main




        
**
************************************************************
**
**      Flush view & disable system
**


CloseWB

        movea.l 4.w,a6          ; exec base
        jsr     -132(a6)        ; Forbid
        jsr     -120(a6)        ; Disable
        lea     GfxName(pc),a1  ; graphics.library
        moveq   #0,d0           ; whatever verision
        jsr     -552(a6)        ; open it !
        move.l  d0,GfxBase      ; store gfxbase
        movea.l d0,a6           ; gfxbase in a6
        move.l  $22(a6),OldView ; store system view
        move.l  $26(a6),OldCop  ; store system copper
        sub.l   a1,a1
        jsr     -222(a6)        ; flush view (LoadView)
        jsr     -270(a6)        ; WaitTOF
        jsr     -270(a6)        ; twice for interlaced views
        move.w  $dff002,OldDMAcon   ; store old dma control register
        ori.w   #$8000,OldDMAcon  ; set bit #15
        move.w  #$7fff,$dff096
        move.w  #$8380,$dff096
        rts
        
        
GfxName dc.b 'graphics.library',0
        even
GfxBase dc.l 0
OldView dc.l 0
OldCop  dc.l 0
OldDMAcon dc.w 0

        cnop 0,4

**
*************************************************************
**
**      Display Screen
**

DisplayScreen

        movem.l d0-d1,-(sp)
        move.b  $bfe801,d0
.wait   cmp.b   $bfe801,d0
        beq.b   .wait
        
        move.l  screen_logical(pc),d0
        move.l  screen_physical(pc),screen_logical
        move.l  d0,screen_physical

        lea     copper_bpl,a0
        move.w  d0,6(a0)                ; lower part of bpl address
        swap    d0
        move.w  d0,2(a0)                ; higher word

        movea.l screen_logical(pc),a0   
        moveq   #0,d0
        move.l  #(320/32)*256-1,d1
.clear  move.l  d0,(a0)+                ; clear logical screen
        dbf     d1,.clear
        lea     -(320/8)*256(a0),a0     
        
        movem.l (sp)+,d0-d1
        rts


screen_physical dc.l 0
screen_logical dc.l 0

        
**
*************************************************************
**
**      Open Screen
**

OpenScreen
        
        lea     $dff000,a5
        move.l  #Copper,$80(a5)
        
        move.w  #$2c81,$08e(a5)         ; display window start pos
        move.w  #$2cc1,$090(a5)         ; display window stop pos
        move.w  #$0038,$092(a5)         ; data fetch start pos
        move.w  #$00d0,$094(a5)         ; data fetch stop pos

        move.l  #ScreenA,screen_logical
        move.l  #ScreenB,screen_physical
        bsr     DisplayScreen
        
        rts
        
**
**************************************************************
**
**      Open WB 
**

Exit
        lea     $dff000,a5
        move.w  #$7fff,$96(a5)          ; clear dmacon
        move.w  OldDMAcon(pc),$96(a5)   ; set old bits
        move.l  GfxBase(pc),a6          ; gfxbase in a6
        move.l  OldCop(pc),$80(a5)      ; restart old copperlist
        move.l  OldView(pc),a1
        jsr     -222(a6)                ; Load system view
        
        move.l  a6,a1
        move.l  4.w,a6
        jsr     -414(a6)                ; close graphics.library
        jsr     -126(a6)                ; Enable
        jsr     -138(a6)                ; Permit
        
        rts
        
        

************************************************************************

        section screens,bss_c
        
ScreenA ds.b (320*256)/8
ScreenB ds.b (320*256)/8

************************************************************************

        section copperlist,data_c

        
Copper  dc.l $01001000  ; bplcon0
        dc.l $01080000  ; bpl1mod
        dc.l $010a0000  ; bpl2mod
        dc.l $01800000  ; colour 0 = black
        dc.l $01820fff  ; colour 1 = white
                
copper_bpl
        dc.l $00e00000  ; bpl1pth
        dc.l $00e20000  ; bpl1ptl


        dc.l $fffffffe


**************************************************************************
**************************************************************************
**
**
**  Your starfield code starts here
**
**
**************************************************************************
**************************************************************************

num_stars	equ	512

        section code,code       ;put your code here

*********************************************
** Do all initialisations here
*********************************************

Starfield_init:
a	lea	Table+(num_stars*3*2),a1
	move.w	#(num_stars*3)-1,d7

boop	move.l	6(a7),d0 ; Main,d0
	move.l	a1,d1
iloop	move.b	d1,-(a1)
	subq.l	#1,a1
	ror.l	d1,d0
	ror.l	d2,d1
	eor.l	d0,d1
	dbra	d7,iloop

b
        rts

*********************************************
** This routine is called once a frame
**
** The destination Bitplane is given in a0
*********************************************

c
offscreen	moveq #3-1,d7	;x, y and z
		bsr.s boop	;randomize
		bra.s	loop

Starfield:

	move.w	#num_stars-1,d4
	lea	Table+1,a1
loop	movem.w	(a1)+,d0-d2
	lsr.w	#8,d2
	muls.w	d2,d0
	swap	d0
	muls.w	d2,d1
	swap	d1

	;-- center on screen, & clip

	move.w	#160,d2
	move.w	#128,d6

	cmp.w	d2,d0
	bge.s	offscreen
	cmp	d6,d1
	bge.s	offscreen
	
	add.w	d2,d0
	bmi.s	offscreen
	add.w	d6,d1
	bmi.s	offscreen

	;-- turn co-ords to pixel on screen
	ext.l	d0
	mulu.w	#40,d1
	bfset	(a0,d1.w){d0:1}
	addq.b	#2,-2(a1)
.skip	dbra	d4,loop
d
	rts


	printt "Length of code:"
	printv ((b-a)+(d-c))

        section bss,bss         ;put your tables heres
Table:	ds.w	3*num_stars


.