59a
@verb #340:"update" this none this rxdo #7214
@program #340:"update" this none this
caller == this || caller_perms():controls(this) || raise(E_PERM)
{server, dir, user} = this.CVSROOT
c = this:_open_connection()
this:_send_line(c, "Argument -d")
this:_send_line(c, "Directory .")
this:_send_line(c, dir, "/", this.repository)
for o in (this.objects)
  objname = this:get_name_for_object(o)
  encobjname = this:_trans_to(objname)
  if (obje = this:_get_entry(encobjname))
    for encname in (listdelete(this:parse_spec(tostr(o)), 1))
      if (e = this:_get_entry(encname))
        this:_send_line(c, "Argument ", encname)
        {lcontents, contents} = this:_contents(o, encname)
        modified = value_hash(contents) != e[rindex(e, "/") + 1..$]
        this:_send_line(c, "Entry ", e)
        if (!modified)
          this:_send_line(c, "Unchanged ", encname)
        else
          this:_send_line(c, "Modified ", encname)
          this:_send_line(c, "u=rw,g=r,o=r")
          this:_send_line(c, tostr(lcontents))
          for x in (contents)
            this:_send_line(c, x)
          endfor
        endif
      else
        player:tell("? ", encname)
      endif
    endfor
  else
    player:tell("? ", encobjname, "/")
  endif
endfor
this:_send_line(c, "update")
this:_handle_response(c)
this:_close_connection(c)
"Last modified by manta (#7165) on Sun May  7 15:33:20 2000 MDT."
.

0