         PROCEDURE MGUI2700                                                     
                                                                                
***********************************************************************         
* PROCEDURE:  MGUI2700                                                *         
* AUTHOR:     JMC                                                     *         
* TITLE:      Manufacturing/Finance Utilities                         *         
* REMARKS:    This procedure will Allow the user to maintain the      *         
*                  Parameter File (MG27001I) and                      *         
*             Parameter Cross Ref. File (MG27002A)                    *         
*                                                                     *         
*---------------------------------------------------------------------*         
*                            MODIFICATIONS                            *         
* VERSIOB  WHO  DATE    WHY                                           *         
* -------- --- -------- --------------------------------------------  *         
* 00.00.00 JMC 12/04/89 Original Version                              *         
*                                                                     *         
***********************************************************************         
                                                                                
          DECLARE &APPL_LITERAL        as String (40) Initial " "               
          DECLARE &PARM_FILE           as String (16) Initial " "               
          DECLARE &XREF_FILE           as String (16) Initial " "               
          DECLARE &MESSAGE             as String (79) Initial " "               
          DECLARE &USER_ID             as String (03) Initial " "               
          DECLARE &USER_ACCESS         as String (01) Initial " "               
          DECLARE &MG2700A_RECORDS     as String (07) Initial "0005000"         
          DECLARE &MG2700B_RECORDS     as String (07) Initial "0005000"         
          DECLARE &MG2700C_RECORDS     as String (07) Initial "0005000"         
          DECLARE &R_C                 as Integer     Initial 0                 
                                                                                
***** Initial EXTRACTS                                                          
          EXTRACT &USER_ID       = USERID                                       
                                                                                
***********************************************************************         
* STEP01 -- MU5350, Get Locations of files needed                     *         
***********************************************************************         
STEP01:   RUN MU5350                                                            
               ENTER CATGET CATNAME = MG27011I                                  
     MG27011I: ENTER LOCATION                                                   
               ENTER CATGET CATNAME = FPSULOAD  [ Object Code ]                 
     FPSULOAD: ENTER LOCATION                                                   
               ENTER CATGET                                                     
                                                                                
          IF STEP01 ne 0 RETURN CODE = STEP01 + 1000                            
                                                                                
***********************************************************************         
* STEP03 -- MG2701, Determine which Parm File to maintain             *         
***********************************************************************         
STEP03:   RUN MG2701 in (FPSULOAD.LIBRARY) on (FPSULOAD.VOLUME)                 
              using &APPL_LITERAL,                                              
                    &PARM_FILE,                                                 
                    &XREF_FILE,                                                 
                    &MESSAGE                                                    
               ENTER MG27011I (MG27011I)                                        
                                                                                
          IF STEP03 = 99 GOTO EOJ                                               
                                                                                
          IF STEP03 ne 0 RETURN CODE = STEP03 + 3000                            
                                                                                
***********************************************************************         
* STEP11 -- MU5350, Get Locations of files needed                     *         
***********************************************************************         
STEP11:   RUN MU5350                                                            
               ENTER CATGET CATNAME = &PARM_FILE                                
     MG27001I: ENTER LOCATION                                                   
               ENTER CATGET CATNAME = &XREF_FILE                                
     MG27002A: ENTER LOCATION                                                   
               ENTER CATGET                                                     
                                                                                
          IF STEP11 = 0 GOTO STEP11z                                            
                                                                                
          ASSIGN &MESSAGE = "Cat Entry for " !! &PARM_FILE(1,*) !!              
                            " and/or " !! &XREF_FILE(1,*) !!                    
                            " is invalid"                                       
          GOTO   STEP03                                                         
                                                                                
STEP11z:  [ Continue ]                                                          
                                                                                
***********************************************************************         
* STEP12 -- Set user access, '0' = no access, '1' = inquiry only      *         
*                            '2' = update access                      *         
***********************************************************************         
STEP12:   ASSIGN &USER_ACCESS = "2"                                             
                                                                                
***********************************************************************         
* STEP13 -- Will make sure files exist                                *         
***********************************************************************         
STEP13:   IF EXISTS FILE (MG27001I) GOTO STEP13A                                
                                                                                
          ASSIGN &MESSAGE = "Unable to find File " !! &PARM_FILE                
          GOTO   STEP03                                                         
                                                                                
STEP13A:  IF EXISTS FILE (MG27002A) GOTO STEP13B                                
                                                                                
          ASSIGN &MESSAGE = "Unable to find File " !! &XREF_FILE                
          GOTO   STEP03                                                         
                                                                                
STEP13B:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP14 -- MG2700, Maintain MG27001I & MG27002A                      *         
***********************************************************************         
STEP14:  RUN MG2700 in (FPSULOAD.LIBRARY) on (FPSULOAD.VOLUME)                  
               ENTER ACCEPT     USERID   = &USER_ID,                            
                                UACCESS  = &USER_ACCESS,                        
                                SPACEA   = &MG2700A_RECORDS,                    
                                SPACEB   = &MG2700B_RECORDS,                    
                                SPACEC   = &MG2700C_RECORDS,                    
                                WSAPPL   = &APPL_LITERAL                        
               ENTER MG27001I   (MG27001I)                                      
               ENTER MG27002A   (MG27002A)                                      
               ENTER MG2700A    FILECLAS = " "   [ File name &        ]         
               ENTER MG2700B    FILECLAS = " "   [ location MUST not  ]         
               ENTER MG2700C    FILECLAS = " "   [ be assigned by PROC]         
                                                                                
          IF STEP14 = 0 GOTO STEP14z                                            
                                                                                
          ASSIGN &R_C = STEP14                                                  
                                                                                
          ASSIGN &MESSAGE = "MG2700 abended, return Code = " !! &R_C            
                                                                                
STEP14z:  ASSIGN &MESSAGE = "Parameter Maintence for " !!                       
                            &APPL_LITERAL(1,*) !! " Complete"                   
          GOTO STEP03                                                           
                                                                                
***********************************************************************         
* EOJ -- End of Job                                                   *         
***********************************************************************         
EOJ:     RETURN                                                                 
                                                                                
************** ####### END OF PROCEDURE MGUI2700 ####### *************          
