tfig.gp - cngf-pf-exp1 - experiments for first paper with continuum granular model
 (HTM) git clone git://src.adamsgaard.dk/manus_continuum_granular1_exp
 (DIR) Log
 (DIR) Files
 (DIR) Refs
 (DIR) Submodules
 (DIR) README
 (DIR) LICENSE
       ---
       tfig.gp (1467B)
       ---
            1 #!/usr/bin/env gnuplot
            2 reset
            3 
            4 set terminal pdfcairo color size 7.5 cm, 10.5 cm
            5 
            6 set multiplot layout 4,1 \
            7         margins 0.19,0.72,0.10,0.98 \
            8         spacing 0.00,0.03
            9 
           10 set key top right samplen 1.0 font ",10"
           11 unset xlabel
           12 set xtics format ""
           13 set yrange [0:320]
           14 set ylabel "{/:Normal [kPa]}"
           15 set ytics 100
           16 
           17 #set label "{/:Bold a}" at screen 0.06,0.99
           18 #set label "{/:Bold b}" at screen 0.06,0.75
           19 #set label "{/:Bold c}" at screen 0.06,0.54
           20 #set label "{/:Bold d}" at screen 0.06,0.30
           21 
           22 set label "{/:Bold a}" at graph 0.05,0.9
           23 
           24 plot \
           25 "timeseries.txt" u ($0/1008*7):($2/1000) w l lw 2 lc "black" t "effective normal stress", \
           26 "" u ($0/1008*7):($3/1000) w l lw 2 lt 3 dt "-" t "water pressure"
           27 
           28 unset label
           29 set label "{/:Bold b}" at graph 0.05,0.9
           30 unset ylabel
           31 unset ytics
           32 set yrange [0:10]
           33 set y2range [0:10]
           34 set y2tics 2.0
           35 set y2label "{/:Normal Shear velocity [km/d]}"
           36 plot "" u ($0/1008*7):($1*60*60*24/1000) w l lw 2 lt 7 t ""
           37 
           38 unset label
           39 set label "{/:Bold c}" at graph 0.05,0.9
           40 unset y2label
           41 unset y2tics
           42 set ytics 0.5
           43 set yrange [2.5:0.0]
           44 set ylabel "{/:Normal Depth of max. strain rate [m]}"
           45 plot "max_strainrate_depth.txt" u ($0/1008*7):(8.0 - $1) w l lw 2 lt 4 t ""
           46 
           47 unset label
           48 set label "{/:Bold d}" at graph 0.05,0.9
           49 unset ylabel
           50 unset ytics
           51 set yrange [0.0:6e-2]
           52 set y2range [0.0:6e-2]
           53 set y2tics 2e-2
           54 set y2label "Specific sediment flux [m^2/s]"
           55 set xtics 1 format "%g"
           56 set xlabel "{/:Normal Time [d]}"
           57 plot "sediment_flux.txt" u ($0/1008*7):1 w l lw 2 lt 6 t ""