4f1
@verb #9131:"@iverbs" any none none rxd #9131
@program #9131:"@iverbs" any none none
"Copied from d.Fo (#6570):@iverbs by Everyman (#61) Jun 13 15:14:48 2003"
"$prog:@iverbs #<obj>"
if (player || caller != this)
  raise(E_PERM)
endif
dobj = (p = player):my_match_object(argstr)
if (!argstr)
  return p:tell("Syntax:  @iverbs #<obj>")
elseif (!$recycler:valid(dobj))
  return p:tell("No such object.")
elseif (!(verbs = verbs(dobj)))
  return p:tell("There are no verbs on ", $string_utils:nn(dobj), ".")
endif
iverbs = {}
for v in (verbs)
  fv = $string_utils:first_word(v)[1]
  if (w = index(fv, "*"))
    fv = fv[1..w - 1] + fv[w + 1..length(fv)]
  endif
  try
    {owner, perms, fvn} = verb_info(dobj, fv)
    vargs = verb_args(dobj, fv)
  except e (ANY)
    {owner, perms, vargs, fvn} = {"#?", "????", {"????", "????", "????"}, v}
  endtry
  iverbs = {@iverbs, {fv, tostr(owner), perms, $string_utils:from_list(vargs, " "), fvn}}
  seconds_left() < 2 ? suspend(0) | 0
endfor
p:tell($string_utils:center(tostr(" Information for verbs on: ", $string_utils:nn(dobj), " "), p:linelength(), "-", "-"))
#6570:tell_columns({15, 5, 5, 17, p:linelength() - 50}, {"verb", "owner", "perms", "arguments", "full verb name"}, iverbs, 1, 1)
.

0