         PROCEDURE MGRB2156                                                     
                   using &LINK_IN_VOLUME           as String (06),              
                         &LINK_IN_LIBRARY          as String (08),              
                         &LINK_OUT_LIBRARY         as String (08)               
                                                                                
***********************************************************************         
* PROCEDURE:  MGRB2156                                                *         
* AUTHOR:     JMC                                                     *         
* TITLE:      Rename Library Utility                                  *         
* REMARKS:    This utility renames a library.  If an error            *         
*             occurs the operator is prompted to correct it.          *         
*                                                                     *         
* NOTE:       All Return Codes exactly matches RENAME Return Codes    *         
*                                                                     *         
*---------------------------------------------------------------------*         
*                            MODIFICATIONS                            *         
* Version  who   Date   Why                                           *         
* -------- --- -------- --------------------------------------------- *         
* 00.00.00 JMC 01/29/90 Original Version                              *         
*                                                                     *         
***********************************************************************         
                                                                                
          DECLARE &RENAME_R_C          as Integer     Initial 0                 
          DECLARE &ERROR_INIT          as String (01) Initial "N"               
                                                                                
***********************************************************************         
* STEP01 -- Rename the Library                                        *         
***********************************************************************         
STEP01:   RENAME LIBRARY &LINK_IN_LIBRARY on &LINK_IN_VOLUME                    
              to &LINK_OUT_LIBRARY                                              
                                                                                
          IF STEP01 = 0 GOTO EOJ                                                
                                                                                
          ASSIGN &RENAME_R_C = STEP01                                           
                                                                                
*#####################################################################*         
* This section only executes when RENAME failed                       *         
*#####################################################################*         
***********************************************************************         
* STEP05 -- Declare Error Variables (if needed)                       *         
***********************************************************************         
STEP05:   IF &ERROR_INIT = "Y" GOTO STEP06z                                     
                                                                                
          ASSIGN  &ERROR_INIT = "Y"                                             
                                                                                
          DECLARE &VERSION            as String (08) Initial "00.00.00"         
                                                                                
          DECLARE &TITLE_01           as String (79) Initial                    
                  "MGRB2156                     WANG LABORA" !!                 
                  "TORIES, INC.                " !! &VERSION !! "  "            
          DECLARE &TITLE_02           as String (79) Initial                    
                  "                  Manufacturing Manageme" !!                 
                  "nt Information Systems                 "                     
          DECLARE &TITLE_03           as String (79) Initial                    
                  "                             Library Ren" !!                 
                  "ame Utility                            "                     
                                                                                
          DECLARE &SPACE_79           as String (79) Initial " "                
          DECLARE &MESSAGE            as String (79) Initial " "                
          DECLARE &RENAME_MESSAGE     as String (50) Initial " "                
          DECLARE &RENAME_LABEL       as String (06) Initial " "                
          DECLARE &RENAME_P2          as String (03) Initial " "                
          DECLARE &Pf                 as Integer     Initial 0                  
                                                                                
STEP06z:  [ continue ]                                                          
                                                                                
***********************************************************************         
* STEP07 -- Prompt operator                                           *         
***********************************************************************         
STEP07:   CALL GETMSG                                                           
          CALL PROM01                                                           
          GOTO STEP01                                                           
                                                                                
*#####################################################################*         
* EOJ  - End of Job                                                   *         
*#####################################################################*         
EOJ:      RETURN                                                                
                                                                                
*#####################################################################*         
*                              SUBROUTINES                            *         
*#####################################################################*         
***********************************************************************         
* PROM01 -- Prompt for File Rename Error                              *         
***********************************************************************         
PROM01:   ASSIGN &TITLE_03 (1,8)      = "PROM01  "                              
          ASSIGN &MESSAGE             = &SPACE_79                               
                                                                                
PROM01a:  MESSAGE ERASE = YES ROW 1                                             
               DIM &TITLE_01;                                                   
               DIM &TITLE_02;                                                   
               DIM &TITLE_03                                                    
                                                                                
          MESSAGE ERASE = NO ROW 7                                              
               DIM    "                  Unable to Rename "  !!                 
                      "Library " !!  &LINK_IN_LIBRARY (1,*)  !!                 
                       " on "    !! &LINK_IN_VOLUME  (1,*);                     
               DIM    "                                to Library " !!          
                      &LINK_OUT_LIBRARY    (1,*) !!                             
                      " on " !! &LINK_IN_VOLUME (1,*);;;                        
               DIM    "                  " !!                                   
                      "Rename Return Code = " !!                                
                      &RENAME_R_C;                                              
               BRIGHT "                          " !!                           
                      &RENAME_MESSAGE;;;                                        
               DIM    "                  " !!                                   
                      "Please try to correct, when fixed select ";              
               DIM    "                  " !!                                   
                      "(ENTER) and the the Library will be RENAMED"             
                                                                                
          PROMPT ERASE = NO, PFKEY = &Pf ROW 22                                 
               BRIGHT &MESSAGE;                                                 
               LINE   &SPACE_79;                                                
               DIM  "(ENTER) Continue;  (32) End with a RETURN CODE"            
                                                                                
                                                                                
          IF &Pf = 00 GOTO PROM01z                                              
          IF &Pf = 32 RETURN CODE = &RENAME_R_C                                 
                                                                                
          ASSIGN &MESSAGE = "Invalid Pf-key selected"                           
          GOTO   PROM01a                                                        
                                                                                
PROM01z:  END                                                                   
                                                                                
***********************************************************************         
* GETMSG -- Format the Remane Error Message                           *         
***********************************************************************         
GETMSG:   ASSIGN &RENAME_MESSAGE = "Reason is unknown"                          
                                                                                
          IF &RENAME_R_C > 999 END                                              
          IF &RENAME_R_C > 99 IF &RENAME_R_C < 999                              
             ASSIGN &RENAME_P2 = &RENAME_R_C                                    
          IF &RENAME_R_C > 9 IF &RENAME_R_C < 99                                
             ASSIGN &RENAME_P2 = "0" !! &RENAME_R_C                             
          IF &RENAME_R_C < 9                                                    
             ASSIGN &RENAME_P2 = "00" !! &RENAME_R_C                            
                                                                                
          ASSIGN &RENAME_LABEL = "MSG" !! &RENAME_P2                            
          IF     &LABEL(&RENAME_LABEL) GOTO &RENAME_LABEL                       
          END                                                                   
                                                                                
MSG004:   ASSIGN &RENAME_MESSAGE = "Volume not mounted"                         
          END                                                                   
MSG008:   ASSIGN &RENAME_MESSAGE = "Volume in exclusive use"                    
          END                                                                   
MSG012:   ASSIGN &RENAME_MESSAGE = "All buffers in use, no RENAME"              
          END                                                                   
MSG016:   ASSIGN &RENAME_MESSAGE = "Library NOT found"                          
          END                                                                   
MSG020:   ASSIGN &RENAME_MESSAGE = "File NOT Found"                             
          END                                                                   
MSG024:   ASSIGN &RENAME_MESSAGE = "Insufficent Access to Library"              
          END                                                                   
MSG028:   ASSIGN &RENAME_MESSAGE = "Unexpired File"                             
          END                                                                   
MSG032:   ASSIGN &RENAME_MESSAGE = "File in use"                                
          END                                                                   
MSG036:   ASSIGN &RENAME_MESSAGE = "VTOC Error"                                 
          END                                                                   
MSG040:   ASSIGN &RENAME_MESSAGE = "VTOC Error"                                 
          END                                                                   
MSG044:   ASSIGN &RENAME_MESSAGE = "Invalid Argument List Address"              
          END                                                                   
MSG048:   ASSIGN &RENAME_MESSAGE = "I/O Error.  VTOC unreliable"                
          END                                                                   
MSG052:   ASSIGN &RENAME_MESSAGE = "New Library name already " !!               
                                   "exists, no rename"                          
          END                                                                   
MSG056:   ASSIGN &RENAME_MESSAGE = "New Library name invalid "                  
          END                                                                   
MSG060:   ASSIGN &RENAME_MESSAGE = "VTOC Currently Full"                        
          END                                                                   
MSG064:   ASSIGN &RENAME_MESSAGE = "Reserved bits in parm " !!                  
                                   "list options bytes nonzero"                 
          END                                                                   
                                                                                
************** ####### END OF PROCEDURE MGRB2156 ####### *************          
