84b
@verb #2250:"@sw*eep" none none none rdo #7788
@program #2250:"@sw*eep" none none none
"Copied from Generic Player (#12):@sweep by Slacker (#55)Jun 30 18:47:00 1998"
buggers = 1
found_listener = 0
here = this.location
for thing in (setremove(here:contents(), this))
  tellwhere = thing:has_verb("tell")
  notifywhere = thing:has_verb("notify")
  if (#-1 in `thing.gaglist ! ANY => {}')
    this:sub_tell(thing:msg_audio_isolate(), thing)
  elseif (thing:connected(1))
    this:notify(tostr(thing.name, " (", thing, ") is listening."))
    found_listener = 1
  elseif (thing:has_callable_verb("sweep_msg") && typeof(msg = thing:sweep_msg()) == $STR)
    this:notify(tostr(thing.name, " (", thing, ") ", msg, "."))
    found_listener = 1
  elseif (tellwhere && ((owner = verb_info(tellwhere[1], "tell")[1]) != this && (!owner.wizard && owner != $hacker)))
    this:notify(tostr(thing.name, " (", thing, ") has been taught to listen by ", owner.name, " (", owner, ")"))
    found_listener = 1
  elseif (notifywhere && ((owner = verb_info(notifywhere[1], "notify")[1]) != this && (!owner.wizard && owner != $hacker)))
    this:notify(tostr(thing.name, " (", thing, ") has been taught to listen by ", owner.name, " (", owner, ")"))
    found_listener = 1
  endif
  suspend(0)
endfor
buggers = {}
for v in ({"announce", "announce_all", "announce_all_but", "say", "emote", "huh", "here_huh", "huh2", "whisper"})
  vwhere = $object_utils:has_verb(here, v)
  if (vwhere && ((owner = verb_info(vwhere[1], v)[1]) != this && (!owner.wizard && owner != $hacker)))
    buggers = setadd(buggers, owner)
  endif
endfor
if (buggers != {})
  if ($object_utils:has_verb(here, "sweep_msg") && typeof(msg = here:sweep_msg()) == $STR)
    this:notify(tostr(here.name, " (", here, ") ", msg, "."))
  else
    this:notify(tostr(here.name, " (", here, ") may have been bugged by ", $string_utils:english_list($list_utils:map_prop(buggers, "name")), "."))
  endif
elseif (!found_listener)
  this:notify("Communications look secure.")
endif
"Last modified by Dax (#789) on Tue May  3 13:43:09 2005 MDT."
.

0