7f5
@verb #8585:"send_request" this none this rxdo #9988
@program #8585:"send_request" this none this
"$ljmoo:send_request({{variable1, value1}, {variable2, value2}, ..., {variableN, valueN}})"
"=>  {{returnvar1, returnvalue1}, {returnvar2, returnvalue2}, ..., {returnvarN, returnvalueN}}"
""
"  Sends a raw request directly to LiveJournal."
"  If the result is successful, it parses the result into an assoc list and returns it."
"  If the connection attempt fails, or the result is not successful, then it parses the error into a user-friendly error message and raises it using raise(E_INVARG, 'Error Message')."
if (caller != this && !caller_perms().wizard)
  raise(E_PERM, "The send_request verb was not called properly.")
endif
{request_list} = args
request_string = $www:integrate_cgi(request_list)
if (request_string[1] == "?")
  request_string[1..1] = ""
endif
server_response = `this:send_request_raw(request_string) ! E_INVARG'
if (server_response == E_INVARG)
  raise(E_INVARG, "www.livejournal.com could not be contacted. Try again later.")
elseif (!server_response)
  raise(E_INVARG, "Server disconnected prematurely, or some sort of connection error occurred. Try again later.")
elseif (!match(server_response[1], "200 OK$"))
  raise(E_INVARG, "Server error, try again later.")
endif
while (`server_response[1] ! E_RANGE' != "")
  server_response[1..1] = {}
endwhile
`server_response[1..1] = {} ! E_RANGE'
if (!server_response)
  raise(E_INVARG, "Server disconnected prematurely, or some sort of connection error occurred. Try again later.")
endif
i = 1
result_list = {}
while (i + 1 <= length(server_response))
  result_list = {@result_list, server_response[i..i + 1]}
  i = i + 2
endwhile
if (`listassoc("success", result_list)[2] ! E_RANGE' != "ok")
  raise(@`{E_NONE, listassoc("errmsg", result_list)[2]} ! E_RANGE => {E_INVARG, "LiveJournal returned an unknown or unspecified error"}')
endif
return result_list
"Last modified by Cecil (#7407) on Mon Feb  4 17:24:45 2002 MST."
.

0