10 REM ***************MAIN******************************
20 BEEP:CLS:CLEAR 2000
30 GOSUB 120 :'SETUP
40 GOSUB 240 :'READBASE
50 GOSUB 310 :'FILENAME
60 GOSUB 830 :'GETDAT
70 IF TIME$="00:01:00" THEN GOSUB 830 :'WAIT
72 IF TIME$>"00:01:00" THEN GOSUB 3000: TIME$="00:00:"+RIGHT$(TIME$,2):CLS:GOSUB 840
75 PRINT @135, TIME$
80 IF N < SL THEN 70
90 GOSUB 1120 :'WAYOUT
100 END
110 REM ************SETUP*******************************
120 DEFINT A-Z: N=0: ST$="": Q$="00:" :SL=0: IL=0: DIM C1$(59)
130 XE=0: BC=0: MO=0: PRINT
140 PRINT TAB(5); "        >>>RELY.BA V2<<<"
150 PRINT TAB(5); "    WRITTEN BY ELIAS ROBLES"
160 PRINT TAB(5); "FOR THE JANE GOODALL INSTITUTE"
170 PRINT TAB(5); "        MARCH  1989.
175 PRINT TAB(5); "(REVISED M.A. CLARK APRIL 1990)"
180 PRINT: PRINT  "           PRESS ANY KEY TO CONTINUE..."
190 IF INKEY$="" THEN 190
200 CLS:GOSUB 8000:'MESSAGE
210 BEEP: PRINT "PLEASE WAIT..."
220 RETURN
230 REM ************READBASE****************************
240 OPEN "RAM:NEWBEH.DO" FOR INPUT AS 1
250 FOR I = 1 TO 59
260 INPUT# 1, C1$(I)
270 NEXT I
280 CLOSE
290 RETURN
300 REM *************FILENAME*************************
310 CLS: BEEP: PRINT @ 120, "ENTER ALL DATA IN CAPITAL LETTERS":PRINT
320 INPUT "CODE OF THE OBSERVER: ";A$
330 IF ASC(LEFT$(A$,1))<65 OR ASC(LEFT$(A$,1))>90 THEN A$="":GOTO 310
570 PRINT:INPUT "ENTER CORRECT DATE (MM/DD/YY)";D$:DATE$=D$
590 ON ERROR GOTO 1240
595 PRINT:INPUT "(B)EHAVIORS OR (C)ONTEXTS:  ";FG$
596 IF FG$<>"B"AND FG$<>"C" THEN 595
690 INPUT "SESSION LENGTH IN MINUTES: ";SL
700 OF$="RAM:"+LEFT$(A$,2)+LEFT$(DATE$,2) + MID$(DATE$,4,2)+".DO"
720 OPEN OF$ FOR OUTPUT AS 1
730 PRINT# 1, SL
740 CLS:PRINT:PRINT "     SYNCHRONIZE BY PRESSING ANY KEY"
745 PRINT "          AT THE STARTING TONE....."
750 IF INKEY$=""THEN 750
760 RETURN
820 REM ************GETDAT*****************************
830 TIME$="00:00:00":CLS:DT$=""
840 BEEP:DF$="": BE$="": LT$="": SP$="": TX$="": PO$=""
845 PRINT "0) MISSED OBSERVATION"
850 PRINT "1) BAD OBSERVATION"
860 PRINT "2) PUBLIC ORIENTATION  3) AGONISTIC"
870 PRINT "4) AFFINITIVE  5) MOTHER-INFANT
880 PRINT "6) SUBMISSIVE  7) NONSOCIAL"
885 PRINT "8) BATTERIES LOW: CLOSE FILE AND RELOAD"
890 PRINT: INPUT "ENTER NUMBER OF CONTEXT: "; TX$
900 IF TX$ = "1" THEN DT$="98":GOTO 1080
905 IF TX$ = "0" THEN DT$="99":GOTO 1080
907 PRINT:INPUT "IS FOCAL OFF-GROUND?  ENTER Y/N:  ";A$: IF A$<>"Y" THEN OG$="*": GOTO 910
908 OG$="^"
910 PRINT:NT$="":DF$="":LT$="*":SP$="****":PO$="**":INPUT "BEHAVIOR:  ";BE$
920 IF BE$="0" THEN 1080
930 FOR I = 1 TO 59
940 IF BE$=LEFT$(C1$(I),4) THEN DF$=C1$(I):GOSUB 9000:'CAT
950 NEXT I
955 IF MID$(DF$,14,1)<> "1" THEN BE$=BE$+"*": GOTO 960
957 GOSUB 2000:'SUBWAY
960 CT$=MID$(DF$,5,6)
970 IF INSTR(CT$,TX$)=0 AND DF$<>"" THEN XE=XE+1
980 IF INSTR(CT$,TX$)<>0 AND DF$<>"" THEN 1020
990 IF DF$="" THEN BC=BC+1 :BEEP: PRINT "***TYPO***":GOTO 910
1000 BEEP:CLS: PRINT "***WRONG CONTEXT***": PRINT
1010 GOTO 840
1020 IF MID$(DF$,11,1)="1" THEN PRINT "LATERALITY:  ":INPUT "(L)EFT/(R)IGHT/(B)OTH/(N)EITHER: ";LT$
1025 IF MID$(DF$,11,1)="1" AND LT$<>"L" AND LT$<>"R" AND LT$<> "B" AND LT$<>"N" THEN 1020
1030 IF MID$(DF$,12,1)="1" THEN INPUT "SOCIAL PARTNER CODE: ";SP$
1040 IF LEFT$(BE$,4)="DVUS" THEN INPUT "DEVICE CODE: "; SP$
1045 IF LEFT$(BE$,4)="HOLD" THEN INPUT "OBJECT CODE: ";SP$
1050 IF MID$(DF$,13,1)="1" THEN PRINT "DIRECTIONALITY: ": INPUT "<<(FOCAL)/>>(OTHER)/<>(MUTUAL):  "; PO$
1055 IF MID$(DF$,13,1)="1" AND PO$<>">>" AND PO$<>"<<" AND PO$<>"<>" THEN 1050
1070 GOTO 910
1080 IF FG$ = "B" THEN PRINT# 1, DT$
1082 IF FG$ = "C" THEN PRINT# 1, "0";TX$
1085 ON ERROR GOTO 1110
1090 N=N+1:BEEP:CLS:PRINT @ 125,"TIMING...":PRINT "     OBSERVATIONS COMPLETED: ";N: PRINT "     OBSERVATIONS TO GO:     ";SL-N
1105 RETURN
1110 REM ****************WAYOUT*************************
1130 CLS:CLOSE
1140 PRINT "SESSION IS OVER."
1150 PRINT "FILE ";OF$
1160 PRINT "WAS WRITTEN SUCCESSFULLY"
1170 PRINT "NUMBER OF MIXED CONTEXTS: ";XE
1180 PRINT "NUMBER OF TYPOS: ";BC
1185 PRINT "MISSED OBSERVATIONS: ";MO
1190 PRINT "BYE....."
1200 BEEP:BEEP:BEEP
1205 IF INKEY$="" THEN 1205
1210 MENU
1220 REM ***************TRAPS***************************
1240 PRINT "SYNTAX ERROR": RESUME 570
2000 REM ***********SUBWAY**************
2010 CLS:BEEP:PRINT:PRINT "NO SUBMENU SPECIFICATION REQUIRED FOR"
2020 PRINT "RELIABILITY TESTING"
2030 PRINT: INPUT "HIT 'ENTER' TO CONTINUE.....";E$
2040 SM$="*"
2050 BE$=BE$+SM$
2060 RETURN
3000 REM **************OVERTIME***************
3010 NT=VAL(RIGHT$(TIME$,2)):CLS: BEEP
3015 PRINT:PRINT
3020 PRINT "OVERTIME ";NT;" SECONDS"
3030 INPUT "HIT 'ENTER' THEN '0' AS NEXT CONTEXT";CN$
3040 MO = MO+1:RETURN
8000 REM***************MESSAGE***************
8010 PRINT "THIS PROGRAM CAN ONLY BE USED"
8020 PRINT "TO OBTAIN DATA FOR MEASURING"
8030 PRINT "INTER- AND INTRA-OBSERVER RELIABILITY"
8040 PRINT "IT IS NOT ADEQUATE FOR"
8050 PRINT "REGULAR DATA COLLECTION"
8060 PRINT: PRINT ".....PRESS ANY KEY TO CONTINUE"
8070 IF INKEY$ = "" THEN 8070
8080 CLS: RETURN
9000 REM ***************CAT***************
9010 IF I<10 THEN DU$ = "0" + RIGHT$(STR$(I),1)
9020 IF I>9 THEN DU$ = RIGHT$(STR$(I),2)
9030 DT$ = DT$ + DU$
9040 RETURN