0 'JOURNL.BA for the Model 200 & CLUB   100 Library - 415/939-1246 BBS, VOICE   PHONE 714-521-7491 DAVID
3 CLS:PRINT "PASSWORD FOR THIS PROGRAM IS ABLE TO BE CHANGED."
4 PRINT" TO CHANGE IT GO TO LINE 9 AND ADD NEW  WORD. THEN DELETE LINE 3-5. PASSWORD IS CURRENTLY <HACKYSAC> IN CAPS"
5 FORX=1TO2300:NEXTX
9 A$="HACKYSAC"
10 CLS:INPUT"You Must Enter The Correct Password To  Enter This Journal Program. You Have One Try. Enter Now";P$
15 IFP$=A$THEN25
20 MENU
25 CLS
35 LINE (0,0)-(239,63),1,BF:LINE (5,5)-(234,58),2,BF
40 PRINT@10,"DAILY JOURNAL PROGRAM":PRINT@87,"By David Leibowitz - 07/90":PRINT@126,"Keeps a Running Daily Journal"
45 PRINT@170,"For Public Domain Use":PRINT@208,"Voice Phone 714-521-7491"
46 PRINT@254,"PRESS ANY KEY"
50 Z$=INKEY$:IF Z$="" THEN 50 ELSE 55
55 R$ = CHR$(27)+CHR$(112)
60 N$ = CHR$(27)+CHR$(113)
65 CLS:PRINT
70 PRINTTAB(12) R$ "JERNAL MAIN MENU"N$
80 PRINT:PRINT
90 PRINTTAB(9) "(1) Enter Todays Log"
100 PRINTTAB(9)"(2) Encode & Decode Menu"
101 PRINTTAB(9)"(3) Exit To Main Menu"
110 PRINT:PRINT
111 PRINT"YOU MUST DECODE FILE BEFORE ENTERING LOG"
113 PRINT:PRINT:PRINT:PRINT:PRINT
115 INPUT"WHAT NUMBER DO YOU CHOOSE 1 OR 2";K
120 IFK=1THEN140
125 IFK=2THEN200
126 IFK=3THENMENU
130 IFK>3THEN55
135 IFK<1THEN55
140 OPEN "RAM:LOG.DO" FOR APPEND AS#1
145 PRINT #1,"======================================="
150 PRINT #1,"        ==>>Log Entry<<=="
155 PRINT#1,"          >>";DATE$;"<<"
160 PRINT#1,"      ** ";DAY$;" == ";TIME$;" **":PRINT#1,
165 CLS:PRINT"**************************************"
170 PRINT "Log entry for ";DATE$;"=";TIME$:PRINT
175 INPUT "Start Entry Here";Q$
180 PRINT#1,Q$
185 GOTO 55
200 MAXFILES=2
201 R$=CHR$(27)+CHR$(112)
203 N$=CHR$(27)+CHR$(113)
205 CLS:INPUT" Master Codes xx,xx";H,I
206 PRINT:PRINTR$"WHEN CODING USE LOG.DO AS THE FILE TO BE CODED AND CODE.DO AS THE NEW FILE      "N$
207 PRINT:PRINT "IMPORTANT! REMEMBER MASTER CODE NUMBERS"
208 PRINT:PRINT R$"WHEN DECODING USE CODE.DO AS THE FILE TO BE DECODED AND LOG.DO AS THE NEW FILE  "N$
210 PRINT:PRINT" Will you be..."
215 PRINT"               1 - CODING"
220 PRINT"               2 - DECODING"
225 INPUT"               3 - EXIT TO JOURNAL";Z
230 IFZ<1THEN210
235 IFZ>3THEN210
236 IFZ=3THEN55
240 PRINT" File to be ";
245 IFZ=2THENPRINT"de";
250 INPUT"coded";A$
255 INPUT" Name of new file";B$
260 IFLEN(B$)>6THENCLS:PRINT"New file name must be less then 6 characters":GOTO255
265 PRINT"TRANSLATION UNDERWAY -- Please wait"
270 OPENA$FORINPUTAS1
275 OPENB$FOROUTPUTAS2
280 N=5:IFZ=2GOTO315
285 C$=INPUT$(1,1):D$=CHR$(ASC(C$)+N)
290 IFD$=CHR$(127)THEND$=CHR$(33):GOTO300
295 IFD$=CHR$(224)THEND$=CHR$(36)
300 PRINT#2,D$;:N=N+H:IFN=>ITHENN=5
305 IFEOF(1)THEN340
310 GOTO285
315 E$=INPUT$(1,1):IFE$=CHR$(33)THENE$=CHR$(127):GOTO325
320 IFE$=CHR$(36)THENE$=CHR$(224)
325 F$=CHR$(ASC(E$)-N):PRINT#2,F$;:N=N+H:IFN=>ITHENN=5
330 IFEOF(1)THEN340
335 GOTO315
340 PRINT" File converted"
345 FORT=1TO10:BEEP:NEXT
350 CLS:PRINT:PRINTTAB(15)"KILL MENU"
355 PRINT:PRINT:PRINTTAB(9)"(1) Kill LOG.DO":PRINTTAB(9)"(2) Kill CODE.DO":PRINTTAB(9)"(3) Exit Back to Journal"
360 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT
365 INPUT "WHAT NUMBER DO YOU CHOOSE";O
370 IFO=1THEN400
375 IFO=2THEN500
380 IFO=3THEN55
385 IFO<1THEN350
390 IFO>3THEN350
400 CLOSE:KILL "LOG.DO"
410 GOTO 55
500 CLOSE:KILL "CODE.DO"
510 GOTO 55