clear
space %1: 2700	NoSpace
godir %1:\sierra\brain	CantCreate
rem	Copy over the necessary files.
echo Copying Startup Files ...
copy %2:*.drv
copy %2:scid*.exe
copy %2:interp.txt
copy %2:version
copy %2:resource.000 
copy %2:resource.map 
copy %2:install.exe
copy %2:install.hlp
copy %2:install.txt
copy %2:brainrs.bat %1:\sierra\brain.bat
copy %2:brainh.bat brain.bat
copy %2:sierrah.bat sierra.bat
copy %2:120.scr
copy %2:380.scr
copy %2:440.scr
echo %3 > resource.cfg

echo Copying Game files...
exists %2:resource.001 Please insert the disk labeled "Disk 1" in drive %2:.
copy %2:resource.001
exists %2:resource.002 Please insert the disk labeled "Disk 2" in drive %2:.
copy %2:resource.002


:exit
clear
echo
echo ˙To play NOW:
echo ˙   Type brain [ENTER].
echo
echo ˙To play LATER:
echo ˙   From the SIERRA directory of %1:,
echo ˙   Type brain and press [ENTER].
echo
pause
goto Exit2


:NoSpace
clear
echo
echo There is not enough space on %1: to install Castle of Dr. Brain!
echo 2.7 megabytes of free hard disk space are necessary
echo to install this game.
pause


:Exit2
end


:CantCreate
alert Unable to create directory %1:\sierra\brain
end



