PL/0-Syntax
-----------

In der EBNF-Systematik laesst sich die Syntax von PL/0 wie folgt
beschreiben:


program =    block "." .

block =      [ "const" ident "=" number { "," ident "=" number } ";" ]
             [ "var" ident { "," ident } ";" ]
             statement .

statement =  [ ident ":=" expression |
               "begin" statement { ";" statement } "end" |
               "if" condition "then" statement [ "else" statement ] |
               "while" condition "do" statement |
               "repeat" statement "until" condition |
               "write" expression { "," expression } ] .

condition =  expression
             ( "=" | "<>" | "<" | "<=" | ">" | ">=" )
             expression .

expression = term { ( "+" | "-" ) term } .

term =       factor { ( "*" | "/" ) factor } .

factor =     ident | number | "(" expression ")" .


Im Vergleich zum Original von N. Wirth fehlen Prozeduren (bei "block"),
die Vorzeichen-Option bei "expression" und die Funktion "odd" bei
"condition".