5b8
@verb #987:"hello" this none this rxdo #987
@program #987:"hello" this none this
"Determine if a player is saying 'hello' to me, and if so, answer back."
suspend(0)
for last_hello in (this.last_hello)
  if (last_hello[1] == player && last_hello[2] + 60 > time())
    return "I just said 'hello' to that player."
  endif
endfor
text = args[1][max(index(args[1], " asks, \""), index(args[1], " exclaims, \""), index(args[1], " says, \"")) + 8..length(args[1])]
while (m = match(text, "[^a-zA-Z ]"))
  text[m[1]..m[2]] = ""
endwhile
text = $string_utils:explode(text)
for word in (text)
  word in {@this.aliases, "all", "guys", "folks", "again", "everyone", "everybody", "there", "Neil"} && (text = setremove(text, word))
endfor
bingo = 0
for word in (text)
  word in {"bonjour", "gidday", "greetage", "greetings", "hallo", "hello", "helo", "hey", "hi", "hilo", "hiya", "h'lo", "howdy", "hullo", "salut", "salutations", "yallo", "yello", "yo"} && ((text = setremove(text, word)) || (bingo = 1))
endfor
if (bingo)
  last_hello = {{player, time()}}
  for record in (this.last_hello)
    record[2] + 90 > time() && (last_hello[1..0] = {record})
  endfor
  this.last_hello = last_hello
  fork (2)
    this.location:announce_all_but({this}, this:title(), " says, \"Hello, ", player:title(), ".\"")
    this:tell("You say, \"Hello, ", player:title(), ".\"")
  endfork
endif
"Last modified by Dax (#789) on Thu May 20 04:10:53 1999 MDT."
.

0