6f5
@verb #9595:"@rule" this is any rxdo #8034
@program #9595:"@rule" this is any
"Usage: @rule <this> is <throw> <beats> <throw> [: script]"
"  Assigns which throw defeats which throw for this roshambo game."
"  Both <throw> words must be legal throws defined by a @throwlist statement."
"  <beats> must be a third-person verb, and can be any number of words."
"  <script> is a sentence describing the interaction between the two throw symbols."
"  Example: "
"     @rule RPS is rock dents scissors: %N %<smashes> %d's scissors to an unrecognizable tangled mess!"
if (this.owner != (valid(caller_perms()) ? caller_perms() | player))
  raise(E_PERM)
endif
if (colon = index(iobjstr, ":"))
  {iobjstr, phrase} = {$su:trimr(iobjstr[1..colon - 1]), $su:triml(iobjstr[colon + 1..$])}
  player:tell(phrase)
else
  phrase = ""
endif
try
  {winner, @winverb, loser} = $su:explode(iobjstr)
except e (E_INVARG)
  player:tell("Usage: @rule <this> is <throw> <beats> <throw>")
  return
endtry
winverb = $su:from_list(winverb, " ")
if (!(winner in this.valid_throws))
  player:tell("This game does not have a throw called ", winner, ".")
elseif (!(loser in this.valid_throws))
  player:tell("This game does not have a throw called ", loser, ".")
endif
while ((rec = $list_utils:assoc({winner, loser}, this.rules)) || (rec = $list_utils:assoc({loser, winner}, this.rules)))
  player:tell("Replacing original rule: ", rec[1][1], " beats ", rec[1][2])
  this.rules = setremove(this.rules, rec)
endwhile
if (winverb == "beats")
  this.rules = {@this.rules, {{winner, loser}, phrase}}
else
  this.rules = {@this.rules, {{winner, loser}, phrase, winverb}}
endif
player:tell("Rule added.")
"Last modified by Pentomino (#8034) on Tue Aug 31 22:53:41 2004 MDT."
.

0