4b3
@verb #51:"fill" any any any rdo #60
@program #51:"fill" any any any
fill_column = 70
if (!(who = this:loaded(player)))
  player:tell(this:msg_nothing_loaded())
elseif (typeof(range = this:parse_range(who, {"_", "1"}, @args)) != $LIST)
  player:tell(range)
elseif (range[3] && (range[3][1] != "@" || (fill_column = toint(range[3][2..length(range[3])])) < 10))
  player:tell("Usage:  fill [&lt;range&gt;] [@ column]   (where column &gt;= 10).")
else
  oldtext = this.texts[who]
  join = this:join_lines(who, @range[1..2], 1)
  newlines = this:fill_string((text = this.texts[who])[from = range[1]], fill_column)
  if (fill = (nlen = length(newlines)) > 1 || newlines[1] != text[from])
    this.texts[who] = {@text[1..from - 1], @newlines, @text[from + 1..length(text)]}
    if ((insert = this.inserting[who]) > from && nlen > 1)
      this.inserting[who] = insert + nlen - 1
    endif
  endif
  if (fill || join)
    for line in [from..from + nlen - 1]
      this:list_line(who, line)
    endfor
    this.changes[who] = oldtext
    this.times[who] = time()
  else
    player:tell("No changes.")
  endif
endif
"Last modified by Dax (#789) on Wed May  4 06:46:00 2005 MDT."
.

0