          PROCEDURE MAUI2299                                                    
***********************************************************************         
* PROCEDURE: MAUI2299                                                 *         
*            PPV/REBNI File Backup/Restore                            *         
* AUTHOR:    JMC                                                      *         
* DATE:      Oct 17, 1994                                             *         
* PURPOSE:   Asks user for action then Calls MARB2299                 *         
*                                                                     *         
*---------------------------------------------------------------------*         
*                            MODIFICATIONS                            *         
*                           ===============                           *         
* Version  who   date   why                                           *         
* -------- --- -------- --------------------------------------------- *         
* 00.00.00 JMC 10/17/94 Original Version                              *         
***********************************************************************         
***** Procedure Constants                                                       
          DECLARE &VERSION         as String (08) Initial "00.00.00"            
          DECLARE &PROCEDURE       as String (08) Initial "MAUI2299"            
          DECLARE &RESTORE         as String (01) Initial "R"                   
          DECLARE &BACKUP          as String (01) Initial "B"                   
          DECLARE &RE_TRY          as String (01) Initial "A"                   
          DECLARE &EXIT_PROC       as String (01) Initial "E"                   
          DECLARE &ACTION          as String (01) Initial " "                   
                                                                                
***** PROMPT variables                                                          
          DECLARE &PROMPT_TITLE_01         as String (79) Initial               
                  &PROCEDURE !! "             PPV/REBNI Batch Bac" !!           
                  "kup/Restore Utility            " !! &VERSION                 
          DECLARE &MESSAGE         as String (79) Initial " "                   
          DECLARE &PF              as Integer     Initial 0                     
          DECLARE &CURSOR_ROW      as Integer     Initial 0                     
          DECLARE &CURSOR_COLUMN   as Integer     Initial 0                     
          DECLARE &MSG_ACTION      as String (24) Initial " "                   
                                                                                
***********************************************************************         
* STEP01 -- Get file locations                                        *         
***********************************************************************         
STEP01:  RUN MU5350                                                             
             CANCEL EXIT is STEP01x                                             
               ENTER CATGET     CATNAME  = PPVLOAD                              
     PPVLOAD:  ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = PPVLOAD                              
     PPVPROC:  ENTER LOCATION                                                   
               ENTER CATGET                                                     
                                                                                
          IF STEP01 = 0 GOTO STEP01z                                            
                                                                                
          IF STEP01 < 99 RETURN CODE = STEP01 + 100                             
                                                                                
          RETURN CODE = 198                                                     
                                                                                
STEP01x:  RETURN CODE = 199                                                     
                                                                                
STEP01z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP02 -- Prompt for action                                         *         
***********************************************************************         
STEP02:   CALL PTYPE                                                            
          IF &ACTION = &BACKUP  GOTO STEP02z                                    
          IF &ACTION = &RESTORE GOTO STEP02z                                    
          GOTO EOJ                                                              
                                                                                
STEP02z:  CALL CLEAR                                                            
                                                                                
***********************************************************************         
* STEP03 -- Verify Action                                             *         
***********************************************************************         
STEP03:   CALL PVERY                                                            
                                                                                
          IF &ACTION = &BACKUP    GOTO STEP03z                                  
          IF &ACTION = &RESTORE   GOTO STEP03z                                  
          IF &ACTION = &EXIT_PROC GOTO EOJ                                      
          GOTO STEP02                                                           
                                                                                
STEP03z:  CALL CLEAR                                                            
                                                                                
***********************************************************************         
* STEP05 -- Process Action                                            *         
***********************************************************************         
STEP05:   RUN MARB2299 in (PPVPROC.LIBRARY) on (PPVPROC.VOLUME)                 
              USING &ACTION                                                     
              CANCEL EXIT is STEP05x                                            
              ERROR  EXIT is STEP05y                                            
                                                                                
          IF STEP05 = 0   GOTO STEP05z                                          
          IF STEP05 > 997 RETURN CODE = 997                                     
          RETURN CODE  = STEP05 + 5000                                          
                                                                                
STEP05x:  RETURN CODE = 5999                                                    
STEP05y:  RETURN CODE = 5998                                                    
STEP05z: [ continue ]                                                           
                                                                                
***********************************************************************         
* EOJ -- End of Job                                                   *         
***********************************************************************         
EOJ:     RETURN                                                                 
                                                                                
*#####################################################################*         
*                                                                     *         
*                           SUB ROUTINES                              *         
*                                                                     *         
*#####################################################################*         
                                                                                
***********************************************************************         
* CLEAR -- Clears the screen                                          *         
***********************************************************************         
CLEAR:    MESSAGE CENTER "Procedure " !! &PROCEDURE(1,*) !!                     
                         " in Progress"                                         
END                                                                             
                                                                                
***********************************************************************         
* PVERY -- Asks user if files are to be restored or Backed up         *         
***********************************************************************         
PVERY:    ASSIGN &MESSAGE              = " "                                    
                                                                                
PVERYa:   MESSAGE ROW 1                                                         
               LINE &PROMPT_TITLE_01                                            
                                                                                
          MESSAGE ERASE = NO ROW 22                                             
               BRIGHT &MESSAGE;                                                 
               LINE   "                                        " !!             
                      "                                       ";                
               DIM "(ENTER) Process Action; (16) Exit"                          
                                                                                
          IF &ACTION = "B" GOTO PVERYb                                          
          IF &ACTION = "R" GOTO PVERYr                                          
          ASSIGN &ACTION = &RE_TRY                                              
          GOTO PVERYz                                                           
                                                                                
PVERYb:   MESSAGE ERASE = NO ROW 4                                              
               CENTER BRIGHT LINE "WARNING";;                                   
               CENTER "About to Backup PPV/REBNI Files, OVERLAYING   ";         
               CENTER "PPV/REBNI Backup Files with current Production";         
               CENTER "Files.  Please verify selection below:        "          
                                                                                
          ASSIGN &MSG_ACTION = " BACKUP PPV/REBNI Files "                       
          GOTO PVERYs                                                           
                                                                                
PVERYr:   MESSAGE ERASE = NO ROW 4                                              
               CENTER BRIGHT LINE "WARNING";;                                   
               CENTER  "About to Restore PPV/REBNI Files, OVERLAYING";          
               CENTER  "current PRODUCTION Files with Backup Files, ";          
               CENTER  "Please verify selection below:              "           
                                                                                
          ASSIGN &MSG_ACTION = " RESTORE PPV/REBNI Files"                       
          GOTO PVERYs                                                           
                                                                                
PVERYs:   PROMPT PFKEY  = &PF, ERASE = NO,                                      
                 CURROW = &CURSOR_ROW, CURCOL = &CURSOR_COLUMN                  
                 ROW 11                                                         
                CENTER TAB " Reselect Options       ";;                         
                CENTER TAB " Exit, do NOT Process   ";;                         
                CENTER TAB &MSG_ACTION                                          
                                                                                
          IF &PF = 0  GOTO PVERYv                                               
          IF &PF = 16 GOTO PVERYx                                               
          ASSIGN &MESSAGE = "Please press ENTER of Pf-16"                       
          GOTO PVERYa                                                           
                                                                                
PVERYv:   IF   &CURSOR_ROW = 11 GOTO PVERYw                                     
          IF   &CURSOR_ROW = 13 GOTO PVERYx                                     
          IF   &CURSOR_ROW = 15 GOTO PVERYz                                     
          ASSIGN &MESSAGE = "Please select an action"                           
          GOTO PVERYa                                                           
PVERYw:   ASSIGN &ACTION = &RE_TRY                                              
          GOTO   PVERYz                                                         
PVERYx:   ASSIGN &ACTION = &EXIT_PROC                                           
          GOTO   PVERYz                                                         
PVERYz:   END                                                                   
                                                                                
***********************************************************************         
* PTYPE -- Asks user if files are to be restored or Backed up         *         
***********************************************************************         
PTYPE:    ASSIGN &ACTION               = " "                                    
          ASSIGN &MESSAGE              = " "                                    
                                                                                
PTYPEa:   MESSAGE ROW 1                                                         
               LINE &PROMPT_TITLE_01                                            
                                                                                
          MESSAGE ERASE = NO ROW 22                                             
               BRIGHT &MESSAGE;                                                 
               LINE   "                                        " !!             
                      "                                       ";                
               DIM "(ENTER) Process Action; (16) Exit"                          
                                                                                
          MESSAGE ERASE = NO ROW 4                                              
               CENTER "About to Backup or Restore PPV/REBNI Files.";            
               CENTER "Please select action below:                "             
                                                                                
          PROMPT PFKEY  = &PF, ERASE = NO,                                      
                 CURROW = &CURSOR_ROW, CURCOL = &CURSOR_COLUMN                  
                 ROW 8                                                          
                CENTER TAB " Exit, do NOT Process   ";;                         
                CENTER TAB " Backup PPV/REBNI Files ";;                         
                CENTER TAB " Restore PPV/REBNI Files"                           
                                                                                
          IF &PF = 0  GOTO PTYPEv                                               
          IF &PF = 16 GOTO PTYPEw                                               
          ASSIGN &MESSAGE = "Please press ENTER of Pf-16"                       
          GOTO PTYPEa                                                           
                                                                                
PTYPEv:   IF   &CURSOR_ROW = 8  GOTO   PTYPEw                                   
          IF   &CURSOR_ROW = 10 GOTO   PTYPEx                                   
          IF   &CURSOR_ROW = 12 GOTO   PTYPEy                                   
          ASSIGN &MESSAGE = "Please select an action"                           
          GOTO PTYPEa                                                           
PTYPEw:   ASSIGN &ACTION = &EXIT_PROC                                           
          GOTO   PTYPEz                                                         
PTYPEx:   ASSIGN &ACTION = &BACKUP                                              
          GOTO   PTYPEz                                                         
PTYPEy:   ASSIGN &ACTION = &RESTORE                                             
          GOTO   PTYPEz                                                         
PTYPEz:   END                                                                   
                                                                                
************** ####### END OF PROCEDURE MARB229R ####### *************          
