4dd
@verb #51:"@flush" this any any rdo #60
@program #51:"@flush" this any any
"@flush <editor>"
"@flush <editor> at <month> <day>"
"@flush <editor> at <weekday>"
"The first form removes all sessions from the editor; the other two forms remove everything older than the given date."
if (!$perm_utils:controls(player, this))
  return player:tell("Only the owner of the editor can do a ", verb, ".")
elseif (!prepstr)
  player:tell("Trashing all sessions.")
  this:kill_all_sessions()
elseif (prepstr != "at")
  player:tell("Usage:  ", verb, " ", dobjstr, " [at [mon day|weekday]]")
else
  p = prepstr in args
  if (t = $time_utils:from_day(iobjstr, -1))
  elseif (t = $time_utils:from_month(args[p + 1], -1))
    if (length(args) > p + 1)
      if (!(n = toint(args[p + 2])))
        return player:tell(args[p + 1], " WHAT?")
      endif
      t = t + (n - 1) * 86400
    endif
  else
    return player:tell("Couldn't parse date.")
  endif
  for i in [-length(this.active)..-1]
    if (this.times[-i] < t)
      player:tell(this.active[-i].name, "(", this.active[-i], ") ", ctime(this.times[-i]))
      this:kill_session(-i)
    endif
  endfor
endif
"Last modified by Dax (#789) on Tue May  3 14:09:30 2005 MDT."
.

0