6de
@verb #3100:"bug" any any any rxdo #789
@program #3100:"bug" any any any
"This monster verb parses all the commands to the bug, and takes appropriate action based on the instruction."
$wiz_utils:autoextend(this)
player == caller_perms() || raise(E_PERM)
if (player != this.owner)
  player:tell(E_PERM)
elseif (valid(dobj))
  this:moveto(dobj)
elseif (length(argstr) > 1 && argstr[1] in {"\"", "`", "'", ":", "!"})
  text = argstr[1] == ":" ? argstr[2] == ":" ? "%n%1" | "%n %1" | (argstr[1] == "!" ? "%1" | this.location:msg_osay())
  this.location:sub_announce(text, $string_utils:trim(argstr[argstr[1] == ":" && argstr[2] == ":" ? 3 | 2..length(argstr)]))
else
  if (args)
    if (args[1] in {"l", "lo", "loo", "look"})
      if (length(args) == 1)
        this.location:look_self()
      else
        dobj = this.location:match_object(args[2])
        if (!$command_utils:object_match_failed(dobj, args[2]))
          dobj:look_self()
        endif
      endif
      return
    elseif (args[1] == "exits")
      return this.location:("@exits")()
    endif
    source = this.location
    exit = $object_utils:isa(source, $room) ? source:match_exit(argstr) | #-1
    if ($object_utils:isa(exit, $exit))
      this:moveto(exit.dest)
      if (this.location == source)
        player:tell("Silent move failed, attemping to use exit...")
        exit:move(this)
      endif
      return
    elseif (valid(playerobj = $string_utils:match_player(args[1])))
      player:sub_tell("%1 is in %2.", playerobj, playerobj.location)
      return this:moveto(playerobj.location)
    endif
  endif
  player:tell("Invalid command, type: help ", this)
endif
"Last modified by Lao-Tzu (#8084) on Thu Dec 13 19:39:11 2001 MST."
.

0