00010 PRINT TAB(32);"HAMURABI"
00020 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
00030 PRINT 
00031 PRINT 
00032 PRINT
00080 PRINT "TRY YOUR HAND AT GOVERNING ANCIENT SUMERIA"
00090 PRINT "FOR A TEN-YEAR TERM OF OFFICE."
00091 PRINT
00095 D1=0
00096  P1=0
00100 Z=0
00101  P=95
00102 S=2800
00103  H=3000
00104  E=H-S
00110 Y=3
00111  A=H/Y
00112  I=5
00113  Q=1
00210 D=0
00215 PRINT 
00216 PRINT 
00217 PRINT "HAMURABI: I BEG TO REPORT TO YOU,"
00219 Z=Z+1
00220 REM 217-218 ==> 221-222
00221 PRINT "IN YEAR";Z;",";D;" PEOPLE STARVED,";I;" CAME TO THE CITY,"
00222 P=P+I
00227 IF Q>0 THEN 230
00228 P=INT(P/2)
00229 PRINT "A HORRIBLE PLAGUE STRUCK!  HALF THE PEOPLE DIED."
00230 PRINT "POPULATION IS NOW";P
00232 PRINT "THE CITY NOW OWNS ";A;" ACRES."
00235 PRINT "YOU HARVESTED";Y;" BUSHELS PER ACRE."
00250 PRINT "THE RATS ATE";E;" BUSHELS."
00260 PRINT "YOU NOW HAVE ";S;"  BUSHELS IN STORE."
00261  PRINT
00270 IF Z=11 THEN 860
00310 C=INT(10*RND)
00311  Y=C+17
00312 PRINT "LAND IS TRADING AT";Y;"  BUSHELS PER ACRE."
00320 PRINT "HOW MANY ACRES DO YOU WISH TO BUY";
00321 INPUT Q
00322  IF Q<0 THEN 850
00323 REM 322-324 ==> 324-326
00324 IF Y*Q<=S THEN 330
00325 GOSUB 710
00326 GOTO 320
00330 IF Q=0 THEN 340
00331 A=A+Q
00332  S=S-Y*Q
00333  C=0
00334 GOTO 400
00340 PRINT "HOW MANY ACRES DO YOU WISH TO SELL";
00341 INPUT Q
00342  IF Q<0 THEN 850
00343 REM 342-344 ==> 344-346
00344 IF Q<A THEN 350
00345 GOSUB 720
00346 GOTO 340
00350 A=A-Q
00351  S=S+Y*Q
00352  C=0
00400 PRINT
00410 PRINT "HOW MANY BUSHELS DO YOU WISH TO FEED YOUR PEOPLE";
00411 INPUT Q
00412 IF Q<0 THEN 850
00418 REM *** TRYING TO USE MORE GRAIN THAN IS IN SILOS?
00420 IF Q<=S THEN 430
00421 GOSUB 710
00422 GOTO 410
00430 S=S-Q
00431  C=1
00432  PRINT
00440 PRINT "HOW MANY ACRES DO YOU WISH TO PLANT WITH SEED";
00441 INPUT D
00442  IF D=0 THEN 511
00443 REM 442,444-447 ==> 444-448
00444 IF D<0 THEN 850
00445 REM *** TRYING TO PLANT MORE ACRES THAN YOU OWN?
00446 IF D<=A THEN 450
00447 GOSUB 720
00448 GOTO 440
00449 REM *** ENOUGH GRAIN FOR SEED?
00450 IF INT(D/2)<=S THEN 455
00452 GOSUB 710
00453 GOTO 440
00454 REM *** ENOUGH PEOPLE TO TEND THE CROPS?
00455 IF D<10*P THEN 510
00460 PRINT "BUT YOU HAVE ONLY";P;"  PEOPLE TO TEND THE FIELDS!  NOW THEN,"
00470 GOTO 440
00510 S=S-INT(D/2)
00511 GOSUB 800
00512 REM *** A BOUNTIFUL HARVEST!
00515 Y=C
00516  H=D*Y
00517  E=0
00521 GOSUB 800
00522 IF INT(C/2)<>C/2 THEN 530
00523 REM *** RATS ARE RUNNING WILD!!
00525 E=INT(S/C)
00530 S=S-E+H
00531 GOSUB 800
00532 REM *** LET'S HAVE SOME BABIES
00533 I=INT(C*(20*A+S)/P/100+1)
00539 REM *** HOW MANY PEOPLE HAD FULL TUMMIES?
00540 C=INT(Q/20)
00541 REM *** HORROS, A 15% CHANCE OF PLAGUE
00542 Q=INT(10*(2*RND-.3))
00550 IF P<C THEN 210
00551 REM *** STARVE ENOUGH FOR IMPEACHMENT?
00552 D=P-C
00553  IF D>.45*P THEN 560
00554 REM 553,555 ==> 555-556
00555 P1=((Z-1)*P1+D*100/P)/Z
00556 P=C
00557  D1=D1+D
00558  GOTO 215
00560 PRINT 
00561  PRINT "YOU STARVED";D;"  PEOPLE IN ONE YEAR!!!"
00565 PRINT "DUE TO THIS EXTREME MISMANAGEMENT YOU HAVE NOT ONLY"
00566 PRINT "BEEN IMPEACHED AND THROWN OUT OF OFFICE BUT YOU HAVE"
00567 PRINT "ALSO BEEN DECLARED NATIONAL FINK!!!!"
00568  GOTO 990
00710 PRINT "HAMURABI: THINK AGAIN.  YOU HAVE ONLY"
00712 REM 711-712 ==> 713-714
00713 PRINT S;"  BUSHELS OF GRAIN.  NOW THEN,"
00714 RETURN
00720 PRINT "HAMURABI: THINK AGAIN.  YOU OWN ONLY";A;" ACRES.  NOW THEN,"
00730 RETURN
00800 C=INT(RND*5)+1
00801 RETURN
00850 PRINT 
00851  PRINT "HAMURABI: I CANNOT DO WHAT YOU WISH."
00855 PRINT "GET YOURSELF ANOTHER STEWARD!!!!!"
00857 GOTO 990
00860 PRINT "IN YOUR 10-YEAR TERM OF OFFICE,";P1;" PERCENT OF THE"
00862 PRINT "POPULATION STARVED PER YEAR ON THE AVERAGE, I.E. A TOTAL OF"
00865 PRINT D1;"  PEOPLE DIED!!"
00866  L=A/P
00870 PRINT "YOU STARTED WITH 10 ACRES PER PERSON AND ENDED WITH"
00875 PRINT L;"  ACRES PER PERSON."
00876  PRINT
00880 IF P1>33 THEN 565
00885 IF L<7 THEN 565
00890 IF P1>10 THEN 940
00892 IF L<9 THEN 940
00895 IF P1>3 THEN 960
00896 IF L<10 THEN 960
00900 PRINT "A FANTASTIC PERFORMANCE!!!  CHARLEMANGE, DISRAELI, AND"
00905 PRINT "JEFFERSON COMBINED COULD NOT HAVE DONE BETTER!"
00906 GOTO 990
00940 PRINT "YOUR HEAVY-HANDED PERFORMANCE SMACKS OF NERO AND IVAN IV."
00945 PRINT "THE PEOPLE (REMIANING) FIND YOU AN UNPLEASANT RULER, AND,"
00950 PRINT "FRANKLY, HATE YOUR GUTS!!"
00951 GOTO 990
00960 PRINT "YOUR PERFORMANCE COULD HAVE BEEN SOMEWHAT BETTER, BUT"
00965 PRINT "REALLY WASN'T TOO BAD AT ALL. ";INT(P*.8*RND);"PEOPLE"
00970 PRINT "WOULD DEARLY LIKE TO SEE YOU ASSASSINATED BUT WE ALL HAVE OUR"
00975 PRINT "TRIVIAL PROBLEMS."
00990 PRINT 
00991  FOR N=1 TO 10
00992  PRINT CHR$(7);
00993 REM 991 ==> 994
00994 NEXT N
00995 PRINT "SO LONG FOR NOW."
00996  PRINT
00999 END