100 'TROTS.BAS: An aid to the differential diagnosis of food and    waterborne infectious gastrointestinal diseases. Programmed    in Microsoft Basic 5.1 by L.P.Biese,MD (June 1980)
110 'The diagnostic triage is from: P.J.Kuhn; "It Didn't Quite Look    Right, But I Ate It Anyway"; Diagnostic Medicine,May/June 1980
120 'Theraputic suggestions are from: J.J.Plorde;"Current Management    of Infectious Diarrhea";Drug Therapy (Hosp.),August 1979
130 WIDTH 80					'Set terminal
140 DEFINT A-Z					'make variable integers
150 NUMBER =22					'# Of codes used
160 DIM LEGAL(NUMBER)
170 DATA "Marked cramps/pain","Fever >99.4","Nausea/Vomiting"
180 DATA "Diarrhea >5/day","WBC in stool","Bloody Stool","Vibrios seen"
190 DATA "Rapid (<6Hr) onset","Delayed onset"
200 DATA 015,115,285,385,386,515,516,535,536,565,566,585
210 DATA 605,612,665,715,735,736,765,785,805,865,885,886
220 '--------------------------------------------------
230 ' VARIABLES USED:
240 '
250 '     SYMPTOM$     = Signs/Symptoms (in data list)
260 '     S$           = yes/no string answer
270 '     S            = numeric equivalent of S$
280 '     S1-S3        = pseudo-octal disease code
290 '     TRY          = counter to exit if useless
300 '     LEGAL        = posible disease codes
310 '     CODE         = computed disease code
320 '--------------------------------------------------
330 PRINT CHR$(12)
340 PRINT TAB(20)"FOOD AND WATERBORNE DIARRHEAL DISEASES"
350 PRINT TAB(20)"======================================"
360 PRINT:PRINT:PRINT "Please answer Yes or No to each question"
370 PRINT:PRINT
380 FOR I=1 TO 9
390     READ SYMPTOM$(I)
400     PRINT SYMPTOM$(I);TAB(25);
410     INPUT S$(I): IF LEFT$(S$(I),1)="Y" THEN S(I)=1 ELSE S(I)=0
420     PRINT
430     NEXT
440 '----------- Calculate diagnostic code
450 S1=(S(1))+(S(2)*2)+(S(3)*5)		'left digit
460 S2=(S(4))+(S(5)*2)+(S(6)*5)		'middle digit
470 S3=(S(7))+(S(8)*2)+(S(9)*5)		'right digit
480 CODE=100*S1 + 10*S2 + S3		'Set hundreds,tens & digits
					 of the final pseudo-octal
490 '---------- Test if calculated code is 'legal' (ie.on file)               If so we jump to a line number = CODE+1000 just               to get numbers high enough.
500 RESTORE 200
510 FOR I=1 TO NUMBER
520     READ LEGAL(I)
530     IF CODE=LEGAL(I) THEN PRINT CHR$(12): ON I GOTO 1015,1115,1285,1385,          1386,1515,1516,1535,1536,1565,1566,1585,1605,1612,1665,1715,1735,          1736,1765,1785,1805,1865,1885,1886
540     NEXT
550     RESTORE
560 '---------- Not 'legal'
570 PRINT CHR$(12)
580 TRY=TRY+1:IF TRY = 6 THEN 720		'might as well give up
590 FOR I=1 TO 3:PRINT CHR$(7);:FOR J=1 TO 300:NEXT J,I  'Ring bell
600 PRINT"The signs and syptoms do not resemble one of the usual"
610 PRINT"patterns... Please review your entries"
620 PRINT
630 FOR I=1 TO 9
640     READ SYMPTOM$(I)
650     PRINT I;"} ";SYMPTOM$(I),S$(I)
660     NEXT
670     RESTORE
680 PRINT:INPUT"WHICH NUMBER TO CHANGE               ";X
690 PRINT:INPUT"WHAT IS THE CORRECT (YES/NO) ANSWER  ";S$(X):   IF LEFT$(S$(X),1)="Y" THEN S(X)=1 ELSE S(X)=0
700 GOTO 450
710 '---------- No match, quit
720 PRINT CHR$(12)
730 PRINT"THERE IS  NO MATCH WITH ANY PATTERN ON FILE"
740 PRINT"FOR THE  ACUTE  DIARRHEAL INFECTIOUS AGENTS"
750 PRINT"         -----":PRINT
760 PRINT"  You may wish to consider:":PRINT
770 PRINT"        1} Chronic infectious agents and carrier states"
780 PRINT"           such as S.typhi, E.histolytica etc."
790 PRINT
800 PRINT"        2} Non-infectious agents (eg. antibiotics) and"
810 PRINT"           disease states such as malabsorption etc.
820 END
830 '============= DIAGNOSTIC TEXTS: LINE # = CODE+1000 ===================    This constitutes a 'Jump Table' to preserve the code number and still    get to the text on file.
1015 GOTO 2005	'GIARDIA
1115 GOTO 2100	'GIARDIA
1285 GOTO 2115	'INVASIVE COLI & SHIGELLA
1385 GOTO 2220  'CAMPYLOBACTER & YERSENIA
1386 GOTO 2220	'CAMPYLOBACTER & YERSENIA
1515 GOTO 2370	'CHOLERA
1516 GOTO 2370	'CHOLERA
1535 GOTO 2435	'S.TYPHI & V.PARAHEMO.
1536 GOTO 2435	'S.TYPHI & V.PARAHEMO.
1565 GOTO 2370	'CHOLERA
1566 GOTO 2370	'CHOLERA
1585 GOTO 2435	'S.TYPHI
1605 GOTO 2585	'TOXIGENIC E.COLI
1612 GOTO 2925	'B.CEREUS & STAPH
1665 GOTO 3035	'AMOEBA
1715 GOTO 3145	'VIRUS
1735 GOTO 2825	'V.PARAHEMO.& S.TYPHI
1736 GOTO 2435	'V.PARAHEMO.
1765 GOTO 3320	'S.ENTERIDITIS
1785 GOTO 2435	'S.TYPHI
1805 GOTO 3225	'C.PERFINGENS & E.COLI
1865 GOTO 3320	'S.ENTERIDITIS
1885 GOTO 2220	'YERSENIA
1886 GOTO 2220	'CAMPYLOBACTER
2000 '============== DIAGNOSTIC AND TREATMENT TEXTS ======================                        ~~~~~ Giardia ~~~~~
2005 PRINT"The protozoa Giardia lamblia is suggested."
2010 PRINT"             ---------------":PRINT
2015 PRINT"  Very common, but seldom diagnosed.  Transmission is usually"
2020 PRINT"  preson to person in children,family groups and institutions"
2025 PRINT"  but many large waterborne epidemics have been documented and"
2030 PRINT"  domestic pet resevoirs are known."
2035 PRINT
2040 PRINT"  The hallmark is marked flatulence  with or  without explosive"
2045 PRINT"  bouts of watery diarrhea and abdominal pain. The organism can"
2050 PRINT"  be readily demonstrated in the stool."
2055 PRINT
2060 PRINT"Specific Treatment suggested is:"
2065 PRINT
2070 PRINT"  Quinacrine (Atabrine) 100 mg,tid for 5 days (adult)"
2075 PRINT"       6-7 mg/kg/day PO in 3 divided doses for 5 days (children)"
2080 PRINT"Or:"
2085 PRINT"  Metronidazole (Flagyl) 250 mg.,tid for 10 days (adult)
2090 PRINT"       15 mg/kg/day PO in 3 divided doses for 10 days (children)"
2095 GOTO 3465
2100 PRINT"Giardia lamblia infection without significant pain occurs in"
2105 PRINT"both chronic and low dose/and/or low virulent forms"
2110 PRINT:GOTO 2015'               ~~~~~ Shigella and invasive E.coli ~~~~~
2115 PRINT"Both Shigella species and invasive E.coli show a similar clinical"
2120 PRINT"course, but Shigella ususally produces a  more voluminous watery"
2125 PRINT"diarrhea and has a longer (12-50 hr.) incubation.":PRINT
2130 PRINT"Both organisms produce disease by invading the colonic mucosa  and"
2135 PRINT"inciting an intense neutrophilic response. Invasive E.coli strains"
2140 PRINT"are uncommon  and Shigella is the most probable for these symptoms"
2145 PRINT"It is more common in summer  and  is usually due to food and dairy"
2150 PRINT"products contaminated with excreta.
2155 PRINT
2160 PRINT"Fluid replacement is usually necessary. Specific antibiotics are:"
2165 PRINT
2170 PRINT"  Tetracycline   2.5gm  PO in a single dose (not rec.for children)"
2175 PRINT
2180 PRINT"  Trimethoprim sulfamethoxazole (Bactrim or  Septra) 160/800 mg PO"
2185 PRINT"     q 12hr for 5 days (adult)  or 10/50 mg/kg/day PO in 2 divided"
2190 PRINT"     doses for 5 days (children)":PRINT
2195 PRINT"  Ampicillin (not always sensitive) 0.5-1.0 gm  PO q 6hr for 5 days"
2200 PRINT"        or   100 mg/kg/day in 4 divided doses for 5 days (children)"
2205 PRINT:PRINT
2210 GOTO 3440'                 ~~~~~ Campylobacter and Yersinia ~~~~
2220 PRINT"The Vibrio organism Campylobacter and Yersinia enterocolytica"
2225 PRINT"can both produce a similar clinical picture and  be difficult"
2230 PRINT"to distinguish under the microscope without control organisms"
2235 PRINT
2240 PRINT"Yersinia may produce ileitis, severe enterocolitis or sepsis and"
2245 PRINT"   can mimic acute appendicitis or mesenteric lymphadenitis.  It"
2250 PRINT"   is occasionally accompanied by erethema nodosum."
2255 PRINT
2260 PRINT"Campylobacter has about the same incubation period (2-10 days)"
2265 PRINT"   but tends to have a more grossly bloody stool.  it is more"
2270 PRINT"   common during summer among pre-schoolers and secondary house-"
2275 PRINT"   hold contacts. Periumbilical pain and cramping just prior to"
2280 PRINT"   defecation is common along with grossly bloody stools."
2285 PRINT
2290 PRINT"Most cases are probably undiagnosed due to the fastidious media"
2295 PRINT"   needed to culture these organisms and their relative rarity"
2300 PRINT"   While most patients recover spontaneously it should be noted"
2305 PRINT"   that there is appoximatly a 25% relapse rate."
2310 PRINT
2315 INPUT"           <hit 'return' to see more> ";Q$
2320 PRINT CHR$(12)
2325 PRINT"Dehydration is usually not a problem, but if present, it should"
2330 PRINT"be treated in the usual manner. Erythromycin 0.5 Gm PO q 6 hr."
2335 PRINT"for 5 days is usually specific (50 mg/kg/day in 4 divided doses"
2340 PRINT"in children)
2345 PRINT
2350 PRINT"SHIGELLA  presents a similar picture but usually without severe"
2355 PRINT"pain. You may wish to rerun the program indicating 'No' for pain"
2360 PRINT"to review that condition.":PRINT:PRINT:PRINT
2365 GOTO 3465'                   ~~~~~ Vibrio cholera ~~~~~
2370 PRINT"CHOLERA is suggested and immediate treatment is necessary. The"
2375 PRINT"vibrio forms may not be readily appreciated.
2380 PRINT
2385 PRINT"Cholera is marked by effortless vomiting without nausea or pain"
2390 PRINT"and voluminous 'rice-water' stools  (10-15 liters/day)  rapidly"
2395 PRINT"leading to dehydration, shock and death."
2400 PRINT
2405 PRINT"Tetracycline is specific but intravenous fluid replacement and"
2410 PRINT"electrolyte management are paramount."
2415 PRINT
2420 FOR I=1 TO 5:PRINT CHR$(7);:FOR J=1 TO 150:NEXT J,I     'ring bell'
2425 PRINT"    CONTACT YOU LOCAL HEALTH DEPARTMENT FOR FURTHER HELP !!"
2430 GOTO 3465'                 ~~~~~ S.typhi and V.parahemo ~~~~~
2435 PRINT"Both Salmonella typhi and Vibrio parahemolyticus infections"
2440 PRINT"result in a similar clinical behavior.
2445 PRINT
2450 PRINT"The usual clinical picture of S.typhi is mild fever,nausea,"
2455 PRINT"dirahhea (with or without blood) and persistant anorrhexia"
2460 PRINT"weakness and fever. A transient rash may be present though"
2465 PRINT"seldom recognized.  The disease tends to have a protracted"
2470 PRINT"debilitating course of several weeks."
2475 PRINT
2480 PRINT"The pathology is ileal rather than colonic and consists if an"
2485 PRINT"intracellular invasion of the organism in the ileal mucosa and"
2490 PRINT"spread to mesentric lymph nodes and the portal circulation. A"
2495 PRINT"mono-nuclear reaction is typical but wbc are usually present."
2500 PRINT
2505 PRINT"Because a large 'dose' of the organism is needed, transmission"
2510 PRINT"is usually via a 'common-source' rather than direct person-to"
2515 PRINT"person"
2520 PRINT
2525 PRINT"Vibrio hemolyticus should not represent a significant diagnostic"
2530 PRINT"dilemma: It is spread by raw seafood/shellfish, usually during"
2535 PRINT"the summer months among travelers from the Far East."
2540 PRINT
2545 INPUT"<to review V.parahemo. type 'V', else type 'return'>";Q$
2550 IF LEFT$(Q$,1)="V" THEN GOSUB 2825 ELSE PRINT CHR$(12)
2555 PRINT"TREATMENT:  consists mainly of supportive measures. It is usually"
2560 PRINT"recommended that antibiotic therapy be withheld until definative"
2565 PRINT"culture reports are available since antibiotics are not necessary"
2570 PRINT"and significantly prolong the shedding period of viable bacteria,"
2575 PRINT"due to their 'protected' intracellular location."
2580 FOR I=1 TO 6:PRINT:NEXT:GOTO 3465'                  ~~~~~ Toxigenic E.coli ~~~~~
2585 PRINT"Toxigenic (in contrast to 'invasive' and enteropathogenic) E.coli"
2590 PRINT"strains have only recently been recognized thru several epidemics."
2595 PRINT"In actuality, they appear to be the  normal-flora in a given area "
2600 PRINT"and are only abnormal for the tourist. This is probably the leading"
2605 PRINT"cause of tourist diarrhea."
2610 PRINT
2615 PRINT"The strains produce a heat-stable,non-allergenic toxin of unknown"
2620 PRINT"action and a heat-labile endotoxin that resembles V.cholera, both"
2625 PRINT"antigenitically and physiologically...it acts on the small bowel"
2630 PRINT"resulting in a net loss of water and electrolytes."
2635 PRINT
2640 PRINT"Vomiting may be seen early in the course of the disease, but the"
2645 PRINT"usual clinical picture is one of abdominal cramping and a watery"
2650 PRINT"diarrhea without significant fever."
2655 PRINT:PRINT:PRINT
2660 INPUT"<hit 'return' for therapy>  ";Q$: PRINT CHR$(12)
2665 PRINT"TREATMENT of 'Traveler's Diarrhea'"
2670 PRINT"=================================
2675 PRINT
2680 PRINT"Antibiotics are not indicated..you would have to sterilize the"
2685 PRINT"whole bowel !"
2690 PRINT
2695 PRINT"** Bismuth subsalicylate ('Pepto Bismol'): 30 ml PO every 30 min."
2700 PRINT"   for 8 doses (adults only):  For children there is no specific"
2705 PRINT"                               recommended treatment."
2710 PRINT
2715 PRINT"This drug works by inhibiting intestinal secretions. Recent studies"
2720 PRINT"indicate it is effective in both treatment  AND  prophylaxis of the"
2725 PRINT"common Traveler's Diarrhea.  The prophylactic dose is  60 ml. taken"
2730 PRINT"four times daily during the first two weeks of travel."
2735 PRINT
2740 PRINT"The time-honored Kaopectate and Aluminum hydroxide act by absorbing"
2745 PRINT"water (and toxins?) and decrease stool liquidity/frequency and may"
2750 PRINT"give some symptomatic relief."
2755 PRINT
2760 PRINT:PRINT
2765 INPUT"          <hit 'return' for more>  ";Q$
2770 PRINT CHR$(12)
2775 PRINT"Paragoric and the loperamid and diphynoxylate (Lomitil) compounds"
2780 PRINT"inhibit gastrointestinal mobility and offer relief from the cramps"
2785 PRINT"and stool frequency...they do not diminish the fluid / electrolyte"
2790 PRINT"loss and may mask progressive dehydration.  In addition, they will"
2795 PRINT"prolong the fever in invasive bacterial diseases. (eg.Salmonella)"
2800 PRINT
2805 PRINT"These drugs should not be used in a patient presenting with fecal"
2810 PRINT"leukocytes,significant fever or toxicity."
2815 PRINT:PRINT
2820 GOTO 3465'                  ~~~~~ Vibrio parahemolyticus ~~~~~
2825 PRINT"Vibrio parahemolyticus"
2830 PRINT"======================"
2835 PRINT
2840 PRINT"Vibrio parahemolyticus  is  a halophilic marine organism that "
2845 PRINT"frequently contaminates shellfish in Japan. It is most common"
2850 PRINT"in the summer months,  and while one of the most common food-"
2855 PRINT"borne epidemics in the Far East, it is seldom recognized in"
2860 PRINT"the US."
2865 PRINT
2870 PRINT"The usual clinical picture is that of Shigellosis: fever with"
2875 PRINT"voluminous bloody and watery stools with leukocytes and a 12-"
2880 PRINT"24 hr. incubation."
2885 PRINT
2890 PRINT"The causative vibrio organisms are always present but may be"
2895 PRINT"difficult to identify."
2900 PRINT
2905 PRINT"If identified, Tetracylines are usually effective and fluid"
2910 PRINT"replacement is almost always indicated."
2915 PRINT:PRINT
2920 GOTO 3465'                 ~~~~~ Staph. and B.cereus ~~~~~
2925 PRINT"Staphylococcal food poisioning is caused by a heat-stable"
2930 PRINT"enterotoxin. It is of rapid onset in 2-4 hours (but ranges"
2935 PRINT"from 30 mn. to 8 hours) It is marked by acute prostration,"
2940 PRINT"abdominal cramps and non-bloody diarrhea."
2945 PRINT
2950 PRINT"The common sources are:cooked ham, potato salad, cream and"
2955 PRINT"custard pastries etc.
2960 PRINT
2965 PRINT"Bacillus cereus produces an enterotoxin also, and a similar"
2970 PRINT"clinical picture. It is uncommon.  The sources are usually"
2975 PRINT"fried rice, corn flour and meat that cools slowly and is then"
2980 PRINT"served the next day.
2985 PRINT
2990 PRINT"TREATMENT is symptomatic for both, with attention to fluid"
2995 PRINT"balance and relief of cramps. Antibiotics are not indicated."
3000 PRINT
3005 PRINT"Symptoms tend to subside in 8 hrs. with recovery in 1-3 days"
3010 PRINT"B.cereus tends to have a much shorter course."
3015 PRINT
3020 PRINT
3025 PRINT
3030 GOTO 3465'                   ~~~~ Entamoeba histolytica ~~~~~
3035 PRINT"The protozoa Entamoeba histolytica is suggested. While usually"
3040 PRINT"a chronic problem, it occasionally causes an acute diarrhea in"
3045 PRINT"visitors to endemic areas."
3050 PRINT
3055 PRINT"The acute stage is characterized by cramps, nausea/vomiting  and"
3060 PRINT"persistant diarrhea, often with blood, but without many WBC. The"
3065 PRINT"organism can be identified in a fresh, warm, stool specimen, but"
3070 PRINT"it is imperative that a preserved specimen be saved and properly"
3075 PRINT"confirmed if trained technicians are not available......BEFORE a "
3080 PRINT"course of treatment is begun."
3085 PRINT
3090 PRINT"Specific Treatment consists of:"
3095 PRINT
3100 PRINT"Metronidazole     750 mg PO tid for 10 days (adult)"
3105 PRINT"                  30-50 mg/kg/day in 3 divided doses X 10 days"
3110 PRINT"                        (in children)"
3115 PRINT"AND"
3120 PRINT
3125 PRINT"Diiodohydroxyquin 650 mg PO tid for 20 days (adult)"
3130 PRINT"                  30-40 mg/kg/day in 3 divided doses X 20 days"
3135 PRINT"                        (in children)"
3140 PRINT:PRINT:GOTO 3465'                     ~~~~~ Viral ~~~~~
3145 PRINT"The Rotoviruses (reovirus-like) have been implicated as a major"
3150 PRINT"cause of pediatric diarrhea, but transmission to family members "
3155 PRINT"may occur.   Unlike the other agents, viral diarrheas are more"
3160 PRINT"common in winter."
3165 PRINT
3170 PRINT"Clinically, the viral diarrheas are acute in onset and brief in"
3175 PRINT"duration. They are marked by vomiting, watery diarrhea and a"
3180 PRINT"low-grade fever.
3185 PRINT
3190 PRINT"The Paroviruses (Norwalk and Hawaii agents) have also been impli-"
3195 PRINT"cated in diarrheal outbreaks and tend to involve larger groups of"
3200 PRINT"both children and adults."
3205 PRINT
3210 PRINT"There is no specic treatment at this time."
3215 FOR I=1 TO 6:PRINT:NEXT
3220 GOSUB 3465'                 ~~~~~ Clostridium perfingens ~~~~~
3225 PRINT"Clostridium perfingens is the suspected agent. This bacteria "
3230 PRINT"produces an endotoxin similar to that of the heat-labile one"
3235 PRINT"from E.coli."
3240 PRINT
3245 PRINT"The clinical course is marked by afebrile watery diarrhea with"
3250 PRINT"nausea. Vomiting is usually absent but griping abdominal pain"
3255 PRINT"is characteristic. Recovery in 12 hours is usual.
3260 PRINT
3265 PRINT"The common sources are: mince-meat pie and meats cooled slowly"
3270 PRINT"after cooking and served the next day.
3275 PRINT
3280 PRINT"Treatment is symptomatic. Since the agent is an endotoxin, an"
3285 PRINT"antibiotic is not indicated.."
3290 PRINT
3295 PRINT"Toxigenic E.coli does not usually present with significant "
3300 PRINT"fever, but it may. You might wish to rerun indicating 'Yes'"
3305 PRINT"to the fever to review that condition"
3310 FOR I=1 TO 6:PRINT:NEXT
3315 GOSUB 3465'                ~~~~~ Salmonella enteritidis ~~~~~
3320 PRINT"Salmonella enteritidis  (and the related non-typhoid species)"
3325 PRINT"present similar clinical pictures with a considerably milder"
3330 PRINT"with a considerably more acute course in the non-typhoid ones."
3335 PRINT
3340 PRINT"The bacteria invade the ileal mucosa and remain intracellular"
3345 PRINT"where they provoke a leukocytic response (in contrast to the"
3350 PRINT"usual mononuclear response of S.typhi."
3355 PRINT
3360 PRINT"The clinical course is one of abdominal pain, chills and fever"
3365 PRINT"frequent vomiting and prostration after a relativly short (12-"
3370 PRINT"72 hr.) incubation. WBC's and occasionally,blood, are present"
3375 PRINT"in the stool in contrast to the usual mononuclear response of"
3380 PRINT"Salmonella typhi."
3385 PRINT
3390 PRINT"The usual sources are: beef and pre-cooked meats, ice cream and"
3395 PRINT"poultry."
3400 PRINT
3405 PRINT"Because of the large bacterial 'dose' reequired, common- source"
3410 PRINT"epidemics are more common than patient-to-patient transfer."
3415 PRINT:PRINT:INPUT"   <hit 'return' for more>     ";Q$
3420 PRINT
3425 PRINT"TREATMENT: Because of the protected intracellular nature of the"
3430 PRINT"           bacteria, antibiotics are contraindicated .. and may"
3435 PRINT"           prolong the 'carrier-state' of bacterial shedding"
3440 PRINT
3445 PRINT"           Fluid management and relief of pain are the primary"
3450 PRINT"           theraputic considerations."
3455 PRINT:GOTO 3465
3460 '===== Subprogram to give user a chance to change entries =========
3465 INPUT"                      <hit 'return' when ready> ";Q$
3470 PRINT CHR$(12)
3475 FOR I=1 TO 6:PRINT:NEXT
3480 PRINT"1} Would you like to review your entries with a possible"
3485 PRINT"   view towards modifying them for an alternate diagnosis "
3490 PRINT
3495 PRINT"2} Review outpatient (home) fluid therapy"
3500 PRINT
3505 INPUT"3} Quit the program                       Ans. 1,2 or 3  ";Q
3510 IF Q>3 THEN PRINT:GOTO 3480
3515 IF Q=1 THEN RESTORE:GOTO 620
3520 IF Q=3 THEN END'

==================== OUTPATIENT (HOME) FLUID REPLACEMENT ===============
3525 PRINT CHR$(12)
3530 PRINT TAB(20)"OUTPATIENT FLUID THERAPY"
3535 PRINT TAB(20)"========================"
3540 PRINT
3545 PRINT"The cornerstone of diarrheal therapy is replacement of the"
3550 PRINT"water,sodium chloride,potassium and bicarbonate lost.  In"
3555 PRINT"minor cases broths,carbonated drinks and commercial fluids"
3560 PRINT"such as Gatorade are sufficient.
3565 PRINT
3570 PRINT"For moderate cases, it is important that the fluid contains"
3575 PRINT"activly transported sugar to promote the absorption of NaCl"
3580 PRINT"and water across the intestinal mucosa.  A combination of 2 "
3585 PRINT"fluids  recommended by the  Center for Disease Control that"
3590 PRINT"closly matches the WHO standards:"
3595 PRINT
3600 PRINT"Glass #1  8 oz orange,apple or other high-potassium fruit juice"
3605 PRINT"          1/2 tsp. honey or corn syrup + a pinch of salt"
3610 PRINT
3615 PRINT"Glass #2  8 oz. tap water with 1/4 tsp. baking soda (bicarbonate)"
3620 PRINT
3625 PRINT"Sig. drink alternatly from each glass, supplimented by carbonated"
3630 PRINT"     drinks, tea etc. as needed."
3635 PRINT
3640 GOTO 3465'                        END OF PROGRAM
