5b7
@verb #51:"invoke_local_editor" this none this rxdo #55
@program #51:"invoke_local_editor" this none this
":invoke_local_editor(name, text, upload)"
"Spits out the magic text that invokes the local editor in the player's client."
"NAME is a good human-readable name for the local editor to use for this particular piece of text."
"TEXT is a string or list of strings, the initial body of the text being edited."
"UPLOAD, a string, is a MOO command that the local editor can use to save the text when the user is done editing.  The local editor is going to send that command on a line by itself, followed by the new text lines, followed by a line containing only `.'.  The UPLOAD command should therefore call $command_utils:read_lines() to get the new text as a list of strings."
if (caller != this)
  return
endif
name = args[1]
text = args[2]
upload = args[3]
if (typeof(text) == $STR)
  text = {text}
endif
if (player:edit_option("local"))
  player:tell("#$# edit name: ", name, " upload: ", upload)
  ":dump_lines() takes care of the final `.' ..."
  for line in ($command_utils:dump_lines(text))
    notify(player, line)
  endfor
elseif (player:edit_option("mcp_edit"))
  player:tell("#$#edit* ", player.mcp_key || "", " name: ", name, " upload: ", upload)
  for line in (text)
    player:tell("@@@", line)
  endfor
  player:tell("#$#END")
else
  return
endif
"Last modified by Dax (#789) on Tue May  3 13:43:07 2005 MDT."
.

0