0 CLS:PRINT@54,"BANK FINANCE":PRINT@133,"COPYRIGHT 1983":PRINT@166,"COMPLETE COMPUTER SERVICES":PRINT@209,"NEWBURGH, IN.  47630":LINE(5,5)-(234,57),1,B:SOUND3000,25:SOUND3000,25:SOUND2000,40:FORX=1TO500:NEXT
10 A$="$$##,###.##"
20 CLS:PRINT:PRINT"1. COMPUTE LOANS":PRINT"2. COMPUTE SAVINGS":INPUT"ENTER OPTION 1 OR 2";X:ONXGOTO30,50
30 CLS:PRINT:PRINT"1. COMPUTE MONTHLY PAYMENT":PRINT"2. AMOUNT YOU MAY BORROW":PRINT"3. LIST PAYMENT SCHEDULE":INPUT"ENTER OPTION 1, 2, OR 3";X
40 ONXGOTO70,110,150
50 CLS:PRINT:PRINT"INTEREST BASED ON QUARTERLY COMPOUNDING":PRINT:PRINT"1. COMPUTE COMPOUND INT ON FIXED AMOUNT":PRINT"2. WEEKLY SAVINGS GROWTH":PRINT"3. WEEKLY SAVINGS TO REACH A GOAL":INPUT"ENTER OPTION 1, 2, OR 3";X
60 ONXGOTO250,290,330
70 J$="LOAN":K$="INT RT":L$="YRS":GOSUB370:PV=J:I9=K:Y=L
80 I=I9/100/12:PM=PV*(I/(1-(1+I)^(Y*-12)))
90 PRINT"MO PMT";USINGA$;PM;:PRINT"  TOTAL";USINGA$;PM*Y*12
100 GOTO70
110 J$="PMT":K$="INT RT":L$="YRS":GOSUB370:PM=J:I9=K:Y=L
120 I=I9/100/12:PV=PM*((1-(1+I)^(Y*-12))/I)
130 PRINT"YOU MAY BORROW";USINGA$;PV
140 GOTO110
150 J$="LOAN":K$="PMT":L$="INT RT":GOSUB370:PV=J:PM=K:I9=L:I=I9/12/100:PRINT"LOAN START DATE MO,YR":INPUT"(FOR EXAMPLE 4,92)";M,Y
160 CLS
170 M=M+1:IFM>12THENM=1:GOSUB230
180 I1=INT((I*PV*100)+.5)/100:IFPV<PMTHENPM=PV+I1
190 PR=PM-I1:PV=PV-PR:TI=TI+I1:TP=TP+PR
200 GOSUB220:PRINT@280,USING"##!##";M;"/";Y;:PRINTUSINGA$;PR;:PRINTUSINGA$;I1;:PRINT" ";:PRINTUSINGA$;PV
210 IFPV<1THENGOSUB230:ENDELSEGOTO170
220 PRINT@0,STRING$(39," "):PRINT"DATE    PRINCIPLE  INTEREST     BALANCE":RETURN
230 GOSUB220:PRINT@280,"TOTAL";:PRINTUSINGA$;TP;:PRINTUSINGA$;TI:FORXY=1TO1500:NEXT:TP=0:TI=0:Y=Y+1:IFY>99THENY=99
240 RETURN
250 J$="BAL":K$="INT RT":L$="YEARS":GOSUB370:PV=J:I9=K:Y=L:P=4:I=I9/100/P:Y1=P*Y
260 FV=PV*(1+I)^Y1
270 PRINT"TOTAL WITH INT.";USINGA$;FV
280 GOTO250
290 J$="WK PMT":K$="INT RT":L$="YEARS":GOSUB370:PM=J:I9=K:Y=L:P=4:I=I9/100/P
300 X=PM*13:Z=Y*P:FV=X*((1+I)^Z-1)/I
310 PRINT"TOTAL WITH INT";USINGA$;FV
320 GOTO290
330 J$="GOAL":K$="INT RT":L$="YEARS":GOSUB370:FV=J:I9=K:Y=L:P=4:I=I9/100/P
340 Z=Y*P:X=FV*I/((1+I)^Z-1):PM=X/13
350 PRINT"WEEKLY SAVINGS";USINGA$;PM
360 GOTO330
370 C=CSRLIN:IFC>5THENC=6
380 C=C*40:PRINTJ$;:INPUTX$:IFX$="T"THEN20ELSEIFX$="Menu"THENMENU
390 J=VAL(X$):PRINT@C+16,K$;:INPUTK:PRINT@C+30,L$;:INPUTL:RETURN