         PROCEDURE MGRB2120                                                     
                   using &LINK_RESTART               as String (01),            
                         &LINK_STREAM                as String (08),            
                         &LINK_PROCEDURE             as String (08),            
                         &LINK_APPL_NAME             as String (40),            
                         &LINK_ACTION                as String (01)             
                                                                                
***********************************************************************         
* PROCEDURE:  MGRB2120                                                *         
* TITLE:      JOB-STREAM RESTART INFORMATION DISPLAY                  *         
* AUTHOR:     JMC                                                     *         
* REMARKS:    This procedure displays Job-Stream restart information  *         
*             to the operator                                         *         
*                                                                     *         
*=====================================================================*         
*                             MODIFICATIONS                           *         
* Version   WHO   DATE   WHY                                          *         
* --------  --- -------- -------------------------------------------- *         
* 00.00.00  JMC 05/04/89 Original Version                             *         
*                                                                     *         
*=====================================================================*         
*                           RETURN CODES                              *         
*                          ==============                             *         
* NOTE: all return-codes MUST be < 99                                 *         
*                                                                     *         
* R/C  Meaning                                                        *         
* ---  -------------------------------------------------------------- *         
*  10  Invalid &LINK_RESTART, must = "B" or "E" or "N" or "R"         *         
*                                                                     *         
*                                                                     *         
*=====================================================================*         
*                         LINK PARAMETERS                             *         
*                        =================                            *         
*                                                                     *         
* Parameter        Description                                        *         
* ---------------  -------------------------------------------------- *         
* &LINK_RESTART    Determines the prompt to be displayed:             *         
*                  "B" - Show Run from beginning prompt               *         
*                  "E" - Stream completed prompt                      *         
*                  "N" - Show start at next procedure prompt          *         
*                  "R" - Show Run at specific procedure prompt        *         
* &LINK_STREAM     Name of the Job Stream                             *         
* &LINK_PROCEDURE  Name of the procedure executed by the Job Stream   *         
* &LINK_APPL_NAME  Name of the Application                            *         
* &LINK_ACTION     Indicates the action selected by operator:         *         
*                  "Y" = Operator elected to allow the Job Stream     *         
*                        to automatically handle the restart          *         
*                  "N" = If &LINK_RESTART = "E" operator elected      *         
*                        to rerun stream from the beginning,          *         
*                        otherwise operator elected NOT to restart    *         
*                        stream                                       *         
*                                                                     *         
* NOTE: &LINK_RESTART, &LINK_STREAM and &LINK_PROCEDURE are passed    *         
*       into this procedure by the calling proc.                      *         
*       &LINK_ACTION is passed back out to the calling procedure      *         
*                                                                     *         
***********************************************************************         
         DECLARE &VERSION            as STRING (08) Initial "00.00.00"          
                                                                                
***** Other Declares                                                            
          DECLARE &PROMPT_LABEL            as String (05) Initial " "           
                                                                                
***** Prompt Titles                                                             
          DECLARE &PROMPT_TITLE_01         as String (79) Initial               
                  "MGRB2120                 WANG LABORATORI"  !!                
                  "ES INCORPORATED              " !! &VERSION !! "  "           
          DECLARE &PROMPT_TITLE_02         as String (79) Initial               
                  "                  Manufacturing Manageme"  !!                
                  "nt Information Systems                 "                     
          DECLARE &PROMPT_TITLE_03         as String (79) Initial               
                  "                              Job Strea"  !!                 
                  "m Restart                             "                      
                                                                                
***** Prompt declares                                                           
          DECLARE &PF                      as Integer     Initial 0             
          DECLARE &SPACE_79                as String (79) Initial " "           
          DECLARE &MESSAGE                 as String (79) Initial " "           
          DECLARE &LINE_APPL               as String (60) Initial " "           
          DECLARE &LINE_01                 as String (60) Initial " "           
          DECLARE &LINE_02                 as String (60) Initial " "           
          DECLARE &LINE_03                 as String (60) Initial " "           
          DECLARE &LINE_04                 as String (60) Initial " "           
          DECLARE &LINE_05                 as String (60) Initial " "           
          DECLARE &LINE_06                 as String (60) Initial " "           
          DECLARE &INSTR_1                 as String (60) Initial " "           
          DECLARE &INSTR_2                 as String (60) Initial " "           
          DECLARE &CURSOR_COLUMN           as Integer     Initial 0             
          DECLARE &CURSOR_ROW              as Integer     Initial 0             
          DECLARE &TEST_ROW                as Integer     Initial 0             
          DECLARE &TEST_ROW_1              as Integer     Initial 0             
                                                                                
***********************************************************************         
* STEP01 -- Validate Restart Switch and format Screen                 *         
***********************************************************************         
STEP01:   ASSIGN &LINE_01 = "Procedure:   " !! &LINK_STREAM(1,*) !!             
                            " -- Restart in Progress"                           
                                                                                
          IF &LINK_APPL_NAME = " " GOTO STEP01a                                 
                                                                                
          ASSIGN &LINE_APPL = "Application: " !! &LINK_APPL_NAME                
                                                                                
STEP01a:  ASSIGN &PROMPT_LABEL = "LINE" !! &LINK_RESTART                        
                                                                                
          IF &LABEL(&PROMPT_LABEL) GOTO STEP01b                                 
                                                                                
          RETURN CODE = 10                                                      
                                                                                
STEP01b:  CALL &PROMPT_LABEL                                                    
                                                                                
          ASSIGN &TEST_ROW_1 = &TEST_ROW + 2                                    
                                                                                
***********************************************************************         
* STEP03 -- Display restart prompt                                    *         
***********************************************************************         
STEP03:   MESSAGE ERASE = YES ROW 1                                             
             DIM    &PROMPT_TITLE_01;                                           
             DIM    &PROMPT_TITLE_02;                                           
             DIM    &PROMPT_TITLE_03                                            
                                                                                
          MESSAGE ERASE = NO ROW 7                                              
               BRIGHT &PROMPT_TAB  !!  &LINE_APPL;                              
               DIM    &PROMPT_TAB  !!  &LINE_01;;                               
               DIM    &PROMPT_TAB  !!  &LINE_02;                                
               DIM    &PROMPT_TAB  !!  &LINE_03;                                
               DIM    &PROMPT_TAB  !!  &LINE_04;                                
               DIM    &PROMPT_TAB  !!  &LINE_05;                                
               DIM    &PROMPT_TAB  !!  &LINE_06                                 
                                                                                
          MESSAGE ERASE = NO ROW 22                                             
               BRIGHT &MESSAGE;                                                 
               LINE   &SPACE_79;                                                
               DIM    "(ENTER) Continue"                                        
                                                                                
          PROMPT PFKEY  = &PF, ERASE = NO,                                      
                 CURROW = &CURSOR_ROW, CURCOL = &CURSOR_COLUMN                  
                 ROW &TEST_ROW                                                  
                 DIM &PROMPT_TAB_1,                                             
                     TAB &INSTR_1;;                                             
                 DIM &PROMPT_TAB_1,                                             
                     TAB &INSTR_2                                               
                                                                                
          IF     &PF      = 00 GOTO STEP04                                      
          ASSIGN &MESSAGE = "Invalid Pf selected"                               
          GOTO   STEP03                                                         
                                                                                
***********************************************************************         
* STEP04 -- Process cursor position                                   *         
***********************************************************************         
STEP04:   IF &CURSOR_ROW    = &TEST_ROW   GOTO STEP04A                          
          IF &CURSOR_ROW    = &TEST_ROW_1 GOTO STEP04B                          
                                                                                
          ASSIGN &MESSAGE = "Invalid Cursor Position"                           
          GOTO   STEP03                                                         
                                                                                
STEP04A:  ASSIGN &LINK_ACTION = "Y"                                             
          GOTO   EOJ                                                            
                                                                                
STEP04B:  ASSIGN &LINK_ACTION = "N"                                             
                                                                                
***********************************************************************         
* EOJ -- End of Job                                                   *         
***********************************************************************         
EOJ:      RETURN                                                                
                                                                                
*#####################################################################*         
*                         S U B R O U T I N E S                       *         
*#####################################################################*         
***********************************************************************         
* LINEB -- Format display for restart = "B"                           *         
***********************************************************************         
LINEB:    DECLARE &PROMPT_TAB    as String (16) Initial " "                     
          DECLARE &PROMPT_TAB_1  as String (15) Initial " "                     
                                                                                
          ASSIGN &TEST_ROW = 13                                                 
                                                                                
          ASSIGN &LINE_02 = &LINK_STREAM(1,*) !!                                
                            " will be started from the beginning, " !!          
                             &LINK_STREAM(1,*)                                  
                                                                                
          ASSIGN &LINE_03 = "did NOT begin application " !!                     
                            "specific processing."                              
                                                                                
          ASSIGN &INSTR_1 = " Restart Job Stream " !! &LINK_STREAM              
          ASSIGN &INSTR_2 = " Do NOT restart " !! &LINK_STREAM                  
                                                                                
END                                                                             
                                                                                
***********************************************************************         
* LINEN -- Format display for restart = "N"                           *         
***********************************************************************         
LINEN:    DECLARE &PROMPT_TAB    as String (17) Initial " "                     
          DECLARE &PROMPT_TAB_1  as String (16) Initial " "                     
                                                                                
          ASSIGN &TEST_ROW = 14                                                 
          ASSIGN &LINE_02 = "Procedure "     !! &LINK_PROCEDURE(1,*) !!         
                            " (executed by " !! &LINK_STREAM(1,*)    !!         
                            ") completed"                                       
          ASSIGN &LINE_03 = "successfully.  " !!  &LINK_STREAM(1,*) !!          
                            " will restart at the procedure"                    
          ASSIGN &LINE_04 = "that follows " !! &LINK_PROCEDURE(1,*) !!          
                            ".  Files will not be restored."                    
                                                                                
          ASSIGN &INSTR_1 = " Restart Job Stream " !! &LINK_STREAM              
          ASSIGN &INSTR_2 = " Do NOT restart " !! &LINK_STREAM                  
                                                                                
END                                                                             
                                                                                
***********************************************************************         
* LINER -- Format display for restart = "R"                           *         
***********************************************************************         
LINER:    DECLARE &PROMPT_TAB    as String (14) Initial " "                     
          DECLARE &PROMPT_TAB_1  as String (13) Initial " "                     
                                                                                
          ASSIGN &TEST_ROW = 16                                                 
                                                                                
          ASSIGN &LINE_02 = "Procedure " !! &LINK_PROCEDURE(1,*) !!             
                            " was in progress when " !!                         
                            &LINK_STREAM(1,*) !! " aborted."                    
                                                                                
          ASSIGN &LINE_03 = &LINK_STREAM(1,*) !!                                
                            " will rerun Procedure " !!                         
                            &LINK_PROCEDURE(1,*)     !!                         
                            ", restoring any"                                   
                                                                                
          ASSIGN &LINE_04 = "necessary files automatically."                    
                                                                                
          ASSIGN &LINE_05 = "Note: In some cases other procedures " !!          
                            "may be rerun due to"                               
          ASSIGN &LINE_06 = "      dependencies."                               
                                                                                
          ASSIGN &INSTR_1 = " Restart Job Stream " !! &LINK_STREAM              
          ASSIGN &INSTR_2 = " Do NOT restart " !! &LINK_STREAM                  
                                                                                
END                                                                             
                                                                                
***********************************************************************         
* LINEE -- Format display for restart = "E"                           *         
***********************************************************************         
LINEE:    DECLARE &PROMPT_TAB    as String (14) Initial " "                     
          DECLARE &PROMPT_TAB_1  as String (13) Initial " "                     
                                                                                
          ASSIGN &TEST_ROW = 15                                                 
                                                                                
          ASSIGN &LINE_02 = &LINK_STREAM(1,*) !! " may have " !!                
                            "been cancelled."                                   
                                                                                
          ASSIGN &LINE_05 = "You MUST be Absolutely SURE of " !!                
                            "the option you select."                            
                                                                                
          ASSIGN &INSTR_1 = " " !! &LINK_STREAM (1,*)         !!                
                            " cancelled OR Sys IPL'd during " !!                
                            &LINK_STREAM (1,*)     !! " execution"              
                                                                                
          ASSIGN &INSTR_2 = " " !! &LINK_STREAM (1,*)     !!                    
                            " is being started for the first time " !!          
                            "tonight"                                           
                                                                                
END                                                                             
                                                                                
************** ####### END OF PROCEDURE MGRB2120 ####### *************          
