How can I add a property of my own to the TActionList?
lazarus / 31-LCL

----------------------------------------------------------------------
sainimu78 · 2015-07-03 17:15

How can I add a property of my own to the TActionList?

I want my property can be shown on the "Object Inspector" window.

----------------------------------------------------------------------
howardpc · 2015-07-03 18:10

You don't say what the type of the new property will be.

The following gives you a simple example of the minimum needed for a
package that provides an ActionListEx, (an ActionList extended with
the addition of one string property). Adding ordinal and string
properties is straightforward. More complex properties might require
that you also write a property editor for use by the Object Inspector.

Code: [Select]unit ActionListEx;

{$mode objfpc}{$H+}

interface

uses
  Classes, LResources, Forms, Controls, Graphics, Dialogs, ActnList;

type

  { TActionListEx }

  TActionListEx = class(TActionList)
  strict private
    FNewStringProp: string;
    procedure SetNewStringProp(AValue: string);
  published
    property NewStringProp: string read FNewStringProp write
SetNewStringProp;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Standard',[TActionListEx]);
end;

{ TActionListEx }

procedure TActionListEx.SetNewStringProp(AValue: string);
begin
  if FNewStringProp=AValue then Exit;
  FNewStringProp:=AValue;
end;

end.