67b
@verb #8438:"_audit" this none this rxdo #8438
@program #8438:"_audit" this none this
"Copied from Generic Player (#12):_audit by Slacker (#55)Jun 30 07:06:11 1998"
"Hacked by Jay (#8438) to return a more friendly audit style."
caller == this || raise(E_PERM)
if (length(args) > 50 && args[1].owner != this)
  player:tell("Audit listing is ", length(args), " objects. Show anyway?")
  if (!$cmd_utils:yes_or_no())
    return
  endif
endif
lines = sizes = {}
toasty = 0
nbytes = nobjs = ndisk = 0
for x in (args)
  if (!$recycler:valid(x))
    continue
  endif
  size = object_bytes(x)
  dsize = x:_obj_disk_size()
  if (`x:_get_subsidised() ! E_PROPNF => 0')
    dsizestr = "[subsidised]"
  else
    dsizestr = dsize || ""
  endif
  sizestr = size || ""
  if (`x:_get_petrified() ! E_PROPNF => 1')
    expire = "[petrified]"
  elseif (x:_get_solidified())
    expire = "[solidified]"
  elseif ($object_utils:isa(x, $player))
    expire = ""
  elseif (x:is_expired())
    expire = "*EXPIRED*"
    toasty = toasty + 1
  else
    expire = $string_utils:from_seconds(x.best_before - time())
  endif
  lines[1..0] = {{x, x:title(), `x:audit_name() ! ANY => "???"', sizestr, tostr(dsizestr), expire}}
  sizes[1..0] = {size}
  $command_utils:suspend_if_needed()
endfor
$tcm || (lines = $list_utils:sort(lines, sizes))
$command_utils:suspend_if_needed(1)
this:tellColumns(3, {20, 10, 15, 20, 20, 20}, {"#", "name", "type", "bytes", "fsize", "expires"}, @lines)
if (toasty)
  this:sub_tell(this:display_pueblo() ? "<b>Total expired objects: %1</b>" | "Total expired objects: %1", toasty)
endif
this:("@quota")(dobj)
.

0