          PROCEDURE MGRB2200                                                    
                                                                                
***********************************************************************         
* Procedure:   MGRB2200                                               *         
* Title:       IRS Archive Procedure                                  *         
* Author:      JMC                                                    *         
* Remarks:     Copies Data Files to TAPE, this tape is to be          *         
*              save for the IRS                                       *         
*                                                                     *         
* Version  Who   Date   Why                                           *         
* -------- --- -------- --------------------------------------------- *         
* 00.01.00 JMC 09/01/93 Added ability to use BACKBURN                 *         
* 00.00.00 JMC 08/07/92 Original Version                              *         
*                                                                     *         
***********************************************************************         
                                                                                
          DECLARE &VERSION       as String (08) Initial "00.01.00"              
          DECLARE &USER_ID       as String (08) Initial " "                     
          DECLARE &TAPE_VOL      as String (06) Initial " "                     
          DECLARE &TAPE_LABEL    as String (02) Initial " "                     
          DECLARE &TAPE_DENSITY  as String (06) Initial " "                     
          DECLARE &TAPE_DEVICE   as String (03) Initial " "                     
          DECLARE &TAPE_COMMENT  as String (60) Initial " "                     
          DECLARE &BEGIN_OK      as String (01) Initial "N"                     
          DECLARE &BACKUP_TYPE   as String (01) Initial " "                     
          DECLARE &TAPE_RETN            as String (40) Initial                  
                  "Retain for 10 Years"                                         
                                                                                
***** BADEND Declares                                                           
          DECLARE &BADEND_APPLICATION as String (06) Initial "FSU   "           
          DECLARE &BADEND_PROCEDURE   as String (08) Initial "MGRB2200"         
          DECLARE &BADEND_RETURN_CODE as Integer     Initial 0                  
          DECLARE &BADEND_RERUN_SW    as String (01) Initial " "                
          DECLARE &BADEND_RESTORE_SW  as String (01) Initial " "                
                                                                                
***********************************************************************         
* STEP01 -- Get File Locations                                        *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 1 -- MU5350 in Progress"                         
                                                                                
STEP01:   RUN MU5350                                                            
              CANCEL EXIT is STEP01x                                            
               ENTER CATGET     CATNAME  = DFATAX                               
     DFATAX:   ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = FPSULOAD                             
     FPSULOAD: ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = FPSUPROC                             
     FPSUPROC: ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = MG10151S                             
     MG10151S: ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = MG23001C                             
     MG23001C: ENTER LOCATION                                                   
               ENTER CATGET                                                     
                                                                                
          IF STEP01 = 0 GOTO STEP01z                                            
                                                                                
          ASSIGN &BADEND_RETURN_CODE = STEP01 + 1000                            
          GOTO   STEP01y                                                        
                                                                                
STEP01x:  RETURN CODE = 1999                                                    
STEP01y:  CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP01                                 
          RETURN CODE = &BADEND_RETURN_CODE                                     
                                                                                
STEP01z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP02 -- Verify Files & Log Procedure Begin                        *         
***********************************************************************         
STEP02:   IF &BEGIN_OK = "Y" GOTO STEP02a                                       
          ASSIGN &BEGIN_OK           = "Y"                                      
          ASSIGN &BADEND_RETURN_CODE = 2001                                     
          CALL   BADEND                                                         
                                                                                
STEP02a:  ASSIGN &BADEND_RETURN_CODE = 0                                        
                                                                                
          IF NOT EXISTS LIBRARY (DFATAX.LIBRARY) on (DFATAX.VOLUME)             
                 ASSIGN &BADEND_RETURN_CODE = 2002                              
          IF NOT EXISTS FILE (MG10151S)                                         
                 ASSIGN &BADEND_RETURN_CODE = 2003                              
                                                                                
          IF &BADEND_RETURN_CODE = 0 GOTO STEP02z                               
                                                                                
          CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP01                                 
                                                                                
          RETURN CODE = &BADEND_RETURN_CODE                                     
                                                                                
STEP02z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP03 -- Obtains MG10151S Parameters                               *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 2 -- MG2151"                                     
                                                                                
STEP03:   RUN MG2151 in (FPSULOAD.LIBRARY) on (FPSULOAD.VOLUME)                 
              CANCEL EXIT is STEP03x                                            
               ENTER ACCEPT     WSOPEN   = S                                    
               ENTER MG10151I   (MG10151S)                                      
               ENTER PARMKEY    KEY      =  MG2100                              
       MG2100: ENTER PARMINFO                                                   
               ENTER PARMKEY    KEY      =  MG2101                              
       MG2101: ENTER PARMINFO                                                   
               ENTER PARMKEY    KEY      =  MG2200                              
       MG2200: ENTER PARMINFO                                                   
               ENTER PARMKEY    KEY      =  MG2201                              
       MG2201: ENTER PARMINFO                                                   
               ENTER PARMKEY    KEY      =  MG2202                              
       MG2202: ENTER PARMINFO                                                   
               ENTER PARMKEY    16                                              
                                                                                
          IF STEP03 = 0 GOTO STEP03b                                            
                                                                                
          ASSIGN &BADEND_RETURN_CODE = STEP03 + 3000                            
          GOTO   STEP03y                                                        
                                                                                
STEP03b:                                                                        
          IF (MG2200.STATUS) = "N" GOTO STEP03w                                 
          ASSIGN &TAPE_RETN    = (MG2200.LITERAL)                               
          ASSIGN &BACKUP_TYPE  = (MG2200.SWITCH)                                
                                                                                
                                                                                
          IF &BACKUP_TYPE = "1" GOTO STEP03d                                    
          IF &BACKUP_TYPE = "2" GOTO STEP03d                                    
          GOTO STEP03v                                                          
                                                                                
STEP03d:  GOTO STEP03z                                                          
                                                                                
STEP03v:  ASSIGN &BADEND_RETURN_CODE = 3997 [ Parm MG2200 Switch    ]           
          GOTO STEP03y                      [ value invalid         ]           
                                                                                
STEP03w:  ASSIGN &BADEND_RETURN_CODE = 3998 [ Parm MG2200 not found ]           
          GOTO STEP03y                                                          
                                                                                
STEP03x:  ASSIGN &BADEND_RETURN_CODE = 3999                                     
                                                                                
STEP03y:  CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP01                                 
          RETURN CODE = &BADEND_RETURN_CODE                                     
                                                                                
STEP03z:  IF &BACKUP_TYPE = "1" GOTO STEP05                                     
          IF &BACKUP_TYPE = "2" GOTO STEP40                                     
          GOTO STEP03v                                                          
                                                                                
*#####################################################################*         
* This section uses BACKUP to create the TAPE                         *         
*#####################################################################*         
***********************************************************************         
* STEP05 -- Prompt for Tape                                           *         
***********************************************************************         
STEP05:   DECLARE &Pf                   as Integer     Initial 0                
          DECLARE &MESSAGE,                                                     
                  &SPACE_79             as String (79) Initial " "              
                                                                                
          DECLARE &TITLE_01a            as String (19) Initial                  
                  "MGRB2200          "                                          
          DECLARE &TITLE_01b            as String (40) Initial                  
                  "     WANG LABORATORIES INCORPORATED     "                    
          DECLARE &TITLE_01c            as String (20) Initial                  
                  "            " !! &VERSION                                    
          DECLARE &TITLE_01             as String (79) Initial " "              
          DECLARE &TITLE_02a            as String (19) Initial " "              
          DECLARE &TITLE_02b            as String (40) Initial                  
                  "  Manuf. Management Information Systems "                    
          DECLARE &TITLE_02             as String (79) Initial " "              
          DECLARE &TITLE_03             as String (37) Initial                  
                  "DFA Internal Revenue Service Archive"                        
          DECLARE &TAPE_CONT            as String (40) Initial                  
                  "IRS Tape for DFA Systems     "                               
          DECLARE &TAPE_DEFL            as String (40) Initial                  
                  "040 ITS001 NL 6250           "                               
          DECLARE &LOPROUL      as String (01) Initial &BYTE(172)               
          DECLARE &FLPRO        as String (01) Initial &BYTE(148)               
          DECLARE &HIPRO        as String (01) Initial &BYTE(132)               
          DECLARE &LOPRO        as String (01) Initial &BYTE(140)               
                                                                                
          ASSIGN &TAPE_COMMENT = "IRS Archive Tape, " !!                        
                                 &TAPE_RETN(1,*)      !!                        
                                 ", Using BACKUP"                               
                                                                                
          IF (MG2100.STATUS) = "Y" ASSIGN &TITLE_01b = (MG2100.LITERAL)         
          IF (MG2101.STATUS) = "Y" ASSIGN &TITLE_02b = (MG2101.LITERAL)         
          IF (MG2201.STATUS) = "Y" ASSIGN &TAPE_DEFL = (MG2201.LITERAL)         
          IF (MG2202.STATUS) = "Y" ASSIGN &TAPE_CONT = (MG2202.LITERAL)         
          ASSIGN &TAPE_DEVICE  = &TAPE_DEFL(1,3)                                
          ASSIGN &TAPE_VOL     = &TAPE_DEFL(5,6)                                
          ASSIGN &TAPE_LABEL   = &TAPE_DEFL(12,2)                               
          ASSIGN &TAPE_DENSITY = &TAPE_DEFL(15,4)                               
          ASSIGN &TITLE_01 = &TITLE_01a !! &TITLE_01b !! &TITLE_01c             
          ASSIGN &TITLE_02 = &TITLE_02a !! &TITLE_02b !! &TITLE_02a             
                                                                                
STEP05a:  ASSIGN &TITLE_02 (1,6) = "STEP05"                                     
                                                                                
          MESSAGE ERASE = YES ROW 1                                             
               DIM    &TITLE_01;                                                
               DIM    &TITLE_02;                                                
               CENTER &TITLE_03                                                 
                                                                                
          MESSAGE ERASE = NO ROW 22                                             
               BRIGHT &MESSAGE;                                                 
               LINE   &SPACE_79;                                                
               DIM    "(ENTER) Process;  (16) Exit"                             
                                                                                
          PROMPT ERASE = NO, PFKEY = &Pf ROW 7                                  
                 DIM "     ",                                                   
                     "This procedure Backups the IRS Archive " !!               
                     "Library to Tape.";;;                                      
                 DIM "     ",                                                   
                     "Please Enter Tape Name:",                                 
                     UPPER &TAPE_VOL;                                           
                 DIM "     ",                                                   
                     "              Device #:",                                 
                     UPPER &TAPE_DEVICE;;;                                      
                 DIM "     ",                                                   
                     BRIGHT LINE "LABEL TAPE AS:";                              
                 DIM "         ",                                               
                     BRIGHT &TAPE_CONT;                                         
                 DIM "         ",                                               
                     BRIGHT &TAPE_RETN                                          
                                                                                
          IF &Pf = 00 GOTO STEP05z                                              
          IF &Pf = 16 GOTO STEP05y                                              
                                                                                
          ASSIGN &MESSAGE = &Pf !! " is not a Valid Pf-Key"                     
          GOTO   STEP05a                                                        
                                                                                
STEP05y:  ASSIGN &BADEND_RETURN_CODE = 5999                                     
          CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP01                                 
          RETURN CODE = &BADEND_RETURN_CODE                                     
                                                                                
STEP05z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP06 -- Mount Tape Volume                                         *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 6 -- MOUNT in Progress"                          
                                                                                
STEP06:  MOUNT TAPE &TAPE_VOL on &TAPE_DEVICE WITH NO LABEL                     
                                                                                
         IF STEP06 = 0 GOTO STEP06z                                             
                                                                                
         ASSIGN &Pf      = STEP06                                               
         ASSIGN &MESSAGE = "Can't mount Tape " !!                               
                           &TAPE_VOL(1,*)   !!                                  
                           ", MOUNT R/C = " !! &Pf !!                           
                           ", Try another tape"                                 
          GOTO STEP05a                                                          
                                                                                
STEP06z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP07 -- Initialize Tape                                           *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 7 -- TAPEINIT in Progress"                       
                                                                                
STEP07:   RUN TAPEINIT                                                          
              CANCEL EXIT is STEP07x                                            
              ERROR  EXIT is STEP07y                                            
        TAPE1: ENTER INPUT   VOLUME    = &TAPE_VOL                              
               ENTER MOUNT                                                      
               ENTER TAPE    LABEL     = &TAPE_LABEL,                           
                             DENSITY   = &TAPE_DENSITY                          
               ENTER EOJ     16                                                 
                                                                                
         IF STEP07 = 0 GOTO STEP07z                                             
                                                                                
          ASSIGN &Pf      = STEP06                                              
          ASSIGN &MESSAGE = "Can't Init Tape " !!                               
                           &TAPE_VOL(1,*)      !!                               
                           ", TAPEINIT R/C = " !! &Pf !!                        
                           ", Try another tape"                                 
          GOTO STEP05a                                                          
                                                                                
STEP07x:  ASSIGN &MESSAGE = "TAPEINIT cancelled by operator"                    
          GOTO STEP05a                                                          
STEP07y:  ASSIGN &MESSAGE = "Unable to Execute TAPEINIT"                        
          GOTO STEP05a                                                          
                                                                                
STEP07z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP08 -- BACKUP Library DFATAX                                     *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 8 -- Creating " !! &TAPE_CONT(1,*)               
                                                                                
STEP08:   RUN BACKUP                                                            
              CANCEL EXIT is STEP08x                                            
              ERROR  EXIT is STEP08y                                            
               ENTER SPEED                                                      
               ENTER INPUT      LIBRARY  = (DFATAX.LIBRARY),                    
                                VOLUME   = (DFATAX.VOLUME),                     
                                DEVICE   = DISK,                                
                                FUNCTION = BACKUP,                              
                                ERRDISP  = YES,                                 
                                MOREFILE = NO,                                  
                                SELECT   = NO                                   
               ENTER OUTPUT     VOLUME   = (TAPE1.VOLUME),                      
                                DEVICE   = TAPE,                                
                                CLEAR    = YES                                  
               ENTER OPTIONS                                                    
               ENTER LOGFILES   PRINT    = "YES"                                
               ENTER EOJ        16                                              
                                                                                
          IF STEP08 = 0 GOTO STEP08z                                            
                                                                                
          ASSIGN &Pf      = STEP08                                              
          ASSIGN &MESSAGE = "BACKUP R/C = " !! &Pf !!                           
                            "try another Tape"                                  
          GOTO STEP05a                                                          
                                                                                
STEP08x:  ASSIGN &MESSAGE = "Backup of IRS Tax Library Cancelled " !!           
                            "by operator"                                       
          GOTO   STEP05a                                                        
STEP08y:  ASSIGN &MESSAGE = "Unable to Execute BACKUP"                          
          GOTO STEP05a                                                          
                                                                                
STEP08z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP09 -- MG2300, Save Information about the tape created           *         
***********************************************************************         
                                                                                
STEP09:   RUN MG2300 in (FPSULOAD.LIBRARY) on (FPSULOAD.VOLUME)                 
              CANCEL EXIT is STEP09x                                            
              ERROR  EXIT is STEP09y                                            
               ENTER MG23001C   FILE     = (MG23001C.FILE),                     
                                LIBRARY  = (MG23001C.LIBRARY),                  
                                VOLUME   = (MG23001C.VOLUME),                   
                                RECORDS  = 25000,                               
                                RELEASE  = NO,                                  
                                FILECLAS = " "                                  
               ENTER TAPEINFO   TAPE     = (TAPE1.VOLUME),                      
                                TYPE     = NL,                                  
                                DENSITY  = 6250,                                
                                VOLUME   = (DFATAX.VOLUME),                     
                                LIBRARY  = (DFATAX.LIBRARY),                    
                                FILE     = "        ",                          
                                COMMENT  = &TAPE_COMMENT,                       
                                PROC     = MGRB2200                             
               ENTER TAPEINFO   16                                              
                                                                                
          GOTO STEP09z [ MG2300 does not have return codes ]                    
                                                                                
STEP09x:  ASSIGN &BADEND_RETURN_CODE = 9999                                     
          CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP09                                 
          GOTO STEP09z                                                          
STEP09y:  ASSIGN &BADEND_RETURN_CODE = 9998                                     
          CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP09                                 
                                                                                
STEP09z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP15 -- Scratch DFATAX Library                                    *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 15 -- Scratching Prior Tax Library"              
                                                                                
STEP15:   RUN MGRB2155 in (FPSUPROC.LIBRARY) on (FPSUPROC.VOLUME)               
              using "        ", (DFATAX.LIBRARY),                               
                                (DFATAX.VOLUME)                                 
              CANCEL EXIT is STEP15x                                            
              ERROR  EXIT is STEP15w                                            
                                                                                
          IF STEP15   = 0 GOTO STEP15z                                          
          ASSIGN &BADEND_RETURN_CODE = STEP15 + 15000                           
          GOTO   STEP15y                                                        
                                                                                
STEP15w:  ASSIGN &BADEND_RETURN_CODE = 15998                                    
          GOTO   STEP15y                                                        
STEP15x:  ASSIGN &BADEND_RETURN_CODE = 15999                                    
STEP15y:  CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP15                                 
                                                                                
STEP15z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP16 -- Dismount the Tape Volume                                  *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 16 -- DISMOUNT in Progress"                      
                                                                                
STEP16:  DISMOUNT TAPE (TAPE1.VOLUME)                                           
                                                                                
STEP06z:  GOTO EOJ                                                              
                                                                                
*#####################################################################*         
* This section uses BACKBURN to create the TAPE                       *         
*#####################################################################*         
***********************************************************************         
* STEP40 -- Get additional Catalog Entries                            *         
***********************************************************************         
STEP40:                                                                         
                                                                                
          ASSIGN &TAPE_COMMENT = "IRS Archive Tape, " !!                        
                                 &TAPE_RETN(1,*)      !!                        
                                 ", Using BACKBURN"                             
                                                                                
***********************************************************************         
* STEP41 -- Get File Locations                                        *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 1 -- MU5350 in Progress"                         
                                                                                
STEP41:   RUN MU5350                                                            
              CANCEL EXIT is STEP41x                                            
               ENTER CATGET     CATNAME  = MGRB2200FPSU#001                     
     BACKPROC: ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = FPSULOAD                             
     FPSULOAD: ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = FPSUPROC                             
     FPSUPROC: ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = MG10151S                             
     MG10151S: ENTER LOCATION                                                   
               ENTER CATGET     CATNAME  = MG23001C                             
     MG23001C: ENTER LOCATION                                                   
               ENTER CATGET                                                     
                                                                                
          IF STEP41 = 0 GOTO STEP41z                                            
                                                                                
          ASSIGN &BADEND_RETURN_CODE = STEP41 + 41000                           
          GOTO   STEP41y                                                        
                                                                                
STEP41x:  RETURN CODE = 41999                                                   
STEP41y:  CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP41                                 
          RETURN CODE = &BADEND_RETURN_CODE                                     
                                                                                
STEP41z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP44 -- Execute Backup                                            *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 44 -- Backuping IRS Data"                        
                                                                                
STEP44:   RUN (BACKPROC.FILE) in (BACKPROC.LIBRARY)                             
                              on (BACKPROC.VOLUME)                              
          IF STEP44 = 0 GOTO STEP44z                                            
                                                                                
          ASSIGN &BADEND_RETURN_CODE = STEP44 + 44000                           
          GOTO   STEP44y                                                        
                                                                                
STEP44x:  RETURN CODE = 44999                                                   
STEP44y:  CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP44                                 
          RETURN CODE = &BADEND_RETURN_CODE                                     
                                                                                
STEP44z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP46 -- Get Tape Volume Name Used                                 *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 46 -- MU5350 in Progress"                        
                                                                                
STEP46:   RUN MU5350                                                            
              CANCEL EXIT is STEP46x                                            
               ENTER CATGET     CATNAME  = FPSU###FPSURSTR                      
     TAPEVOL:  ENTER LOCATION                                                   
               ENTER CATGET                                                     
                                                                                
          IF STEP46 = 0 GOTO STEP46z                                            
                                                                                
          ASSIGN &BADEND_RETURN_CODE = STEP46 + 46000                           
          GOTO   STEP46y                                                        
                                                                                
STEP46x:  RETURN CODE = 46999                                                   
STEP46y:  CALL BADEND                                                           
          GOTO STEP47z  [ Bypass Tape Log ]                                     
                                                                                
STEP46z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP47 -- MG2300, Save Information about the tape created           *         
***********************************************************************         
                                                                                
STEP47:   RUN MG2300 in (FPSULOAD.LIBRARY) on (FPSULOAD.VOLUME)                 
              CANCEL EXIT is STEP47x                                            
              ERROR  EXIT is STEP47y                                            
               ENTER MG23001C   FILE     = (MG23001C.FILE),                     
                                LIBRARY  = (MG23001C.LIBRARY),                  
                                VOLUME   = (MG23001C.VOLUME),                   
                                RECORDS  = 25000,                               
                                RELEASE  = NO,                                  
                                FILECLAS = " "                                  
               ENTER TAPEINFO   TAPE     = (TAPEVOL.VOLUME),                    
                                TYPE     = NL,                                  
                                DENSITY  = 6250,                                
                                VOLUME   = (DFATAX.VOLUME),                     
                                LIBRARY  = (DFATAX.LIBRARY),                    
                                FILE     = "        ",                          
                                COMMENT  = &TAPE_COMMENT,                       
                                PROC     = MGRB2200                             
               ENTER TAPEINFO   16                                              
                                                                                
          GOTO STEP47z [ MG2300 does not have return codes ]                    
                                                                                
STEP47x:  ASSIGN &BADEND_RETURN_CODE = 47999                                    
          CALL BADEND                                                           
          GOTO STEP47z                                                          
STEP47y:  ASSIGN &BADEND_RETURN_CODE = 47998                                    
          CALL BADEND                                                           
          GOTO STEP47z                                                          
                                                                                
STEP47z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP49 -- Scratch DFATAX Library                                    *         
***********************************************************************         
          MESSAGE ERASE = NO ROW 22                                             
                  CENTER "Step 15 -- Scratching Prior Tax Library"              
                                                                                
STEP49:   RUN MGRB2155 in (FPSUPROC.LIBRARY) on (FPSUPROC.VOLUME)               
              using "        ", (DFATAX.LIBRARY),                               
                                (DFATAX.VOLUME)                                 
              CANCEL EXIT is STEP49x                                            
              ERROR  EXIT is STEP49w                                            
                                                                                
          IF STEP49   = 0 GOTO STEP49z                                          
          ASSIGN &BADEND_RETURN_CODE = STEP49 + 49000                           
          GOTO   STEP49y                                                        
                                                                                
STEP49w:  ASSIGN &BADEND_RETURN_CODE = 49998                                    
          GOTO   STEP49y                                                        
STEP49x:  ASSIGN &BADEND_RETURN_CODE = 49999                                    
STEP49y:  CALL BADEND                                                           
          IF &BADEND_RERUN_SW = "Y" GOTO STEP49                                 
                                                                                
STEP49z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* EOJ -- End of Job                                                   *         
***********************************************************************         
EOJ:      ASSIGN &BADEND_RETURN_CODE = 9999999                                  
          CALL   BADEND                                                         
          RETURN                                                                
                                                                                
***********************************************************************         
* BADEND --  Abnormal end of job, will execute if there is a return   *         
*            code.                                                    *         
***********************************************************************         
BADEND:   RUN MGRB2005 in (FPSUPROC.LIBRARY) on (FPSUPROC.VOLUME)               
                       USING &BADEND_APPLICATION,                               
                             &BADEND_PROCEDURE,                                 
                             &BADEND_RETURN_CODE,                               
                             &BADEND_RERUN_SW,                                  
                             &BADEND_RESTORE_SW                                 
              CANCEL EXIT is BADEND                                             
              ERROR  EXIT is BADENDy                                            
                                                                                
          GOTO BADENDz                                                          
                                                                                
BADENDy:  RETURN CODE = &BADEND_RETURN_CODE                                     
BADENDz:  END                                                                   
                                                                                
***********########### End of Procedure MGRB2200 ###########***********         
