10 11 12 13 2008 2009 2010 1 captures 13 11 09 - 13 11 09

Close Help

URL and HTML entities

The following table was created entirely with Perl, using CGI.pm and several other modules. The program listing is at the bottom.

The above table was generated by the following program:

#!C:/perl/bin/perl.exe -w
# Please note that the taint switch (-T) is not used here as this is NOT
# a CGI program.  CGI.pm is merely used for its HTML generating functions.
use strict;

# This allows us to escape characters properly for query strings
use URI::Escape;

# This can be used to generate HTML character codes.
use HTML::Entities;

# Since this is a command line program, we don't want to be forced to
# enter name=value pairs.  Therefore, we use qw/:no_debug/
use CGI::Pretty qw/:no_debug/;
$CGI::Pretty::INDENT = "\t";

my $q = CGI->new();

# The logic is simple:  create the table data, read the source code, and use
# them to create the web page.  We could have done all of this without subroutines,
# but this allows us to revisit this program easily in the future and extend its
# functionality.  For many, this is a matter of personal preference.


# characters which must be encoded in query strings:
my $cgi_chars = '\x00-\x29\x2b\x2c\x2f\x3a-\x40\x5b-\x5e\x60\x7b-\xff';

# characters which often have their HTML character code equivalent used instead:
my $html_chars = '\x00-\x2f\x3a-\x40\x5b-\x5e\x60\x7b-\xff';

my $bit = 1;

sub row
{
	my $cell_method = shift;
	$q->Tr(
		{
			-align => 'right',
			-bgcolor => ('#FFFFFF','#CCCCCC')[ $bit ^= 1 ], # a flipping bit
		},
		$q->$cell_method( \@_ )
	)
}

my $outfile = "appendix2.html";
open OUT, '>', $outfile or die "Error opening $outfile for writing: $!\n";
print OUT $q->table(
	row( 'th', # header row
		'Symbol',
		'ASCII Value',
		'URL encoded',
		'HTML code'
	),
	map
	{
		my $char = chr $_; # The actual character
		my $symbol = encode_entities( $char, $html_chars ); # HTML code for web page
		my $escaped = uri_escape( $char, $cgi_chars ); # CGI representation
		my $html_code = encode_entities( $symbol ); # Re-encode HTML code so that it displays properly
		$escaped eq '%20' and $escaped .= ' or +'; # a space may be %20 or a +

		row( 'td',
			$_ < 33 ? '&nbsp;' : $symbol,
			$_,
			$escaped,
			$html_code
		)
	}
	0 .. 255
);
close OUT;