877
@verb #8165:"@newt" any for/about any rdo #8165
@program #8165:"@newt" any for/about any
"Copied from Generic Teacher (#15):@newt by Slacker (#55)Aug 31 11:13:29 2001"
"@newt [player] for [duration]:[reason]"
""
"Suspends a player's character for the duration specified, and \"marks\" it into their criminal record."
if (player != this)
  return $msg:mtell("huh")
endif
{intervalstr, ?reason = "breaking the rules", ?sponge = ""} = $su:explode(iobjstr, ":")
sponge && (reason = reason + ":" + sponge)
"Just in case there was a smilie in there or something."
if ($command_utils:player_match_failed(dobj = $string_utils:match_player(dobjstr), dobjstr))
  return
elseif (!(interval = $time_utils:parse_english_time_interval(intervalstr)))
  return player:tell(intervalstr, " is not a valid time duration.")
elseif (dobj != #7214)
  return player:tell("Sorry, you are only authorised to @newt JS.")
elseif ($wiz_utils:isnewt(dobj))
  player:sub_tell("*** NOTE: %d was already newted for %1 ***", $time_utils:english_time(dobj.nologin[1] - time()))
endif
fork (0)
  $msg:mtell({dobj, "i"}, "newt")
endfork
suspend(1)
boot_player(dobj)
dobj.anchor = #-1
dobj.nologin = {interval + time(), $su:subst($wiz_utils:msg_newt_nologin(), {{"<<by>>", player:nn()}, {"<<for>>", reason}})}
dobj.criminal_record[3] = {@dobj.criminal_record[3], tostr("NEWTED:  By ", player:nn(), " on ", ctime(), " for ", reason)}
prime = dobj.primary_character
seconds = dobj.second_characters
valid(prime) && player:tell("*** NOTE: ", dobj:nn(), " was  a second to ", prime:nn(), "! ***")
seconds && player:tell("*** NOTE: ", dobj:nn(), " has the following seconds: ", $string_utils:nn_list(seconds), "! ***")
subj = tostr("@newt ", dobj:nn())
msg = {"Duration: " + intervalstr, "Reason: " + reason, "", "Connected from: ", $su:from_list(dobj:fileread("all_connect_places"), ", ")}
valid(prime) && (msg = {@msg, "", "Primary Character: " + prime:nn()})
seconds && (msg = {@msg, "", "Secondary Characters:", $string_utils:nn_list(seconds)})
$mail_agent:send_message(player, $newt_log, subj, msg)
"Last modified by Dax (#789) on Fri Aug 31 11:22:46 2001 MDT."
.

0