45c
@verb #1492:"set_pointer" this none this rx #60
@program #1492:"set_pointer" this none this
if (!args)
  value = this.remembered
else
  value = $gopher:get(@args[1])
endif
if (!value)
  this:busy(0)
  this:announce_op($gopher:interpret_error(value))
  return 0
endif
if (value[1][1] == "3")
  this:busy(0)
  this:announce_op("The gopher request results in an error:")
  for x in (value)
    this:announce_op(": ", x ? x[2..length(x)] | x)
  endfor
  return 0
endif
if (args && args[1][4][1] == "0")
  "text node"
  desc = value
else
  desc = {}
  cnt = 1
  for x in (value)
    $command_utils:suspend_if_needed()
    type = $gopher:type(x[1])
    if (type == "text")
      type = ""
    else
      type = " (" + type + ")"
    endif
    tab = index(x, "	")
    label = x[2..tab - 1]
    desc = {@desc, tostr(cnt, ". ", label, type)}
    cnt = cnt + 1
  endfor
endif
$command_utils:suspend_if_needed()
this.desclines = desc
this.stack = args
this.value = value
this:busy(0)
this:show_results()
return 1
"Last modified by Dax (#789) on Sat May 16 14:19:43 1998 EDT."
.

0