7d8
@verb #1606:"@resident*s" any none none rdo #55
@program #1606:"@resident*s" any none none
"Copied from Generic Room (#6):@residents by Slacker (#55)Apr 14 16:32:29 2001"
if (typeof(this.residents) != $LIST)
  this.residents = {this.residents}
endif
"First, remove !valid objects from this room..."
for x in (this.residents)
  if (!$recycler:valid(x))
    player:tell("Warning: removing ", x, ", an invalid object, from the residents list.")
    this.residents = setremove(this.residents, x)
  endif
endfor
if (!dobjstr)
  if (!this.residents)
    player:tell("There are no residents in this room.")
  else
    player:tell("Allowable residents in this room: ")
    for x in (this.residents)
      player:tell("  ", $string_utils:nn(x), "  --  ", x:rank())
    endfor
    player:tell("-----------")
  endif
elseif (!$perm_utils:controls(player, this))
  player:tell("You must own this room to manipulate the legal residents list.  Try contacting ", this.owner.name, ".")
else
  if (dobjstr[1] == "!")
    notflag = 1
    dobjstr = dobjstr[2..$]
  else
    notflag = 0
  endif
  result = $string_utils:match_player_or_object(dobjstr)
  if (!result)
    return
  else
    "a one element list was returned to us if it won."
    result = result[1]
    if (notflag)
      if (!(result in this.residents))
        player:tell(result.name, " doesn't appear to be in the residents list of ", this.name, ".")
      else
        this.residents = setremove(this.residents, result)
        player:tell(result.name, " removed from the residents list of ", this.name, ".")
      endif
    else
      if (result in this.residents)
        player:tell(result.name, " is already an allowed resident of ", this.name, ".")
      else
        this.residents = {@this.residents, result}
        player:tell(result.name, " added to the residents list of ", this.name, ".")
      endif
    endif
  endif
endif
"Last modified by Dax (#789) on Wed May  4 06:46:02 2005 MDT."
.

0