a71
@verb #2345:"pray" any any any rdo #9342
@program #2345:"pray" any any any
"This verb determines to whom the player is worshiping, and handles each case."
if (this.prayer)
  player:tell("Be patient; a prayer is still in progress.")
  $object_utils:isa(player, $guardian) && player:tell("Guardians may terminate the prayer by saying: \"Amen\".")
  return
elseif (!argstr)
  player:tell("You pray fervently to nobody in particular.")
  $msg:mtell("pray", "nobody in particular")
  suspend(2)
  return this:announce_all($msg:msg_not_much())
endif
this.prayer = $string_utils:match_stringlist(args[length(args)], {"Prophets", "Profits", "Picard", "Ardra", "Orbs"})
this.prayer = this.prayer ? {"Prophets", "Profits", "Picard", "Ardra", "Orbs"}[this.prayer] | ""
if (this.prayer == "Prophets")
  $msg:mtell("pray", "the Prophets.")
  $building_utils:set_names(Orb = $recycler:create(#343), "an Orb, orb")
  typeof(Orb) == $OBJ ? Orb:moveto(player) | 0
  player:tell(Orb in player.contents ? "The Prophets smile on you today.  They give you an Orb" | "The Prophets seem to be experiencing technical difficulties with their Orbs.")
elseif (this.prayer == "Profits")
  $msg:mtell("pray", "the Profits.")
  rule = #1035:ferengi()
  player:tell("A shrill, high pitched, Ferengi voice admonishes the ", $string_utils:ordinal(rule[1]), " Rule of Acquisition:")
  suspend(1)
  player:tell(rule[2])
elseif (this.prayer == "Picard")
  $msg:mtell("pray", "The Picard")
  this:announce_all("You hear a whine.")
  suspend(1)
  this:announce_all("The Picard appears inside a sparkling glow, which subsides.")
  suspend(1)
  this:announce_all("You hear the whine subsiding")
  suspend(2)
  this:announce_all("Picard says, \"I am NOT a God!\"")
  suspend(2)
  this:announce_all("Picard says, \"If you continue to worship me, I shall smite thee!\"")
  suspend(2)
  this:announce_all("Picard mutters something about the Prime Directive.")
  suspend(2)
  this:announce_all("You hear a whine.")
  suspend(1)
  this:announce_all("The Picard is obscured by sparkles.")
  suspend(1)
  this:announce_all("You hear the whine subsiding")
elseif (this.prayer == "Ardra")
  $msg:mtell("pray", "Ardra")
  #666.key = 0
  #666:moveto(this)
  this:announce_all("Ardra appears in a pillar of flame.")
  #666:pray()
  this:announce_all("Ardra disappears in a pillar of flame.")
  #666:moveto(#2333)
elseif (this.prayer == "Orbs")
  player:tell("If you want an Orb, you should consider praying to the Prophets.")
else
  player:tell("To whom do you wish to pray?")
endif
this.prayer = ""
"Last modified by Dax (#789) on Tue May  3 13:49:41 2005 MDT."
.

0