485
@verb #9699:"grab" any through this rdo #789
@program #9699:"grab" any through this
"Wizzed by Dax."
if (player.location != this.location)
  return player:tell("You don't have a long enough arm to manage that!")
elseif (!valid(dobj))
  dobj = $string_utils:match_object(dobjstr, this.dest)
endif
if (!valid(dobj))
  return player:tell("I couldn't find any ", dobjstr, " through the portal.")
elseif (dobj.location != this.dest)
  return player:tell(dobj:title(), " is not on the other side of the portal.")
endif
`set_task_perms(player) ! ANY'
this.location:announce_all(this:thisside_grab_msg())
this.dest:announce_all_but({dobj}, this:otherside_grab_msg())
dobj:tell(this:victim_grab_msg())
if (!is_player(dobj))
  `dobj:moveto(player) ! ANY'
endif
if (dobj.location != player)
  `dobj:moveto(this.location) ! ANY'
endif
if (dobj.location != player && dobj.location != this.location)
  dobj:tell(this:victim_grab_fail_msg())
  this.dest:announce_all_but({dobj}, this:otherside_grab_fail_msg())
  this.location:announce_all(this:thisside_grab_fail_msg())
endif
"Last modified by Dax (#789) on Sun Dec 30 20:21:22 2001 MST."
.

0