515
@verb #4:"_kick" this none this rxdo #789
@program #4:"_kick" this none this
"Begin generic security check (_kick)"
if (verb == "_kick" && !args[1]:isa(this))
  raise(E_INVARG, "Illegal object", args[1])
  return E_INVARG
endif
"End generic security check (_kick)"
"Called every week or so.  Does some basic cleaning on players."
{dude} = args
"Make sure that all of the objects I think I own are actualy mine."
newlist = oldlist = dude.owned_objects
for x in (dude.owned_objects)
  if (!$recycler:valid(x))
    newlist = setremove(newlist, x)
    continue
  endif
  if (x.owner != dude)
    newlist = setremove(newlist, x)
  endif
  $command_utils:suspend_if_needed()
endfor
if (oldlist != dude.owned_objects)
  "Doh, the list changed while we were suspended."
else
  dude.owned_objects = newlist
endif
for x in (dude.quota_contribs)
  valid(x[1]) && x[1]:isa($accountable) || (dude.quota_contribs = setremove(dude.quota_contribs, x))
  $command_utils:suspend_if_needed()
endfor
newstuds = {}
for x in (dude:_get_students())
  if (x:isa($accountable))
    newstuds = setadd(newstuds, x)
  endif
endfor
dude:_set_students(newstuds)
"Force a check of the player's quota"
dude:is_over_quota()
"Last modified by manta (#7165) on Thu Jul 25 12:14:26 2002 MDT."
.

0