871
@verb #59:"funky_action" this none this rxdo #55
@program #59:"funky_action" this none this
if (caller != this && !caller_perms().wizard)
  raise(E_PERM)
endif
{o} = args
if (!$recycler:valid(o) || (!o:is_expired() && $recycler:valid(o.owner)) || o.owner == this || o.owner.wizard)
  player:tell("Repoman was asked to repo ", o:nn(), ", but he's got second thoughts.")
  return E_INVARG
endif
if (o:isa($room))
  this:indirect_move(o)
  `this.location:sub_announce_all("%t slaps a reposession notice on this room, and starts wrapping red tape across the walls.") ! ANY => "Too bad."'
  this:reposses(o, 0)
elseif (o:isa($thing))
  locs = {}
  l = o
  while (valid(l) && !l:isa($room))
    locs = {@locs, l}
    l = l.location
  endwhile
  if (valid(l))
    this:indirect_move(l)
    suspend(2)
    if (length(locs) > 1)
      for i in [1..length(locs) - 1]
        `this.location:sub_announce_all("%t snatches %1 from %2.", locs[$ - i], locs[$ - i + 1]) ! ANY'
      endfor
      for i in [2..length(locs) - 1]
        `this.location:sub_announce_all("%t puts %1 back in %2.", locs[i], locs[i + 1]) ! ANY => "Pbbt."'
      endfor
    else
      this.location:sub_announce_all("%t snatches %1.", o)
    endif
  endif
  this:reposses(o, 1)
elseif (o:isa($project))
  if (o.leader == this && !o.teachers)
    this:reposses(o, 2)
  endif
elseif (o:isa($player))
  this:indirect_move(o.location)
  try
    this.location:sub_announce_all("%t dons a black cloak and a giant scythe, and slowly and solemnly approaches %1...", o)
    this:sub_announce_all("%t stands between you and %1, and motions over %1#-3, %1 is no longer there!", o)
  except (ANY)
    "Too bad."
  endtry
  if (is_player(o))
    $wiz_utils:forget_player(o)
  endif
  $repo_man:dispatch(@listappend(setremove(o.owned_objects, o), o))
  this:reposses(o, 3)
else
  this:reposses(o, 0)
endif
"Last modified by Dax (#789) on Sat Dec 29 19:34:43 2001 MST."
"This verb previously owned by Raptor (#6319), and chowned to $slacker upon dewizarding (Sat Aug 17 14:48:42 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:48:42 2002 MDT."
.

0