89e
@verb #80:"handle_task_timeout" this none this rxdo #55
@program #80:"handle_task_timeout" this none this
"Copied from The SchoolNet MOO (#0):handle_uncaught_error by whiz.kid (#3135) Sep  6 01:12:05 1996"
"Passes tracebacks to anyone who's listening, too."
if (valid(player) && !player.header_issued)
  notify(player, "HTTP/1.0 500 Internal Server Error")
  notify(player, $www:server_name())
  notify(player, "Content-type: text/html")
  notify(player, "")
  player.header_issued = 1
endif
goner = verb_info(args[2][1][1], args[2][1][2])[1]
if (goner in {$hacker, $housekeeper, $postman, $repo_man} || goner.wizard)
  notify(player, tostr("<h2>Error encountered; please report this error to <a href=\"/feedback\">a wizard</a>.</h2>"))
else
  notify(player, tostr("<H2>Error encountered; please report this error to ", $web:link(goner), ".</H2>"))
endif
notify(player, tostr("Error was: <TT>Task out of ", tostr(args[1]), "</TT><P>"))
if (index(player.user_agent, "Lynx"))
  for x in (args[3])
    notify(player, x + "<br>")
  endfor
else
  notify(player, "<TABLE BORDER=\"1\"><TR><TH>VerbLoc:Verb</TH><TH>Programmer</TH><TH>This</TH><TH>Player</TH><TH>Line</TH></TR>")
  for x in (args[2])
    n = tostr(x[4])[2..$] + ":" + x[2]
    notify(player, tostr("<TR><TD>", $web:link(x[4], tostr(x[4])), ":<A HREF=/", n, ">", x[2], "</A></TD>"))
    notify(player, tostr("<TD>", $www:link(x[3], tostr(x[3])), "</TD><TD>", $www:link(x[1], tostr(x[1])), "</TD><TD>", $www:link(x[5], tostr(x[5])), "</TD><TD>", x[6], "</TD></TR>"))
  endfor
  notify(player, "</TABLE>")
  notify(player, "<br>You can cut-and-paste the following: <p><pre>")
  for x in (args[3])
    notify(player, x)
  endfor
  notify(player, "</pre>")
endif
notify(player, "</BODY></HTML>")
boot_player(player)
who = `this.spies ! ANY => {}'
for x in (args[3])
  for y in (who)
    notify(y, tostr("[", player, "]: ", x))
  endfor
endfor
return 1
"Last modified by Lao-Tzu (#8084) on Mon Aug 14 15:53:13 2000 MDT."
"This verb previously owned by whiz (#3135), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:03 2002 MDT)."
"Last modified by Dax (#789) on Mon May  2 09:02:08 2005 MDT."
.

0