6f0
@verb #6:"l*ook" any any any rxdo #55
@program #6:"l*ook" any any any
set_task_perms(callers() ? caller_perms() | player)
if (dobjstr == "" && !prepstr)
  this:look_self()
elseif (!(prepstr in {"in", "on", "to"}))
  if (!dobjstr && prepstr == "at")
    dobjstr = iobjstr
    iobjstr = ""
  else
    dobjstr = dobjstr + (prepstr && (dobjstr && " ") + prepstr)
    dobjstr = dobjstr + (iobjstr && (dobjstr && " ") + iobjstr)
  endif
  dobj = player:my_match_object(dobjstr)
  if (!$command_utils:object_match_failed(dobj, dobjstr))
    dobj:look_self()
  endif
elseif (!iobjstr)
  $msg:mtell("no_iobj", verb, dobjstr, prepstr)
elseif (prepstr == "to")
  if (!$command_utils:object_match_failed(this:match_exit(iobjstr, player), iobjstr))
    if (dobjstr == "")
      iobj.dest:look_self()
    elseif ((thing = `iobj.dest:match(dobjstr, player) ! E_VERBNF => #-1') == $failed_match)
      $msg:mtell("not_contain", iobj, dobjstr)
    elseif (thing == $ambiguous_match)
      $msg:mtell("ambiguous", dobjstr)
    else
      thing:look_self()
    endif
  endif
else
  iobj = player:my_match_object(iobjstr)
  if (!$command_utils:object_match_failed(iobj, iobjstr))
    if (dobjstr == "")
      iobj:look_self()
    elseif ((thing = `iobj:match(dobjstr, player) ! E_VERBNF => #-1') == $failed_match)
      $msg:mtell("not_contain", iobj, dobjstr)
    elseif (thing == $ambiguous_match)
      $msg:mtell("ambiguous", dobjstr)
    else
      thing:look_self()
    endif
  endif
endif
"Last modified by manta (#7165) on Fri Oct 26 09:03:48 2001 MDT."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:04 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:04 2002 MDT."
.

0