4cb
@verb #6:"_destructor" this none this rxdo #55
@program #6:"_destructor" this none this
"Begin generic security check (_destructor)"
if (verb == "_destructor" && caller_perms() != #-1)
  raise(E_PERM)
  return E_PERM
endif
"End generic security check (_destructor)"
if (caller_perms() == #-1)
  nuke = {}
  n = args[1].name
  for e in (args[1]:exits())
    if (`e.recycle_with_room ! E_PROPNF => 0')
      nuke[1..0] = {e}
    endif
  endfor
  for x in ({args[1].owner, @args[1].residents})
    `x.home == args[1] && (x.home = $player_start) ! E_INVIND, E_PROPNF => "<shrug, owner or residents may be invalid or not have a home prop>"'
  endfor
  fork (0)
    for e in (nuke)
      $recycler:recycle(e)
    endfor
    if ($recycler:valid(args[1]))
      for x in (args[1].contents)
        `args[1]:eject(x) ! ANY'
      endfor
    endif
    if ($room_db.frozen)
      $room_db.frozen = 2
    endif
    $room_db:delete(n)
  endfork
endif
"Last modified by Slacker (#55) on Sat Mar 30 16:27:09 2002 MST."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:04 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:04 2002 MDT."
.

0