80 'SEQNCE.BA by Rudy Bender [71426,41]
81 '(c) 1987 by Rudy Bender.  License
82 'to copy for personal use granted to
83 'CIS Photoforum members only.
84 '
90 CLS:PRINT:PRINT"SEQNCE.BA:CAMERA EXPOSURE INTERVALOMETER"
100 PRINT "ENTER INTERVAL BETWEEN EXPOSURES, IN"
111 INPUT "DECIMAL (i.e. 1.2, etc.) SECONDS:";D
120 B=INT(((307.332*D)-15)+1)
130 PRINT "IS EXPOSURE LONGER THAN 1 SECOND?"
131 INPUT "(Y or N)";J$
150 IF J$ = "Y" OR J$="y" THEN 170 ELSE 190
170 N=0:INPUT "ENTER EXPOSURE TIME IN SECONDS";K
175 M=K
180 K=(INT(K*307.332)+1):GOTO 230
190 K=0:INPUT "ENTER EXPOSURE 1/N SEC. INPUT N:";N
220 L = INT((307.332*(1/N))+1)
230 INPUT "NUMBER OF EXPOSURES IN SEQUENCE";A:O=A
231 CLS:PRINT:PRINT"NUMBER OF EXPOSURES PROGRAMED =";A
232 PRINT"INTERVAL BETWEEN EXPOSURES =";D;"SECONDS"
233 IF K>0 THEN GOTO 236
234 IF K=0 THEN PRINT"EXPOSURE TIME = 1/";N;"SECOND":GOTO 237
236 PRINT"EXPOSURE TIME = ";M;" SECONDS"
237 PRINT:INPUT"PRESS ENTER TO START EXPOSURE SEQUENCE.";G$
239 IF G$ = ""THEN 240 ELSE 100
240 MOTOR ON:FOR Z = 1TO15:NEXT Z
241 MOTOR OFF: A=A-1
250 FOR X = 1 TO A STEP 1
260 FOR E = 1 TO (B+L+K)  STEP 1
270 NEXT E
280 MOTOR ON
290 FOR Z = 1 TO  15
300 NEXT Z
310 MOTOR OFF
320 NEXT X
325 A=O
330 INPUT "REPEAT SAME SEQUENCE? (Y or N)";R$
350 IF R$ = "Y" OR R$ = "y" THEN 231 ELSE 370
370 INPUT "NEW SEQUENCE? (Y or N)";S$
390 IF S$ = "Y" OR S$="y" THEN 400 ELSE MENU
400 CLS:GOTO 100