705
@verb #2030:"go_go" this none this rxdo #987
@program #2030:"go_go" this none this
"The master movement verb."
"Receives destination info in string or obj# format; converts to obj#; calls go_exit if destination is an exit; calls go_path if destination is room; calls go_move if no path exists."
if (!this:key())
  $msg:mtell("no_key")
  return E_PERM
endif
deststr = ""
if (typeof(dest = args[1]) != $OBJ)
  dest == "home" ? dest = player.home | (deststr = tostr(args[1]))
endif
if (deststr)
  if ($object_utils:isa(this.location, $room))
    dest = this.location:match_exit(deststr)
  else
    exits = this:exit_list(this.location)
    dest = $string_utils:match(deststr, exits, "name", exits, "aliases")
  endif
endif
if ($object_utils:isa(dest, $exit))
  this:jabber_shout(this:msg_ogo_started(), this, dest.dest:title())
  if (this:go_exit(dest))
    this:look_out()
  else
    player:tell("You have been denied entry to " + dest.dest:title() + " via " + dest:title() + ".")
    this:jabber_shout(this:msg_ogo_failed(), this, dest.dest:title())
  endif
else
  if (deststr)
    dest = this:room_id(deststr)
  endif
  if ($object_utils:isa(dest, $room))
    if (dest == this || dest == this.location)
      return player:tell("You are already here!")
    else
      this:jabber_shout(this:msg_ogo_started(), this, dest:title())
      if (!this:go_path(dest))
        player:tell("Unable to find path to destination, activating transporter...")
        if (!this:go_move(dest))
          this:jabber_shout(this:msg_ogo_failed(), this, dest:title())
        endif
      endif
    endif
  else
    player:tell(deststr ? "Unknown destination." | "Invalid destination.")
  endif
endif
"Last modified by Dax (#789) on Wed May  4 06:44:33 2005 MDT."
.

0