4bc
@verb #3200:"@view" any none none rxdo #7407
@program #3200:"@view" any none none
if ((NUM = $code_utils:toint(argstr)) == E_TYPE)
  return player:tell("You have to use the vote's ID number. (Look at \"@topics\")")
endif
try
  {creator, title, desc, options, voters, expiry} = this.topics[NUM]
except (E_RANGE)
  return player:tell("You tried to view a topic that does not exist.")
endtry
if (!options)
  options = {"Yes", "No"}
  maxlen = 3
else
  maxlen = 0
  for opt in (options)
    maxlen = max(maxlen, $msg:string_length(opt))
  endfor
endif
optvotes = $list_utils:make(length(options), 0)
for voter in (voters)
  optvotes[voter[2]] = optvotes[voter[2]] + 1
endfor
player:tell(title)
player:tell($string_utils:space(player:linelength(), "="))
player:tell(desc)
player:tell($string_utils:space(player:linelength(), "="))
for i in [1..length(options)]
  player:tell(player.output_rendering_object:left_render(options[i], min(player:linelength() - 11, maxlen), player), " ", player.output_rendering_object:right_render(optvotes[i], 10, player))
endfor
player:tell($string_utils:space(player:linelength(), "="))
"Last modified by Dax (#789) on Wed May  4 06:36:14 2005 MDT."
.

0