638
@verb #9595:"make_throw" this none this rxdo #8034
@program #9595:"make_throw" this none this
here = player.location
myThrow = $string_utils:lowercase(args[1])
" find out if a challenge has been issued in this room. "
challenge_num = $list_utils:iassoc(here, this.challenges)
if (!challenge_num)
  " add challenges "
  challenge_num = this:make_challenge()
elseif (this.challenges[challenge_num][2][1] == player)
  player:tell("You have already made the challenging throw.")
  player:tell("Type 'unthrow' to rescind the challenge.")
  return 0
endif
" unpack challenge record "
{here, throw1, throw2, start_time} = this.challenges[challenge_num]
if (throw1[2])
  " challenge throw already made. "
  if (!throw2[1])
    " answer the challenge! "
    throw2[1] = this.challenges[challenge_num][3][1] = player
  elseif (throw2[1] != player)
    " challenge player already decided. "
    player:tell("You cannot throw; this match is between ", throw1[1]:title(), " and ", throw2[1]:title(), ".")
    return 0
  endif
  throw2[2] = this.challenges[challenge_num][3][2] = myThrow
  here:announce_all(player:titlec(), " answers the challenge!")
  this:resolve_match(throw1, throw2)
  " remove challenge "
  this.challenges = listdelete(this.challenges, challenge_num)
else
  " make challenge throw. "
  throw1[1] = this.challenges[challenge_num][2][1] = player
  throw1[2] = this.challenges[challenge_num][2][2] = myThrow
  0 && $you:say_action("%N %<makes> %p challenging throw!")
endif
"Last modified by Pentomino (#8034) on Sun Aug 29 19:22:28 2004 MDT."
.

0