tgettext.m4 - vaccinewars - be a doctor and try to vaccinate the world
(HTM) git clone git://src.adamsgaard.dk/vaccinewars
(DIR) Log
(DIR) Files
(DIR) Refs
(DIR) README
(DIR) LICENSE
---
tgettext.m4 (14488B)
---
1 # gettext.m4 serial 71 (gettext-0.20.2)
2 dnl Copyright (C) 1995-2014, 2016, 2018-2020 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6 dnl
7 dnl This file can be used in projects which are not available under
8 dnl the GNU General Public License or the GNU Lesser General Public
9 dnl License but which still want to provide support for the GNU gettext
10 dnl functionality.
11 dnl Please note that the actual code of the GNU gettext library is covered
12 dnl by the GNU Lesser General Public License, and the rest of the GNU
13 dnl gettext package is covered by the GNU General Public License.
14 dnl They are *not* in the public domain.
15
16 dnl Authors:
17 dnl Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
18 dnl Bruno Haible <haible@clisp.cons.org>, 2000-2006, 2008-2010.
19
20 dnl Macro to add for using GNU gettext.
21
22 dnl Usage: AM_GNU_GETTEXT([INTLSYMBOL], [NEEDSYMBOL], [INTLDIR]).
23 dnl INTLSYMBOL must be one of 'external', 'use-libtool'.
24 dnl INTLSYMBOL should be 'external' for packages other than GNU gettext, and
25 dnl 'use-libtool' for the packages 'gettext-runtime' and 'gettext-tools'.
26 dnl If INTLSYMBOL is 'use-libtool', then a libtool library
27 dnl $(top_builddir)/intl/libintl.la will be created (shared and/or static,
28 dnl depending on --{enable,disable}-{shared,static} and on the presence of
29 dnl AM-DISABLE-SHARED).
30 dnl If NEEDSYMBOL is specified and is 'need-ngettext', then GNU gettext
31 dnl implementations (in libc or libintl) without the ngettext() function
32 dnl will be ignored. If NEEDSYMBOL is specified and is
33 dnl 'need-formatstring-macros', then GNU gettext implementations that don't
34 dnl support the ISO C 99 <inttypes.h> formatstring macros will be ignored.
35 dnl INTLDIR is used to find the intl libraries. If empty,
36 dnl the value '$(top_builddir)/intl/' is used.
37 dnl
38 dnl The result of the configuration is one of three cases:
39 dnl 1) GNU gettext, as included in the intl subdirectory, will be compiled
40 dnl and used.
41 dnl Catalog format: GNU --> install in $(datadir)
42 dnl Catalog extension: .mo after installation, .gmo in source tree
43 dnl 2) GNU gettext has been found in the system's C library.
44 dnl Catalog format: GNU --> install in $(datadir)
45 dnl Catalog extension: .mo after installation, .gmo in source tree
46 dnl 3) No internationalization, always use English msgid.
47 dnl Catalog format: none
48 dnl Catalog extension: none
49 dnl If INTLSYMBOL is 'external', only cases 2 and 3 can occur.
50 dnl The use of .gmo is historical (it was needed to avoid overwriting the
51 dnl GNU format catalogs when building on a platform with an X/Open gettext),
52 dnl but we keep it in order not to force irrelevant filename changes on the
53 dnl maintainers.
54 dnl
55 AC_DEFUN([AM_GNU_GETTEXT],
56 [
57 dnl Argument checking.
58 ifelse([$1], [], , [ifelse([$1], [external], , [ifelse([$1], [use-libtool], ,
59 [errprint([ERROR: invalid first argument to AM_GNU_GETTEXT
60 ])])])])
61 ifelse(ifelse([$1], [], [old])[]ifelse([$1], [no-libtool], [old]), [old],
62 [errprint([ERROR: Use of AM_GNU_GETTEXT without [external] argument is no longer supported.
63 ])])
64 ifelse([$2], [], , [ifelse([$2], [need-ngettext], , [ifelse([$2], [need-formatstring-macros], ,
65 [errprint([ERROR: invalid second argument to AM_GNU_GETTEXT
66 ])])])])
67 define([gt_included_intl],
68 ifelse([$1], [external], [no], [yes]))
69 gt_NEEDS_INIT
70 AM_GNU_GETTEXT_NEED([$2])
71
72 AC_REQUIRE([AM_PO_SUBDIRS])dnl
73 ifelse(gt_included_intl, yes, [
74 AC_REQUIRE([AM_INTL_SUBDIR])dnl
75 ])
76
77 dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
78 AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
79 AC_REQUIRE([AC_LIB_RPATH])
80
81 dnl Sometimes libintl requires libiconv, so first search for libiconv.
82 dnl Ideally we would do this search only after the
83 dnl if test "$USE_NLS" = "yes"; then
84 dnl if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" != "yes"; }; then
85 dnl tests. But if configure.in invokes AM_ICONV after AM_GNU_GETTEXT
86 dnl the configure script would need to contain the same shell code
87 dnl again, outside any 'if'. There are two solutions:
88 dnl - Invoke AM_ICONV_LINKFLAGS_BODY here, outside any 'if'.
89 dnl - Control the expansions in more detail using AC_PROVIDE_IFELSE.
90 dnl Since AC_PROVIDE_IFELSE is not documented, we avoid it.
91 ifelse(gt_included_intl, yes, , [
92 AC_REQUIRE([AM_ICONV_LINKFLAGS_BODY])
93 ])
94
95 dnl Sometimes, on Mac OS X, libintl requires linking with CoreFoundation.
96 gt_INTL_MACOSX
97
98 dnl Set USE_NLS.
99 AC_REQUIRE([AM_NLS])
100
101 ifelse(gt_included_intl, yes, [
102 BUILD_INCLUDED_LIBINTL=no
103 USE_INCLUDED_LIBINTL=no
104 ])
105 LIBINTL=
106 LTLIBINTL=
107 POSUB=
108
109 dnl Add a version number to the cache macros.
110 case " $gt_needs " in
111 *" need-formatstring-macros "*) gt_api_version=3 ;;
112 *" need-ngettext "*) gt_api_version=2 ;;
113 *) gt_api_version=1 ;;
114 esac
115 gt_func_gnugettext_libc="gt_cv_func_gnugettext${gt_api_version}_libc"
116 gt_func_gnugettext_libintl="gt_cv_func_gnugettext${gt_api_version}_libintl"
117
118 dnl If we use NLS figure out what method
119 if test "$USE_NLS" = "yes"; then
120 gt_use_preinstalled_gnugettext=no
121 ifelse(gt_included_intl, yes, [
122 AC_MSG_CHECKING([whether included gettext is requested])
123 AC_ARG_WITH([included-gettext],
124 [ --with-included-gettext use the GNU gettext library included here],
125 nls_cv_force_use_gnu_gettext=$withval,
126 nls_cv_force_use_gnu_gettext=no)
127 AC_MSG_RESULT([$nls_cv_force_use_gnu_gettext])
128
129 nls_cv_use_gnu_gettext="$nls_cv_force_use_gnu_gettext"
130 if test "$nls_cv_force_use_gnu_gettext" != "yes"; then
131 ])
132 dnl User does not insist on using GNU NLS library. Figure out what
133 dnl to use. If GNU gettext is available we use this. Else we have
134 dnl to fall back to GNU NLS library.
135
136 if test $gt_api_version -ge 3; then
137 gt_revision_test_code='
138 #ifndef __GNU_GETTEXT_SUPPORTED_REVISION
139 #define __GNU_GETTEXT_SUPPORTED_REVISION(major) ((major) == 0 ? 0 : -1)
140 #endif
141 changequote(,)dnl
142 typedef int array [2 * (__GNU_GETTEXT_SUPPORTED_REVISION(0) >= 1) - 1];
143 changequote([,])dnl
144 '
145 else
146 gt_revision_test_code=
147 fi
148 if test $gt_api_version -ge 2; then
149 gt_expression_test_code=' + * ngettext ("", "", 0)'
150 else
151 gt_expression_test_code=
152 fi
153
154 AC_CACHE_CHECK([for GNU gettext in libc], [$gt_func_gnugettext_libc],
155 [AC_LINK_IFELSE(
156 [AC_LANG_PROGRAM(
157 [[
158 #include <libintl.h>
159 #ifndef __GNU_GETTEXT_SUPPORTED_REVISION
160 extern int _nl_msg_cat_cntr;
161 extern int *_nl_domain_bindings;
162 #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_domain_bindings)
163 #else
164 #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0
165 #endif
166 $gt_revision_test_code
167 ]],
168 [[
169 bindtextdomain ("", "");
170 return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION
171 ]])],
172 [eval "$gt_func_gnugettext_libc=yes"],
173 [eval "$gt_func_gnugettext_libc=no"])])
174
175 if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" != "yes"; }; then
176 dnl Sometimes libintl requires libiconv, so first search for libiconv.
177 ifelse(gt_included_intl, yes, , [
178 AM_ICONV_LINK
179 ])
180 dnl Search for libintl and define LIBINTL, LTLIBINTL and INCINTL
181 dnl accordingly. Don't use AC_LIB_LINKFLAGS_BODY([intl],[iconv])
182 dnl because that would add "-liconv" to LIBINTL and LTLIBINTL
183 dnl even if libiconv doesn't exist.
184 AC_LIB_LINKFLAGS_BODY([intl])
185 AC_CACHE_CHECK([for GNU gettext in libintl],
186 [$gt_func_gnugettext_libintl],
187 [gt_save_CPPFLAGS="$CPPFLAGS"
188 CPPFLAGS="$CPPFLAGS $INCINTL"
189 gt_save_LIBS="$LIBS"
190 LIBS="$LIBS $LIBINTL"
191 dnl Now see whether libintl exists and does not depend on libiconv.
192 AC_LINK_IFELSE(
193 [AC_LANG_PROGRAM(
194 [[
195 #include <libintl.h>
196 #ifndef __GNU_GETTEXT_SUPPORTED_REVISION
197 extern int _nl_msg_cat_cntr;
198 extern
199 #ifdef __cplusplus
200 "C"
201 #endif
202 const char *_nl_expand_alias (const char *);
203 #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_expand_alias (""))
204 #else
205 #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0
206 #endif
207 $gt_revision_test_code
208 ]],
209 [[
210 bindtextdomain ("", "");
211 return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION
212 ]])],
213 [eval "$gt_func_gnugettext_libintl=yes"],
214 [eval "$gt_func_gnugettext_libintl=no"])
215 dnl Now see whether libintl exists and depends on libiconv.
216 if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" != yes; } && test -n "$LIBICONV"; then
217 LIBS="$LIBS $LIBICONV"
218 AC_LINK_IFELSE(
219 [AC_LANG_PROGRAM(
220 [[
221 #include <libintl.h>
222 #ifndef __GNU_GETTEXT_SUPPORTED_REVISION
223 extern int _nl_msg_cat_cntr;
224 extern
225 #ifdef __cplusplus
226 "C"
227 #endif
228 const char *_nl_expand_alias (const char *);
229 #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_expand_alias (""))
230 #else
231 #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0
232 #endif
233 $gt_revision_test_code
234 ]],
235 [[
236 bindtextdomain ("", "");
237 return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION
238 ]])],
239 [LIBINTL="$LIBINTL $LIBICONV"
240 LTLIBINTL="$LTLIBINTL $LTLIBICONV"
241 eval "$gt_func_gnugettext_libintl=yes"
242 ])
243 fi
244 CPPFLAGS="$gt_save_CPPFLAGS"
245 LIBS="$gt_save_LIBS"])
246 fi
247
248 dnl If an already present or preinstalled GNU gettext() is found,
249 dnl use it. But if this macro is used in GNU gettext, and GNU
250 dnl gettext is already preinstalled in libintl, we update this
251 dnl libintl. (Cf. the install rule in intl/Makefile.in.)
252 if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" = "yes"; } \
253 || { { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; } \
254 && test "$PACKAGE" != gettext-runtime \
255 && test "$PACKAGE" != gettext-tools; }; then
256 gt_use_preinstalled_gnugettext=yes
257 else
258 dnl Reset the values set by searching for libintl.
259 LIBINTL=
260 LTLIBINTL=
261 INCINTL=
262 fi
263
264 ifelse(gt_included_intl, yes, [
265 if test "$gt_use_preinstalled_gnugettext" != "yes"; then
266 dnl GNU gettext is not found in the C library.
267 dnl Fall back on included GNU gettext library.
268 nls_cv_use_gnu_gettext=yes
269 fi
270 fi
271
272 if test "$nls_cv_use_gnu_gettext" = "yes"; then
273 dnl Mark actions used to generate GNU NLS library.
274 BUILD_INCLUDED_LIBINTL=yes
275 USE_INCLUDED_LIBINTL=yes
276 LIBINTL="ifelse([$3],[],\${top_builddir}/intl,[$3])/libintl.la $LIBICONV $LIBTHREAD"
277 LTLIBINTL="ifelse([$3],[],\${top_builddir}/intl,[$3])/libintl.la $LTLIBICONV $LTLIBTHREAD"
278 LIBS=`echo " $LIBS " | sed -e 's/ -lintl / /' -e 's/^ //' -e 's/ $//'`
279 fi
280
281 CATOBJEXT=
282 if test "$gt_use_preinstalled_gnugettext" = "yes" \
283 || test "$nls_cv_use_gnu_gettext" = "yes"; then
284 dnl Mark actions to use GNU gettext tools.
285 CATOBJEXT=.gmo
286 fi
287 ])
288
289 if test -n "$INTL_MACOSX_LIBS"; then
290 if test "$gt_use_preinstalled_gnugettext" = "yes" \
291 || test "$nls_cv_use_gnu_gettext" = "yes"; then
292 dnl Some extra flags are needed during linking.
293 LIBINTL="$LIBINTL $INTL_MACOSX_LIBS"
294 LTLIBINTL="$LTLIBINTL $INTL_MACOSX_LIBS"
295 fi
296 fi
297
298 if test "$gt_use_preinstalled_gnugettext" = "yes" \
299 || test "$nls_cv_use_gnu_gettext" = "yes"; then
300 AC_DEFINE([ENABLE_NLS], [1],
301 [Define to 1 if translation of program messages to the user's native language
302 is requested.])
303 else
304 USE_NLS=no
305 fi
306 fi
307
308 AC_MSG_CHECKING([whether to use NLS])
309 AC_MSG_RESULT([$USE_NLS])
310 if test "$USE_NLS" = "yes"; then
311 AC_MSG_CHECKING([where the gettext function comes from])
312 if test "$gt_use_preinstalled_gnugettext" = "yes"; then
313 if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; }; then
314 gt_source="external libintl"
315 else
316 gt_source="libc"
317 fi
318 else
319 gt_source="included intl directory"
320 fi
321 AC_MSG_RESULT([$gt_source])
322 fi
323
324 if test "$USE_NLS" = "yes"; then
325
326 if test "$gt_use_preinstalled_gnugettext" = "yes"; then
327 if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; }; then
328 AC_MSG_CHECKING([how to link with libintl])
329 AC_MSG_RESULT([$LIBINTL])
330 AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCINTL])
331 fi
332
333 dnl For backward compatibility. Some packages may be using this.
334 AC_DEFINE([HAVE_GETTEXT], [1],
335 [Define if the GNU gettext() function is already present or preinstalled.])
336 AC_DEFINE([HAVE_DCGETTEXT], [1],
337 [Define if the GNU dcgettext() function is already present or preinstalled.])
338 fi
339
340 dnl We need to process the po/ directory.
341 POSUB=po
342 fi
343
344 ifelse(gt_included_intl, yes, [
345 dnl In GNU gettext we have to set BUILD_INCLUDED_LIBINTL to 'yes'
346 dnl because some of the testsuite requires it.
347 BUILD_INCLUDED_LIBINTL=yes
348
349 dnl Make all variables we use known to autoconf.
350 AC_SUBST([BUILD_INCLUDED_LIBINTL])
351 AC_SUBST([USE_INCLUDED_LIBINTL])
352 AC_SUBST([CATOBJEXT])
353 ])
354
355 dnl For backward compatibility. Some Makefiles may be using this.
356 INTLLIBS="$LIBINTL"
357 AC_SUBST([INTLLIBS])
358
359 dnl Make all documented variables known to autoconf.
360 AC_SUBST([LIBINTL])
361 AC_SUBST([LTLIBINTL])
362 AC_SUBST([POSUB])
363 ])
364
365
366 dnl gt_NEEDS_INIT ensures that the gt_needs variable is initialized.
367 m4_define([gt_NEEDS_INIT],
368 [
369 m4_divert_text([DEFAULTS], [gt_needs=])
370 m4_define([gt_NEEDS_INIT], [])
371 ])
372
373
374 dnl Usage: AM_GNU_GETTEXT_NEED([NEEDSYMBOL])
375 AC_DEFUN([AM_GNU_GETTEXT_NEED],
376 [
377 m4_divert_text([INIT_PREPARE], [gt_needs="$gt_needs $1"])
378 ])
379
380
381 dnl Usage: AM_GNU_GETTEXT_VERSION([gettext-version])
382 AC_DEFUN([AM_GNU_GETTEXT_VERSION], [])
383
384
385 dnl Usage: AM_GNU_GETTEXT_REQUIRE_VERSION([gettext-version])
386 AC_DEFUN([AM_GNU_GETTEXT_REQUIRE_VERSION], [])