         PROCEDURE MGUI2001                                                     
                                                                                
***********************************************************************         
* PROCEDURE:  MGUI2001                                                *         
* AUTHOR:     JMC                                                     *         
* TITLE:      Procedure/Return Code File Maintenance Procedure        *         
* REMARKS:    This procedure will first ask the user which system     *         
*             is being maintained and then MGRB2010 will execute      *         
*             to get the catalog entry of that systems                *         
*             Return Code Description File.  Next MU5350 will         *         
*             execute to get the location of the file.  MG2001        *         
*             will the execute to allow the user to maintain          *         
*             the file.                                               *         
*                                                                     *         
*---------------------------------------------------------------------*         
*                            MODIFICATIONS                            *         
* VER WHO   DATE   WHY                                                *         
* --- --- -------- -------------------------------------------------- *         
*  03 JMC 09/23/92 Added FPSULOAD/FPSUPROC Catalog                    *         
*  02 JMC 02/02/88 Added MG2002 to determine list of applications     *         
*  01 JMC 03/07/88 Added SMS WIP/PRS to the main screen               *         
*  00 JMC 05/01/87 Original Version                                   *         
*                                                                     *         
***********************************************************************         
                                                                                
          DECLARE &VERSION             as String (02) Initial "03"              
                                                                                
          DECLARE &MG2001_EXISTS       as String (01) Initial " "               
          DECLARE &MG2001_LITERAL      as String (30) Initial " "               
          DECLARE &CAT_ENTRY           as String (16) Initial " "               
          DECLARE &R_C_FILE            as String (08) Initial " "               
          DECLARE &R_C_LIB             as String (08) Initial " "               
          DECLARE &R_C_VOL             as String (06) Initial " "               
          DECLARE &RETURN_CODE         as Integer     Initial 0                 
                                                                                
          DECLARE &P                   as Integer     Initial 0                 
          DECLARE &SPACE_79            as String (79) Initial " "               
          DECLARE &MESSAGE             as String (79) Initial " "               
          DECLARE &TITLE_01            as String (79) Initial                   
                  "MGUI2001-Sxx     W A N G    "      !!                        
                  "L A B O R A T O R I E S    I N C." !!                        
                  "     Version: " !! &VERSION                                  
          DECLARE &TITLE_02            as String (42) Initial                   
                  "Manufacturing Information Resource Service"                  
          DECLARE &TITLE_03            as String (40) Initial                   
                  "Application Return-Code File Maintenance"                    
                                                                                
***********************************************************************         
* STEP01 -- MU5350, Get File Locations                                *         
***********************************************************************         
STEP01:   RUN MU5350                                                            
                ENTER CATGET CATNAME = MG10151S                                 
      MG10151S: ENTER LOCATION                                                  
                ENTER CATGET CATNAME = FPSULOAD                                 
      FPSULOAD: ENTER LOCATION                                                  
                ENTER CATGET CATNAME = FPSUPROC                                 
      FPSUPROC: ENTER LOCATION                                                  
                ENTER CATGET                                                    
                                                                                
           IF STEP01 ne 0 RETURN CODE = + STEP01                                
                                                                                
***********************************************************************         
* STEP02 -- Get application being used.                               *         
***********************************************************************         
STEP02:   RUN MG2002 in (FPSULOAD.LIBRARY) on (FPSULOAD.VOLUME)                 
                     using &MG2001_LITERAL, &CAT_ENTRY, &MESSAGE                
              ENTER MG10151S (MG10151S)                                         
                                                                                
          IF STEP02 = 99 GOTO EOJ                                               
                                                                                
          ASSIGN &MESSAGE = &SPACE_79                                           
                                                                                
***********************************************************************         
* STEP03 -- MU5350, Get File Locations                                *         
***********************************************************************         
STEP03:   RUN MU5350                                                            
                ENTER CATGET CATNAME = &CAT_ENTRY                               
      MG20011I: ENTER LOCATION                                                  
                ENTER CATGET                                                    
                                                                                
          IF STEP03 = 0 GOTO STEP04                                             
                                                                                
          ASSIGN &MESSAGE = "File " !! &CAT_ENTRY(1,*) !!                       
                            " used by " !! &MG2001_LITERAL(1,*) !!              
                            " is NOT cataloged"                                 
          GOTO STEP02                                                           
                                                                                
***********************************************************************         
* STEP04 -- Will make sure volume is mounted                          *         
***********************************************************************         
STEP04:   ASSIGN &R_C_FILE      = (MG20011I.FILE)                               
          ASSIGN &R_C_LIB       = (MG20011I.LIBRARY)                            
          ASSIGN &R_C_VOL       = (MG20011I.VOLUME)                             
                                                                                
          IF EXISTS VOLUME (MG20011I.VOLUME) GOTO STEP05                        
                                                                                
          ASSIGN &MESSAGE = "Volume " !! &R_C_VOL(1,*) !!                       
                            " is NOT mounted, File "   !!                       
                            &R_C_FILE(1,*)             !!                       
                            " is cataloged to this volume"                      
          GOTO STEP02                                                           
                                                                                
***********************************************************************         
* STEP05 -- Make sure file exists                                     *         
***********************************************************************         
STEP05:   ASSIGN &MG2001_EXISTS = "Y"                                           
                                                                                
          IF EXISTS FILE (MG20011I) GOTO STEP06                                 
                                                                                
          ASSIGN &MG2001_EXISTS = "N"                                           
                                                                                
          CALL   PROM01                                                         
          IF     &P            = 1  GOTO STEP06                                 
                                                                                
          ASSIGN &MESSAGE      = "Maintenance for "            !!               
                                 &MG2001_LITERAL(1,*)          !!               
                                 " bypassed because R/C File " !!               
                                 "was not found"                                
          GOTO STEP02                                                           
                                                                                
***********************************************************************         
* STEP06 -- MG2001, Maintain the Return Code Desc. File               *         
***********************************************************************         
STEP06:   RUN MG2001 in (FPSULOAD.LIBRARY) on (FPSULOAD.VOLUME)                 
               ENTER ACCEPT   WSEXISTS = &MG2001_EXISTS,                        
                              WSSYSLIT = &MG2001_LITERAL                        
               ENTER MG20011I FILE     = (MG20011I.FILE),                       
                              LIBRARY  = (MG20011I.LIBRARY),                    
                              VOLUME   = (MG20011I.VOLUME),                     
                              RECORDS  = 5000,                                  
                              RELEASE  = NO,                                    
                              FILECLAS = " "                                    
               ENTER MG2001A  [ MUST NOT CONTAIN AN OVERRIDE ]                  
                                                                                
          IF STEP06 = 0 GOTO STEP06A                                            
                                                                                
          ASSIGN &RETURN_CODE = STEP06                                          
          ASSIGN &MESSAGE = "Maintenance for "        !!                        
                            &MG2001_LITERAL(1,*)      !!                        
                            " Failed, Return Code = " !!                        
                            &RETURN_CODE                                        
          GOTO STEP02                                                           
                                                                                
STEP06A:  ASSIGN &MESSAGE = &MG2001_LITERAL (1,*) !!                            
                            " Maintenance Complete"                             
          GOTO   STEP02                                                         
                                                                                
***********************************************************************         
* EOJ -- End of Job                                                   *         
***********************************************************************         
EOJ:     RETURN                                                                 
                                                                                
***********************************************************************         
* PROM01 -- Prompt when file not found                                *         
***********************************************************************         
PROM01:   ASSIGN &MESSAGE        = &SPACE_79                                    
          ASSIGN &TITLE_01(11,2) = "01"                                         
                                                                                
PROM01a:  MESSAGE ERASE = YES ROW 1                                             
                  DIM     &TITLE_01;                                            
                  CENTER  &TITLE_02;                                            
                  CENTER  &TITLE_03                                             
                                                                                
          MESSAGE ERASE = NO ROW 22                                             
                  BRIGHT  &MESSAGE;                                             
                  LINE    &SPACE_79;                                            
                  DIM     "(01) Create File;  (16) Do NOT Create File"          
                                                                                
                                                                                
          PROMPT ERASE = NO, PFKEY=&P ROW 08                                    
                 DIM    "             "           !!                            
                        "File " !! &R_C_FILE(1,*) !!                            
                        " in "  !! &R_C_LIB(1,*)  !!                            
                        " on "  !! &R_C_VOL(1,*)  !!                            
                        " for application";                                     
                 DIM    "             "           !!                            
                        &MG2001_LITERAL(1,*)      !!                            
                        " does NOT exist.";;                                    
                 DIM    "             "           !!                            
                        "Select pf-01 to CREATE the file " !!                   
                        "or pf-16 to bypass maintenance."                       
                                                                                
          ASSIGN &MESSAGE = &SPACE_79                                           
                                                                                
          IF &P = 01 GOTO PROM01z                                               
          IF &P = 16 GOTO PROM01z                                               
                                                                                
          ASSIGN &MESSAGE = "(01) and (16) are the only valid " !!              
                            "functions"                                         
          GOTO   PROM01a                                                        
                                                                                
PROM01z:  END                                                                   
                                                                                
********* #########    END of PROCEDURE MGUI2001    ######### *********         
