         PROCEDURE MGUI2900                                                     
                                                                                
***********************************************************************         
* PROCEDURE:  MGUI2900                                                *         
* AUTHOR:     JMC                                                     *         
* TITLE:      SMS WIP/SCS Item Inquiry                                *         
* REMARKS:    This procedure will allow the user to inquire upon      *         
*             ITEMMAST and /or SECCOST                                *         
*                                                                     *         
*---------------------------------------------------------------------*         
*                            MODIFICATIONS                            *         
* VER WHO   DATE   WHY                                                *         
* --- --- -------- -------------------------------------------------- *         
* 03  JMC 09/23/92 Removed VS-9 processing, system no longer exists   *         
* 02  JMC 06/07/91 Added special VS-9 processing, this will try to    *         
*                  find MG2900 on VS-9                                *         
* 01  JMC 03/07/90 Procedure will bypass SECCOST processing when      *         
*                  SECCOST is not found                               *         
* 00  JMC 03/09/88 Original Version                                   *         
*                                                                     *         
***********************************************************************         
                                                                                
          DECLARE &FIRST_SCREEN_DISPLAYED as String (01) Initial "0"            
                  [ 0 = display SMS WIP Screen first ]                          
                  [ 1 = display SECCOST Screen first ]                          
                  [ 2 = No SECCOST Screen, access SMS WIP screen ONLY ]         
                                                                                
***** Other Declares                                                            
          DECLARE &SYSTEM_VOL         as String (06) Initial " "                
                                                                                
***** SECCOST Declares                                                          
          DECLARE &SECCOST_FILE       as String (08) Initial " "                
          DECLARE &SECCOST_LIB        as String (08) Initial " "                
          DECLARE &SECCOST_VOL        as String (08) Initial " "                
                                                                                
***** BADEND Declares                                                           
          DECLARE &BADEND_APPLICATION as String (06) Initial "FSU   "           
          DECLARE &BADEND_PROCEDURE   as String (08) Initial "MGUI2900"         
          DECLARE &BADEND_RETURN_CODE as Integer     Initial 0                  
          DECLARE &BADEND_RERUN_SW    as String (01) Initial " "                
          DECLARE &BADEND_RESTORE_SW  as String (01) Initial " "                
                                                                                
***********************************************************************         
* STEP01 -- MU5350, Get Locations of files needed                     *         
***********************************************************************         
STEP01:   RUN MU5350                                                            
               ENTER CATGET CATNAME = FPSULOAD                                  
     FPSULOAD: ENTER LOCATION                                                   
               ENTER CATGET CATNAME = FPSUPROC                                  
     FPSUPROC: ENTER LOCATION                                                   
               ENTER CATGET CATNAME = ITEMMAST                                  
     ITEMMAST: ENTER LOCATION                                                   
               ENTER CATGET CATNAME = MG10151S                                  
     MG10151S: ENTER LOCATION                                                   
               ENTER CATGET                                                     
                                                                                
          IF STEP01 = 0 GOTO STEP01z                                            
                                                                                
          ASSIGN &BADEND_RETURN_CODE = 1000 + STEP01                            
          GOTO   BADEND                                                         
                                                                                
STEP01z:  [ Continue ]                                                          
                                                                                
***********************************************************************         
* STEP02 -- MU5350, Get Locations of files needed                     *         
***********************************************************************         
STEP02:   RUN MU5350                                                            
               ENTER CATGET CATNAME = SECCOST                                   
     SECCOST:  ENTER LOCATION                                                   
               ENTER CATGET                                                     
                                                                                
          IF STEP02 = 0 GOTO STEP02y                                            
                                                                                
          ASSIGN &FIRST_SCREEN_DISPLAYED = "2"                                  
          GOTO   STEP02z                                                        
                                                                                
STEP02y:  ASSIGN &SECCOST_FILE = (SECCOST.FILE)                                 
          ASSIGN &SECCOST_LIB  = (SECCOST.LIBRARY)                              
          ASSIGN &SECCOST_VOL  = (SECCOST.VOLUME)                               
          IF     EXISTS FILE (SECCOST) GOTO STEP02z                             
          ASSIGN &FIRST_SCREEN_DISPLAYED = "2"                                  
                                                                                
STEP02z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP03 -- Will make sure files exist                                *         
***********************************************************************         
STEP03:   IF EXISTS FILE (ITEMMAST) GOTO STEP03a                                
                                                                                
          ASSIGN &BADEND_RETURN_CODE = 3001                                     
          GOTO   BADEND                                                         
                                                                                
STEP03a:  IF EXISTS FILE (MG10151S) GOTO STEP03b                                
                                                                                
          ASSIGN &BADEND_RETURN_CODE = 3002                                     
          GOTO   BADEND                                                         
                                                                                
STEP03b:  EXTRACT &SYSTEM_VOL = SYSVOL                                          
                                                                                
STEP03z:  [ Continue ]                                                          
                                                                                
***********************************************************************         
* STEP05 -- MG2900, ITEMMAST/SECCOST Inquiry                          *         
***********************************************************************         
STEP05:   RUN MG2900 in (FPSULOAD.LIBRARY) on (FPSULOAD.VOLUME)                 
               ENTER ACCEPT   WSPROCS = &FIRST_SCREEN_DISPLAYED                 
               ENTER ITEMMAST (ITEMMAST)                                        
               ENTER MG10151S (MG10151S)                                        
               ENTER SECCOST  FILE       = &SECCOST_FILE,                       
                              LIBRARY    = &SECCOST_LIB,                        
                              VOLUME     = &SECCOST_VOL                         
                                                                                
          IF STEP05 = 0 GOTO STEP05z                                            
                                                                                
          ASSIGN &BADEND_RETURN_CODE = STEP05 + 5000                            
          GOTO   BADEND                                                         
                                                                                
STEP05z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* EOJ -- End of Job                                                   *         
***********************************************************************         
EOJ:     RETURN                                                                 
                                                                                
***********************************************************************         
* BADEND --  Abnormal end of job, will execute if there is a return   *         
*            code.                                                    *         
***********************************************************************         
BADEND:   RUN MGRB2005 in (FPSUPROC.LIBRARY) on (FPSUPROC.VOLUME)               
                       USING &BADEND_APPLICATION,                               
                             &BADEND_PROCEDURE,                                 
                             &BADEND_RETURN_CODE,                               
                             &BADEND_RERUN_SW,                                  
                             &BADEND_RESTORE_SW                                 
              CANCEL EXIT is BADEND                                             
              ERROR  EXIT is BADEND99                                           
                                                                                
BADEND99: RETURN CODE = &BADEND_RETURN_CODE                                     
                                                                                
************** ####### END OF PROCEDURE MGUI2900 ####### *************          
