4cd
@verb #3135:"@set_msgs" any none none rdo #3135
@program #3135:"@set_msgs" any none none
"Copied from Generic player (#6):@mess by Slacker (#2) Apr 27 22:43:26 1996"
set_task_perms(player)
dobj = player:my_match_object(dobjstr)
if ($command_utils:object_match_failed(dobj, dobjstr))
  return
endif
found_one = 0
props = $object_utils:all_properties(dobj)
if (typeof(props) == $ERR)
  player:tell("You can't read the messages on that.")
  return
endif
for pname in (props)
  len = length(pname)
  if (len > 4 && pname[len - 3..len] == "_msg" && !is_clear_property(dobj, pname))
    found_one = 1
    msg = dobj.(pname)
    mname = pname[1..len - 4]
    if (msg == E_PERM)
      player:sub_tell("@%1 #%d~# is ...unreadable...", mname)
    elseif (!msg)
      player:sub_tell("@%1 #%d~# is ...not set...", mname)
    else
      header = $msg:str(player.language, "@%1 #%d~# is", mname)
      player:tell(header, " ", toliteral(msg))
      "Bypass&&mechanism for message text, so player sees it all."
    endif
  endif
  $command_utils:suspend_if_needed()
endfor
if (!found_one)
  player:tell("That object has no messages.")
endif
"Last modified by Dax (#789) on Tue May  3 13:45:59 2005 MDT."
.

0