556
@verb #18:"@request request" any none none rdo #55
@program #18:"@request request" any none none
"Copied from The Connections Thingy (#4172):request by Dead_Duck (#396) Sep  8 17:06:13 1996"
if (player != this)
  return $msg:mtell("huh")
elseif (length(args) != 2)
  return player:tell("Syntax: request <name> <email-address>")
endif
{name, email} = args
host = $string_utils:connection_hostname(connection_name(this))
server_log(tostr("REQUEST: ", name, " for ", email, " from ", host))
if (result = $wiz_utils:check_player_request(name, email, host))
  $msg:mtell("request_nak", result)
  server_log(tostr("REQUEST FAILED: ", result, " from ", host))
  return
endif
result = $wiz_utils:make_player(name, email)
$msg:mtell("request_ok", result[1])
server_log(tostr("REQUEST OK: ", result[1], " for ", host, "."))
$mail_agent:send_message(this, $pcl, tostr(result[1].name, " (", result[1], ")"), {email, connection_name(player)})
ok = $wiz_utils:send_new_player_mail({}, name, email, result[1], result[2])
if (ok == 0)
  $msg:mtell("request_email_ok", email)
  server_log(tostr("REQUEST EMAIL OK: ", host, " (", email, ")"))
else
  $msg:mtell("request_email_bomb", email, ok)
  server_log(tostr("REQUEST EMAIL BOMB: ", host, " (", email, "): ", ok))
endif
"Last modified by Cecil (#7407) on Mon Nov  4 15:12:51 2002 MST."
.

0