tfig-sediment_flux.gp - hansen-zoet-exp - comparison of lab and model results of sediment advection
 (HTM) git clone git://src.adamsgaard.dk/hansen-zoet-exp
 (DIR) Log
 (DIR) Files
 (DIR) Refs
 (DIR) Submodules
       ---
       tfig-sediment_flux.gp (1539B)
       ---
            1 #!/usr/bin/env gnuplot
            2 
            3 reset
            4 
            5 set terminal pdfcairo enhanced color size 8.3 cm, 10.3 cm font ",10"
            6 set multiplot layout 2,1
            7 
            8 rswidth = 1
            9 
           10 set lmargin 9.0
           11 set bmargin 3.5
           12 set rmargin 2.0
           13 set tmargin 2.0
           14 
           15 labelx = 0.05
           16 set label "a" at screen labelx,0.98 font "{:Bold},12"
           17 set label "b" at screen labelx,0.48 font "{:Bold},12"
           18 
           19 # https://sodocumentation.net/gnuplot/topic/8825/fit-data-with-gnuplot
           20 #f(x) = a * exp(b * x)
           21 f(x, v) = a * x**b * v
           22 fit f(x, 100) "sediment_flux_v3.169e-6ms.txt" u ($1/1000):($2*3600*24*365.25*rswidth) via a,b
           23 fitparams = sprintf("{/:Italic q}_t = %.2e {/:Italic v N'}^{%.3g}", a, b)
           24 
           25 set xlabel "Effective stress, {/:Italic N'} [kPa]"
           26 set ylabel "Sediment flux, {/:Italic q}_t [m²/a]"
           27 set key bottom right font ",09" invert samplen 1.0 box lw 0.5
           28 #set title "{/:Italic v} = 100 m/a"
           29 set xrange [0:210]
           30 set xtics 0,50,200
           31 
           32 set title "{/:Italic v} = 100 m/a"
           33 set yrange [0:1.1]
           34 plot f(x, 100) lt 1 t fitparams, \
           35         "sediment_flux_v3.169e-6ms.txt" u ($1/1000):($2*3600*24*365.25*rswidth) w p lt 2 ps 0.5 t "CNGF-PF (Damsgaard et al., 2020)", \
           36         "rs_sediment_flux_100ma_high-N.txt" u ($1/1000):($2) w p lt 4 ps 1 t "Hansen and Zoet (2022)", \
           37         "rs_sediment_flux_100ma.txt" u ($1/1000):($2) w p lt 4 ps 1 t ""
           38 
           39 set title "{/:Italic v} = 300 m/a"
           40 set yrange [0:*]
           41 plot f(x, 300) lt 1 t fitparams, \
           42         "sediment_flux_v9.506e-6ms.txt" u ($1/1000):($2*3600*24*365.25*rswidth) w p lt 2 ps 0.5 t "CNGF-PF (Damsgaard et al., 2020)", \
           43         "rs_sediment_flux_300ma.txt" u ($1/1000):($2) w p lt 4 ps 1 t "Hansen and Zoet (2022)"